kc3-lang/angle/src/libANGLE/renderer/metal/ImageMtl.mm

• Show log

  Commit

• Hash : 6136620b
  Author :
  Date : 2021-03-25T15:43:06
  

  Reland "EGL: GLES: Implement GL_EXT_protected_textures"
  
  This is a reland of 6210a9b34a721df2c84cf69170ad9bf7ba40e4aa
  This removes changes in gl backend.
  
  Original change's description:
  > EGL: GLES: Implement GL_EXT_protected_textures
  >
  > Implement EGL_EXT_protected_content Images
  > Add protected member to Images and Textures
  > Add error when creating objects if not supported or
  > does't match native buffer
  > When creating siblings pass protected state
  > Add extension caps
  > Add Validation
  > Add GetTexParameter and SetTextparameter
  > Add protected to Texture and state
  > Expand tests for images and textures
  >
  > Test: angle_end2end_test --gtest_filter=EGLProtectedContentTest
  >
  > Bug: angleproject:3965
  > Change-Id: I35a89b4e80bba6d9b6831c68e71630eef304dacb
  > Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2802852
  > Commit-Queue: Mohan Maiya <m.maiya@samsung.com>
  > Reviewed-by: Geoff Lang <geofflang@chromium.org>
  > Reviewed-by: Jamie Madill <jmadill@chromium.org>
  > Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
  
  Test: angle_end2end_test --gtest_filter=EGLProtectedContentTest
  
  Bug: angleproject:3965
  Change-Id: Id36d697c53afc0f0dadf92bda4565f9157f4fc2a
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/3076825
  Commit-Queue: Brandon Schade <b.schade@samsung.com>
  Reviewed-by: Ian Elliott <ianelliott@google.com>
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  

Download

• src/libANGLE/renderer/metal/ImageMtl.mm

• //
  // Copyright 2021 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  // ImageMtl.cpp:
  //    Implements the class methods for ImageMtl.
  //
  
  #include "libANGLE/renderer/metal/ImageMtl.h"
  
  #include "common/debug.h"
  #include "libANGLE/Context.h"
  #include "libANGLE/Display.h"
  #include "libANGLE/renderer/metal/ContextMtl.h"
  #include "libANGLE/renderer/metal/DisplayMtl.h"
  #include "libANGLE/renderer/metal/RenderBufferMtl.h"
  #include "libANGLE/renderer/metal/TextureMtl.h"
  
  namespace rx
  {
  
  // TextureImageSiblingMtl implementation
  TextureImageSiblingMtl::TextureImageSiblingMtl(EGLClientBuffer buffer)
      : mBuffer(buffer), mGLFormat(GL_NONE)
  {}
  
  TextureImageSiblingMtl::~TextureImageSiblingMtl() {}
  
  // Static
  bool TextureImageSiblingMtl::ValidateClientBuffer(const DisplayMtl *display, EGLClientBuffer buffer)
  {
      id<MTLTexture> texture = (__bridge id<MTLTexture>)(buffer);
      if (!texture || texture.device != display->getMetalDevice())
      {
          return false;
      }
  
      if (texture.textureType != MTLTextureType2D && texture.textureType != MTLTextureTypeCube)
      {
          return false;
      }
  
      angle::FormatID angleFormatId = mtl::Format::MetalToAngleFormatID(texture.pixelFormat);
      const mtl::Format &format     = display->getPixelFormat(angleFormatId);
      if (!format.valid())
      {
          ERR() << "Unrecognized format";
          // Not supported
          return false;
      }
  
      return true;
  }
  
  egl::Error TextureImageSiblingMtl::initialize(const egl::Display *display)
  {
      DisplayMtl *displayMtl = mtl::GetImpl(display);
      if (initImpl(displayMtl) != angle::Result::Continue)
      {
          return egl::EglBadParameter();
      }
  
      return egl::NoError();
  }
  
  angle::Result TextureImageSiblingMtl::initImpl(DisplayMtl *displayMtl)
  {
      mNativeTexture = mtl::Texture::MakeFromMetal((__bridge id<MTLTexture>)(mBuffer));
  
      angle::FormatID angleFormatId =
          mtl::Format::MetalToAngleFormatID(mNativeTexture->pixelFormat());
      mFormat = displayMtl->getPixelFormat(angleFormatId);
  
      mGLFormat = gl::Format(mFormat.intendedAngleFormat().glInternalFormat);
  
      mRenderable = mFormat.getCaps().depthRenderable || mFormat.getCaps().colorRenderable;
  
      mTextureable = mFormat.getCaps().filterable || mFormat.hasDepthOrStencilBits();
  
      return angle::Result::Continue;
  }
  
  void TextureImageSiblingMtl::onDestroy(const egl::Display *display)
  {
      mNativeTexture = nullptr;
  }
  
  gl::Format TextureImageSiblingMtl::getFormat() const
  {
      return mGLFormat;
  }
  
  bool TextureImageSiblingMtl::isRenderable(const gl::Context *context) const
  {
      return mRenderable;
  }
  
  bool TextureImageSiblingMtl::isTexturable(const gl::Context *context) const
  {
      return mTextureable;
  }
  
  gl::Extents TextureImageSiblingMtl::getSize() const
  {
      return mNativeTexture ? mNativeTexture->sizeAt0() : gl::Extents(0, 0, 0);
  }
  
  size_t TextureImageSiblingMtl::getSamples() const
  {
      uint32_t samples = mNativeTexture ? mNativeTexture->samples() : 0;
      return samples > 1 ? samples : 0;
  }
  
  bool TextureImageSiblingMtl::isYUV() const
  {
      // NOTE(hqle): not supporting YUV image yet.
      return false;
  }
  
  bool TextureImageSiblingMtl::hasProtectedContent() const
  {
      return false;
  }
  
  // ImageMtl implementation
  ImageMtl::ImageMtl(const egl::ImageState &state, const gl::Context *context) : ImageImpl(state) {}
  
  ImageMtl::~ImageMtl() {}
  
  void ImageMtl::onDestroy(const egl::Display *display)
  {
      mNativeTexture = nullptr;
  }
  
  egl::Error ImageMtl::initialize(const egl::Display *display)
  {
      if (mState.target == EGL_METAL_TEXTURE_ANGLE)
      {
          const TextureImageSiblingMtl *externalImageSibling =
              GetImplAs<TextureImageSiblingMtl>(GetAs<egl::ExternalImageSibling>(mState.source));
  
          mNativeTexture = externalImageSibling->getTexture();
  
          switch (mNativeTexture->textureType())
          {
              case MTLTextureType2D:
                  mImageTextureType = gl::TextureType::_2D;
                  break;
              case MTLTextureTypeCube:
                  mImageTextureType = gl::TextureType::CubeMap;
                  break;
              default:
                  UNREACHABLE();
          }
  
          mImageLevel = 0;
          mImageLayer = 0;
      }
      else
      {
          UNREACHABLE();
          return egl::EglBadAccess();
      }
  
      return egl::NoError();
  }
  
  angle::Result ImageMtl::orphan(const gl::Context *context, egl::ImageSibling *sibling)
  {
      if (sibling == mState.source)
      {
          mNativeTexture = nullptr;
      }
  
      return angle::Result::Continue;
  }
  
  }  // namespace rx
  

Download