kc3-lang/angle/third_party/BUILD.gn

• Show log

  Commit

• Hash : 58afe4cb
  Author :
  Date : 2020-07-08T06:06:49
  

  Remove angle_libjpeg_turbo_dir fallback after Chromium side fix
  
  This is a follow up of crrev.com/c/2282277. To avoid ANGLE roll failure,
  crrev.com/c/2285839 should be landed first.
  
  Bug: None
  Change-Id: I41ece21af4b689150d82b0b1bc7eaae21ce23fed
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2286811
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  Commit-Queue: Jiajie Hu <jiajie.hu@intel.com>
  

Download

• third_party/BUILD.gn

• # Copyright 2019 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  #
  # See:
  # https://chromium.googlesource.com/chromium/src/+/master/third_party/BUILD.gn
  
  import("//build_overrides/angle.gni")
  import("//third_party/libjpeg.gni")
  
  assert(!is_ios, "This is not used on iOS, don't drag it in unintentionally")
  
  config("system_libjpeg_config") {
    libs = [ "jpeg" ]
    defines = [ "USE_SYSTEM_LIBJPEG" ]
  }
  
  config("libjpeg_turbo_config") {
    defines = [ "USE_LIBJPEG_TURBO=1" ]
  }
  
  # This is a meta target that forwards to the system's libjpeg,
  # third_party/libjpeg, or third_party/libjpeg_turbo depending on the build args
  # declared in this file.
  group("jpeg") {
    if (use_system_libjpeg) {
      public_configs = [ ":system_libjpeg_config" ]
    } else if (use_libjpeg_turbo) {
      public_deps = [ "$angle_libjpeg_turbo_dir:libjpeg" ]
      public_configs = [ ":libjpeg_turbo_config" ]
    } else {
      public_deps = [ "//third_party/libjpeg:libjpeg" ]
    }
  }
  
  # This is a meta target that forwards include paths only to the system's
  # libjpeg, third_party/libjpeg, or third_party/libjpeg_turbo depending on the
  # build args declared in this file. This is needed, rarely, for targets that
  # need to reference libjpeg without explicitly building it.
  group("jpeg_includes") {
    if (use_system_libjpeg) {
      public_configs = [ ":system_libjpeg_config" ]
    } else if (use_libjpeg_turbo) {
      public_configs = [ "$angle_libjpeg_turbo_dir:libjpeg_config" ]
    } else {
      public_configs = [ "//third_party/libjpeg:libjpeg_config" ]
    }
  }
  

Download