kc3-lang/angle/samples/BUILD.gn

• Show log

  Commit

• Hash : 175d918a
  Author :
  Date : 2018-12-16T19:53:23
  

  Revert "Load correct libGLESv2 on Linux and Mac."
  
  This reverts commit dd815b623e60a1e1550f328104ffcd7caf20fde1.
  
  Reason for revert: Broke https://luci-milo.appspot.com/p/chromium/builders/luci.chromium.ci/win-rel/8006
  
  Original change's description:
  > Load correct libGLESv2 on Linux and Mac.
  > 
  > libEGL was implicitly loading libGLESv2 on startup. This is bad
  > because on platforms like Linux and Mac we could sometimes use the
  > incorrect rpath. This in turn meant we needed workarounds like using
  > "_angle" extensions to our shared objects to get the correct loading
  > behaviour.
  > 
  > Fix this by loading libGLESv2 dynamically in libEGL. We build the
  > loader automatically from egl.xml. The loader itself is lazily
  > initialized on every EGL entry point call. This is necessary because
  > on Linux, etc, there is no equivalent to Windows' DLLMain.
  > 
  > We also use an EGL.h with different generation options so we have the
  > proper function pointer types. A README is included for instructions
  > on how to regenerate EGL.h.
  > 
  > The entry point generation script is refactored into a helper class
  > that is used in the loader generator. Also adds the libGLESv2 versions
  > of the EGL entry points in the DEF file on Windows. This allows them to
  > be imported properly in 32-bit configurations.
  > 
  > Also fixes up some errors in ANGLE's entry point definitions. Also
  > includes a clang-format disable rule for the Khronos headers.
  > 
  > This CL will help us to run ANGLE tests against native drivers.
  > 
  > Bug: angleproject:2871
  > Change-Id: Id6ecf969308f17b1be4083538428c9c1a1836572
  > Reviewed-on: https://chromium-review.googlesource.com/c/1370725
  > Commit-Queue: Jamie Madill <jmadill@chromium.org>
  > Reviewed-by: Geoff Lang <geofflang@chromium.org>
  
  TBR=ynovikov@chromium.org,geofflang@chromium.org,jmadill@chromium.org
  
  Change-Id: I921b3c45435ab4f05cbc2d1c1172b4185d6257b0
  No-Presubmit: true
  No-Tree-Checks: true
  No-Try: true
  Bug: angleproject:2871
  Reviewed-on: https://chromium-review.googlesource.com/c/1378887
  Reviewed-by: Yuly Novikov <ynovikov@chromium.org>
  Commit-Queue: Yuly Novikov <ynovikov@chromium.org>
  

Download

• samples/BUILD.gn

• # Copyright 2017 The Chromium Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  
  import("../gni/angle.gni")
  
  executable("shader_translator") {
    sources = [
      "shader_translator/shader_translator.cpp",
    ]
    include_dirs = [ "../include" ]
    deps = [
      "../:translator",
    ]
  }
  
  config("sample_util_config") {
    include_dirs = [ "sample_util" ]
  }
  
  static_library("sample_util") {
    sources = [
      "sample_util/SampleApplication.cpp",
      "sample_util/SampleApplication.h",
      "sample_util/texture_utils.cpp",
      "sample_util/texture_utils.h",
      "sample_util/tga_utils.cpp",
      "sample_util/tga_utils.h",
    ]
    deps = [
      "../:angle_common",
      "../:angle_util",
      "../:libEGL${angle_libs_suffix}",
      "../:libGLESv1_CM${angle_libs_suffix}",
      "../:libGLESv2${angle_libs_suffix}",
    ]
    public_configs = [ ":sample_util_config" ]
  }
  
  template("angle_sample") {
    if (defined(invoker.data)) {
      copy(target_name + "_data") {
        sources = invoker.data
        outputs = [
          "$root_out_dir/{{source_file_part}}",
        ]
      }
    }
  
    executable(target_name) {
      deps = [
        ":sample_util",
        "../:angle_util",
      ]
      if (defined(invoker.data)) {
        deps += [ ":${target_name}_data" ]
      }
      sources = invoker.sources
    }
  }
  
  angle_sample("hello_triangle") {
    sources = [
      "hello_triangle/HelloTriangle.cpp",
    ]
  }
  
  angle_sample("mip_map_2d") {
    sources = [
      "mip_map_2d/MipMap2D.cpp",
    ]
  }
  
  angle_sample("multi_texture") {
    sources = [
      "multi_texture/MultiTexture.cpp",
    ]
    data = [
      "multi_texture/basemap.tga",
      "multi_texture/lightmap.tga",
    ]
  }
  
  angle_sample("multi_window") {
    sources = [
      "multi_window/MultiWindow.cpp",
    ]
  }
  
  angle_sample("multiple_draw_buffers") {
    sources = [
      "multiple_draw_buffers/MultipleDrawBuffers.cpp",
    ]
    data = [
      "multiple_draw_buffers/multiple_draw_buffers_copy_fs.glsl",
      "multiple_draw_buffers/multiple_draw_buffers_fs.glsl",
      "multiple_draw_buffers/multiple_draw_buffers_vs.glsl",
    ]
  }
  
  angle_sample("multiview") {
    sources = [
      "multiview/Multiview.cpp",
    ]
  }
  
  angle_sample("particle_system") {
    sources = [
      "particle_system/ParticleSystem.cpp",
    ]
    data = [
      "particle_system/smoke.tga",
    ]
  }
  
  angle_sample("post_sub_buffer") {
    sources = [
      "post_sub_buffer/PostSubBuffer.cpp",
    ]
  }
  
  angle_sample("simple_instancing") {
    sources = [
      "simple_instancing/SimpleInstancing.cpp",
    ]
  }
  
  angle_sample("simple_texture_2d") {
    sources = [
      "simple_texture_2d/SimpleTexture2D.cpp",
    ]
  }
  
  angle_sample("simple_texture_cubemap") {
    sources = [
      "simple_texture_cubemap/SimpleTextureCubemap.cpp",
    ]
  }
  
  angle_sample("simple_vertex_shader") {
    sources = [
      "simple_vertex_shader/SimpleVertexShader.cpp",
    ]
  }
  
  angle_sample("stencil_operations") {
    sources = [
      "stencil_operations/StencilOperations.cpp",
    ]
  }
  
  angle_sample("tex_redef_microbench") {
    sources = [
      "tex_redef_microbench/TexRedefMicroBench.cpp",
    ]
  }
  
  angle_sample("texture_wrap") {
    sources = [
      "texture_wrap/TextureWrap.cpp",
    ]
  }
  
  angle_sample("tri_fan_microbench") {
    sources = [
      "tri_fan_microbench/TriFanMicroBench.cpp",
    ]
  }
  
  angle_sample("window_test") {
    sources = [
      "WindowTest/WindowTest.cpp",
    ]
  }
  
  angle_sample("gles1_hello_triangle") {
    sources = [
      "gles1/HelloTriangle.cpp",
    ]
  }
  
  angle_sample("gles1_simple_texture_2d") {
    sources = [
      "gles1/SimpleTexture2D.cpp",
    ]
  }
  
  angle_sample("gles1_simple_lighting") {
    sources = [
      "gles1/SimpleLighting.cpp",
    ]
  }
  
  angle_sample("gles1_flat_shading") {
    sources = [
      "gles1/FlatShading.cpp",
    ]
  }
  
  angle_sample("gles1_draw_texture") {
    sources = [
      "gles1/DrawTexture.cpp",
    ]
  }
  
  group("all") {
    testonly = true
    deps = [
      ":hello_triangle",
      ":mip_map_2d",
      ":multi_texture",
      ":multi_window",
      ":multiple_draw_buffers",
      ":multiview",
      ":particle_system",
      ":post_sub_buffer",
      ":sample_util",
      ":simple_instancing",
      ":simple_texture_2d",
      ":simple_texture_cubemap",
      ":simple_vertex_shader",
      ":stencil_operations",
      ":tex_redef_microbench",
      ":texture_wrap",
      ":tri_fan_microbench",
      ":window_test",
    ]
  }
  

Download