kc3-lang/angle/third_party/OpenCL-ICD-Loader/BUILD.gn

• Show log

  Commit

• Hash : afed1224
  Author :
  Date : 2024-03-04T16:17:37
  

  CL: Add CTS build to ANGLE
  
  * CTS Build is done automatically if angle_enable_vulkan and
  angle_enable_cl flags are set along with angle_enable_cl_testing flag
  * Updates ICD Loader source set to include ICD dispatch files
  
  Bug: angleproject:8540
  Change-Id: I6ccebb3279e0d2798703b3ec783ff54eabe57452
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/5350744
  Commit-Queue: Yuly Novikov <ynovikov@chromium.org>
  Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
  Reviewed-by: Geoff Lang <geofflang@chromium.org>
  

Download

• third_party/OpenCL-ICD-Loader/BUILD.gn

• # Copyright 2021 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  
  import("//gni/angle.gni")
  
  config("opencl_icd_loader_config") {
    include_dirs = [ "src/loader" ]
  }
  
  source_set("opencl_icd_loader") {
    sources = [
      "src/loader/icd.c",
      "src/loader/icd_dispatch.c",
      "src/loader/icd_dispatch_generated.c",
    ]
    defines = [
      "CL_TARGET_OPENCL_VERSION=300",
      "OPENCL_ICD_LOADER_DISABLE_OPENCLON12",
    ]
  
    if (is_win) {
      sources += [
        "src/loader/windows/icd_windows.c",
        "src/loader/windows/icd_windows_apppackage.cpp",
        "src/loader/windows/icd_windows_dxgk.c",
        "src/loader/windows/icd_windows_envvars.c",
        "src/loader/windows/icd_windows_hkr.c",
      ]
  
      configs -= [ "//build/config/win:lean_and_mean" ]
      libs = [ "cfgmgr32.lib" ]
  
      if (is_clang) {
        cflags = [ "-Wno-incompatible-pointer-types" ]
      } else {
        cflags = [ "/wd4133" ]
      }
    } else {
      sources += [
        "src/loader/linux/icd_linux.c",
        "src/loader/linux/icd_linux_envvars.c",
      ]
      include_dirs = [ "." ]
  
      if (is_android) {
        cflags = [ "-Wno-#pragma-messages" ]
      } else {
        defines += [ "HAVE_SECURE_GETENV" ]
      }
    }
  
    configs -= [ "//build/config/compiler:chromium_code" ]
    configs += [ "//build/config/compiler:no_chromium_code" ]
  
    public_configs = [ ":opencl_icd_loader_config" ]
    public_deps = [ "$angle_root:cl_includes" ]
  }
  

Download