kc3-lang/angle/src/libANGLE/renderer/d3d/d3d9/shaders/Blit.ps

• Show log

  Commit

• Hash : 9d737966
  Author :
  Date : 2019-08-14T12:25:12
  

  Standardize copyright notices to project style
  
  For all "ANGLE Project" copyrights, standardize to the format specified
  by the style guide. Changes:
  - "Copyright (c)" and "Copyright(c)" changed to just "Copyright".
  - Removed the second half of date ranges ("Y1Y1-Y2Y2"->"Y1Y1").
  - Fixed a small number of files that had no copyright date using the
    initial commit year from the version control history.
  - Fixed one instance of copyright being "The ANGLE Project" rather than
    "The ANGLE Project Authors"
  
  These changes are applied both to the copyright of source file, and
  where applicable to copyright statements that are generated by
  templates.
  
  BUG=angleproject:3811
  
  Change-Id: I973dd65e4ef9deeba232d5be74c768256a0eb2e5
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/1754397
  Commit-Queue: Jamie Madill <jmadill@chromium.org>
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  

Download

• src/libANGLE/renderer/d3d/d3d9/shaders/Blit.ps

• //
  // Copyright 2012 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  
  sampler2D tex : s0;
  
  uniform float4 mult : c0;
  uniform float4 add  : c1;
  
  // Passthrough Pixel Shader
  // Outputs texture 0 sampled at texcoord 0.
  float4 passthroughps(float4 texcoord : TEXCOORD0) : COLOR
  {
      return tex2D(tex, texcoord.xy);
  };
  
  // Luminance Conversion Pixel Shader
  // Performs a mad operation using the LA data from the texture with mult.xw and add.xw.
  // Returns data in the form of llla
  float4 luminanceps(float4 texcoord : TEXCOORD0) : COLOR
  {
      return (tex2D(tex, texcoord.xy).xw * mult.xw + add.xw).xxxy;
  };
  
  float4 luminancepremultps(float4 texcoord : TEXCOORD0) : COLOR
  {
      float4 luma = tex2D(tex, texcoord.xy).xxxw;
      luma.rgb *= luma.a;
      return luma * mult + add;
  };
  
  float4 luminanceunmultps(float4 texcoord : TEXCOORD0) : COLOR
  {
      float4 luma = tex2D(tex, texcoord.xy).xxxw;
      if (luma.a > 0.0f)
      {
          luma.rgb /= luma.a;
      }
      return luma * mult + add;
  };
  
  // RGB/A Component Mask Pixel Shader
  // Performs a mad operation using the texture's RGBA data with mult.xyzw and add.xyzw.
  // Returns data in the form of rgba
  float4 componentmaskps(float4 texcoord : TEXCOORD0) : COLOR
  {
      return tex2D(tex, texcoord.xy) * mult + add;
  };
  
  float4 componentmaskpremultps(float4 texcoord : TEXCOORD0) : COLOR
  {
      float4 color = tex2D(tex, texcoord.xy);
      color.rgb *= color.a;
      return color * mult + add;
  };
  
  float4 componentmaskunmultps(float4 texcoord : TEXCOORD0) : COLOR
  {
      float4 color =  tex2D(tex, texcoord.xy);
      if (color.a > 0.0f)
      {
          color.rgb /= color.a;
      }
      return color * mult + add;
  };
  

Download