BUILD.gn

Show log
Commit

Hash : c5a4aaab
Author :
Date : 2025-08-21T12:34:30

Roll chromium_revision c57f111ea1..fc7a6f6aa1 (1504489:1504499)

This includes fixes to several breakages:
1. Change siso path in DEPS due to
https://chromium-review.googlesource.com/c/chromium/src/+/6864442
2. For unknown reason, "gclient sync --deps=all" no longer downloads mac
   dependencies on linux. Change conditions for buildtools/mac and
   others from host_os to checkout_mac, so that roll_chromium_deps can
   process these dependencies.
3. Remove third_party/googletest (BUILD.gn) submodule and copy build
   files from Chromium verbatim. Then add third_party/googletest/src
   submodule, which was previously added via recursedeps. This is
   because old structure had to be updated manually, and now we can
   autoroll googletest. Making this change now, because is_nacl was
   removed in
https://chromium-review.googlesource.com/c/chromium/src/+/6857278
   but the corresponding removal from BUILD.gn
https://chromium-review.googlesource.com/c/chromium/src/+/6723712
   didn't get rolled in due to crbug.com/440040381.
   Also roll googletest sources while at it.
https://chromium.googlesource.com/external/github.com/google/googletest/+log/c67de117379f4d1c889c7581a0a76aa0979c2083..244cec869d12e53378fa0efb610cd4c32a454ec8
4. Use "use_clang_modules = false" to suppress missing includes in LLVM.
5. Add "tools/win" dependency needed for abseil-cpp after
https://chromium-review.googlesource.com/c/chromium/src/+/6857983

Change log: https://chromium.googlesource.com/chromium/src/+log/c57f111ea1..fc7a6f6aa1
Full diff: https://chromium.googlesource.com/chromium/src/+/c57f111ea1..fc7a6f6aa1

Changed dependencies
* buildtools/mac: git_revision:cc7c61e105fb56183fd6c5c52bbe3c37ff724a0d..git_revision:ee5b7e32b961a9da1933e9f46a018ba6cac8ef60
* buildtools/win: git_revision:cc7c61e105fb56183fd6c5c52bbe3c37ff724a0d..git_revision:ee5b7e32b961a9da1933e9f46a018ba6cac8ef60
* testing: https://chromium.googlesource.com/chromium/src/testing/+log/fb889d0363..62256178de
* third_party/abseil-cpp: https://chromium.googlesource.com/chromium/src/third_party/abseil-cpp/+log/1e18dc54a0..4862f4f12d
* third_party/android_build_tools: https://chromium.googlesource.com/chromium/src/third_party/android_build_tools/+log/f43e2cc47f..d48cf42075
* third_party/android_build_tools/error_prone/cipd: wQ_Wsj0aINAwt4LrHHM6IEnMhVEAdvQtBFtLv7YL4PoC..vPi1VfStH9EQCdbZI5NAMcK7C_dWs3-8Frr1CAzIafEC
* third_party/android_build_tools/lint/cipd: XO6ykSsPN632w1Hwz4YCLW0qC1KhVCn53F8FdJeuhKUC..8i-9CpSofgFA-RhKjreXIK0ZbDC8IhGVe2yvxRX0ku4C
* third_party/android_build_tools/nullaway/cipd: mFkUqdlIqmMQ3rAaTHFmOBYjNFgFUQOmMlPG6PGgmHYC..Zk_ffB0B6qGrr2ZDKqCxAgnPmo4-5giVRIauRffZaZYC
* third_party/android_deps: https://chromium.googlesource.com/chromium/src/third_party/android_deps/+log/973ea8c7c6..8f103008c5
* third_party/android_sdk: https://chromium.googlesource.com/chromium/src/third_party/android_sdk/+log/e71ef403c5..f1c6b36cde
* third_party/catapult: https://chromium.googlesource.com/catapult.git/+log/8dc29cff6c..8512c34797
* third_party/depot_tools: https://chromium.googlesource.com/chromium/tools/depot_tools.git/+log/eddc72dce5..778a576e20
* third_party/fuchsia-sdk/sdk: version:29.20250730.5.1..version:29.20250815.6.1
* third_party/libc++/src: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxx.git/+log/6f8fe913d6..91206b4d03
* third_party/libc++abi/src: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxxabi.git/+log/a6c815c69d..f7f5a32b3e
* third_party/libunwind/src: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libunwind.git/+log/84c5262b57..bdc00ca63e
* third_party/llvm-libc/src: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libc.git/+log/82c07b9654..46fede94c0
* third_party/protobuf: https://chromium.googlesource.com/chromium/src/third_party/protobuf/+log/78c1ca719e..28e24a669f
* third_party/r8/cipd: qD5apdNjxRv3dBblf27nEZYf7r_pbLEgfN7hWyXvP_UC..Xyh7Kdh-M2Dj5lwFGH2QRe7TFErRgYCvMFMkPiYnIwsC
* third_party/r8/d8/cipd: qD5apdNjxRv3dBblf27nEZYf7r_pbLEgfN7hWyXvP_UC..pBaBgtFdvclLMBwz1H7s88bhc3ioF8iEyFh6rZ81054C
* third_party/re2/src: https://chromium.googlesource.com/external/github.com/google/re2.git/+log/85c7c0fb11..6569a9a3df
* third_party/rust: https://chromium.googlesource.com/chromium/src/third_party/rust/+log/5de5e7b6ba..cc36abecbc
* third_party/turbine/cipd: TkTaFqF4Bs-JmFtxFV_Nfh4u5jh_401ZQsLhC7vIEqQC..9ZS5YYFBth7RSqNe7VLip-qJhk00WoicV_Qb0byHna8C
* third_party/zlib: https://chromium.googlesource.com/chromium/src/third_party/zlib/+log/363a126ed2..044b44e6de
* tools/android: https://chromium.googlesource.com/chromium/src/tools/android/+log/b44ad70ef5..7d8848041e
* tools/clang: https://chromium.googlesource.com/chromium/src/tools/clang.git/+log/9d91ec919b..f10114ce19
* tools/luci-go: git_revision:2aa8d904a9f8cc8891d2710e4cf58156057fa4b3..git_revision:230495e01666a7468ff6803179519a5c93317083
* tools/luci-go: git_revision:2aa8d904a9f8cc8891d2710e4cf58156057fa4b3..git_revision:230495e01666a7468ff6803179519a5c93317083
* tools/luci-go: git_revision:2aa8d904a9f8cc8891d2710e4cf58156057fa4b3..git_revision:230495e01666a7468ff6803179519a5c93317083
* tools/mb: https://chromium.googlesource.com/chromium/src/tools/mb/+log/c5719eb114..513bc2117e
* tools/perf: https://chromium.googlesource.com/chromium/src/tools/perf/+log/c1a26b544f..88de4dbaab
* tools/rust: https://chromium.googlesource.com/chromium/src/tools/rust.git/+log/fa1df48579..f2fba99158
* tools/skia_goldctl/linux: 84tAKAqEtqjebJywg8jyXDWUVodNBYZraFt9RZ0A2pwC..46Onf_f3s_Mr84pViZFnexVYU47ArSn3knDqNZcIoYsC
* tools/skia_goldctl/mac_amd64: dpgLOuWsqpBYSIj44DbnlJD7fnp640TD4cprUlwV0VMC..itdWmANhuoNsgIG1DuIe7XMdwQR4Vc9kkznuHSuPOekC
* tools/skia_goldctl/mac_arm64: AU5OTil4VjYO94g8-Jhq02qBoLka6t-JsgKKEzllcy8C..aFRLGxnuqC86Y3ejs72PnkJfG0caCnrl72QiuxJ1XbkC
* tools/skia_goldctl/win: DW55Ki0OZtTTzxrsItNbFeB9IDA9GBVXB647W6SOLN4C..sYuoNL-siny-CypUt4LuqE25k1hWho4rLa3T7ikBQAoC
DEPS diff: https://chromium.googlesource.com/chromium/src/+/c57f111ea1..fc7a6f6aa1/DEPS

No update to Clang.

Bug: chromium:440040381, angleproject:40041909, angleproject:439777063
Change-Id: Id814e849a08a1533c246ed9d1803f8b7c90fa68b
Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/6870430
Reviewed-by: Geoff Lang <geofflang@chromium.org>
Auto-Submit: Yuly Novikov <ynovikov@chromium.org>
Commit-Queue: Geoff Lang <geofflang@chromium.org>

Download

third_party/googletest/BUILD.gn

# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build_overrides/build.gni")

config("gtest_config") {
  # webrtc wants to push this config without a public_dep chain
  # TODO(crbug.com/1249254): figure out what to do with this
  visibility = [
    ":*",  # gmock also shares this config.
    "//test:*",  # webrts standalone setup
    "//third_party/webrtc/test:*",
  ]

  defines = [
    # Chromium always links googletest statically, so no API qualifier is
    # necessary. The definition in gtest-port.h at the time of this writing
    # causes crashes in content_browsertests.
    "GTEST_API_=",

    # In order to allow regex matches in gtest to be shared between Windows
    # and other systems, we tell gtest to always use its internal engine.
    "GTEST_HAS_POSIX_RE=0",

    # Use Abseil, but without flags support: Abseil flags uses the
    # `FastTypeId<T>()` pattern internally, which is known to be broken in
    # subtle ways in the component build.
    "GTEST_HAS_ABSL",
    "GTEST_NO_ABSL_FLAGS",
  ]

  # Gtest headers need to be able to find themselves.
  include_dirs = [
    "custom",
    "src/googletest/include",
  ]

  if (is_win) {
    cflags = [ "/wd4800" ]  # Unused variable warning.
  }

  configs = [
    "//third_party/abseil-cpp:absl_include_config",
    "//third_party/re2:re2_config",
  ]
}

config("gmock_config") {
  # Gmock headers need to be able to find themselves.
  include_dirs = [
    "custom",
    "src/googlemock/include",
  ]

  if (is_clang) {
    # TODO(crbug.com/40616204): remove this when we migrated to new MOCK_METHOD
    # macro.
    # ref: https://google.github.io/googletest/gmock_cook_book.html#old-style-mock_methodn-macros
    cflags = [ "-Wno-inconsistent-missing-override" ]
  }
}

# Do NOT depend on this directly. Use //testing/gtest instead.
# See README.chromium for details.
source_set("gtest") {
  testonly = true
  sources = [
    "custom/gtest/internal/custom/gtest.h",
    "custom/gtest/internal/custom/stack_trace_getter.cc",
    "custom/gtest/internal/custom/stack_trace_getter.h",

    # TODO(crbug.com/1009553): Remove this wrapper and custom temp dir
    # after plumbing a workable temporary path into googletest on Android.
    "custom/gtest/internal/custom/chrome_custom_temp_dir.cc",
    "custom/gtest/internal/custom/chrome_custom_temp_dir.h",
    "custom/gtest/internal/custom/gtest_port_wrapper.cc",
    "src/googletest/include/gtest/gtest-assertion-result.h",
    "src/googletest/include/gtest/gtest-death-test.h",
    "src/googletest/include/gtest/gtest-matchers.h",
    "src/googletest/include/gtest/gtest-message.h",
    "src/googletest/include/gtest/gtest-param-test.h",
    "src/googletest/include/gtest/gtest-printers.h",
    "src/googletest/include/gtest/gtest-spi.h",
    "src/googletest/include/gtest/gtest-test-part.h",
    "src/googletest/include/gtest/gtest-typed-test.h",
    "src/googletest/include/gtest/gtest.h",
    "src/googletest/include/gtest/gtest_pred_impl.h",
    "src/googletest/include/gtest/gtest_prod.h",

    #"src/googletest/include/gtest/internal/custom/gtest.h",  # Superseded.
    "src/googletest/include/gtest/internal/custom/gtest-port.h",
    "src/googletest/include/gtest/internal/custom/gtest-printers.h",
    "src/googletest/include/gtest/internal/gtest-death-test-internal.h",
    "src/googletest/include/gtest/internal/gtest-filepath.h",
    "src/googletest/include/gtest/internal/gtest-internal.h",
    "src/googletest/include/gtest/internal/gtest-param-util.h",
    "src/googletest/include/gtest/internal/gtest-port-arch.h",
    "src/googletest/include/gtest/internal/gtest-port.h",
    "src/googletest/include/gtest/internal/gtest-string.h",
    "src/googletest/include/gtest/internal/gtest-type-util.h",

    #"src/googletest/src/gtest-all.cc",  # Not needed by our build.
    "src/googletest/src/gtest-assertion-result.cc",
    "src/googletest/src/gtest-death-test.cc",
    "src/googletest/src/gtest-filepath.cc",
    "src/googletest/src/gtest-internal-inl.h",
    "src/googletest/src/gtest-matchers.cc",

    # gtest_port_wrapper.cc is used instead of gtest-port.cc.
    # TODO(crbug.com/1009553): Re-enable this file after plumbing a workable
    #                          temporary path into googletest on Android.
    #"src/googletest/src/gtest-port.cc",
    "src/googletest/src/gtest-printers.cc",
    "src/googletest/src/gtest-test-part.cc",
    "src/googletest/src/gtest-typed-test.cc",
    "src/googletest/src/gtest.cc",
  ]

  # Some files include "src/gtest-internal-inl.h".
  include_dirs = [ "src/googletest" ]

  public_configs = [ ":gtest_config" ]

  configs -= [ "//build/config/compiler:chromium_code" ]
  configs += [ "//build/config/compiler:no_chromium_code" ]

  defines = []

  # googletest only needs `absl`, but this makes gn check happier.
  deps = [ "//third_party/abseil-cpp:absl_full" ]
  public_deps = [ "//third_party/re2" ]
  if (!build_with_chromium) {
    defines += [ "GTEST_DISABLE_PRINT_STACK_TRACE" ]
    sources -= [
      "custom/gtest/internal/custom/stack_trace_getter.cc",
      "custom/gtest/internal/custom/stack_trace_getter.h",
    ]
  } else {
    deps += [ "//base" ]
  }

  if (is_fuchsia) {
    deps += [
      "//third_party/fuchsia-sdk/sdk/pkg/fdio",
      "//third_party/fuchsia-sdk/sdk/pkg/zx",
    ]
  }
}

# Do NOT depend on this directly. Use //testing/gtest:gtest_main instead.
# See README.chromium for details.
source_set("gtest_main") {
  testonly = true
  sources = [ "src/googletest/src/gtest_main.cc" ]
  deps = [ ":gtest" ]
}

# Do NOT depend on this directly. Use //testing/gmock instead.
# See README.chromium for details.
source_set("gmock") {
  testonly = true
  sources = [
    "src/googlemock/include/gmock/gmock-actions.h",
    "src/googlemock/include/gmock/gmock-cardinalities.h",
    "src/googlemock/include/gmock/gmock-function-mocker.h",
    "src/googlemock/include/gmock/gmock-matchers.h",
    "src/googlemock/include/gmock/gmock-more-matchers.h",
    "src/googlemock/include/gmock/gmock-nice-strict.h",
    "src/googlemock/include/gmock/gmock-spec-builders.h",
    "src/googlemock/include/gmock/gmock.h",

    #"src/googlemock/include/gmock/internal/custom/gmock-port.h",  # Superseded.
    "src/googlemock/include/gmock/internal/custom/gmock-generated-actions.h",
    "src/googlemock/include/gmock/internal/custom/gmock-matchers.h",
    "src/googlemock/include/gmock/internal/gmock-internal-utils.h",
    "src/googlemock/include/gmock/internal/gmock-port.h",
    "src/googlemock/include/gmock/internal/gmock-pp.h",

    #"src/googlemock/src/gmock-all.cc",  # Not needed by our build.
    "src/googlemock/src/gmock-cardinalities.cc",
    "src/googlemock/src/gmock-internal-utils.cc",
    "src/googlemock/src/gmock-matchers.cc",
    "src/googlemock/src/gmock-spec-builders.cc",
    "src/googlemock/src/gmock.cc",
  ]

  # googlemock only needs `absl`, but this makes gn check happier.
  deps = [ "//third_party/abseil-cpp:absl_full" ]

  public_deps = [ ":gtest" ]
  public_configs = [ ":gmock_config" ]
}

# Do NOT depend on this directly. Use //testing/gmock:gmock_main instead.
# See README.chromium for details.
static_library("gmock_main") {
  testonly = true
  sources = [ "src/googlemock/src/gmock_main.cc" ]
  deps = [ ":gmock" ]
}

Download