flatbuffer.gni

Show log
Commit

Hash : a48a2c7a
Author :
Date : 2022-11-02T18:04:35

Roll Chromium from c8d10c0b09ab to 2c98c5af6539 (5653 revisions)

Manually copying third_party/flatbuffers from Chromium,
with one small modification:
  libs = [ "log" ]
in "flatbuffers_unittests" BUILD.gn

Also, forcing MSVC builds to use C++17 instead of C++20.

https://chromium.googlesource.com/chromium/src.git/+log/c8d10c0b09ab..2c98c5af6539

If this roll has caused a breakage, revert this CL and stop the roller
using the controls here:
https://autoroll.skia.org/r/chromium-angle-autoroll
Please CC syoussefi@google.com,ynovikov@google.com on the revert to ensure that a human
is aware of the problem.

To file a bug in Chromium: https://bugs.chromium.org/p/chromium/issues/entry
To file a bug in ANGLE: https://bugs.chromium.org/p/angleproject/issues/entry

To report a problem with the AutoRoller itself, please file a bug:
https://bugs.chromium.org/p/skia/issues/entry?template=Autoroller+Bug

Documentation for the AutoRoller is here:
https://skia.googlesource.com/buildbot/+doc/main/autoroll/README.md

Changed dependencies
* build: https://chromium.googlesource.com/chromium/src/build.git/+log/ef3d15e613..f75f7c9503
* buildtools: https://chromium.googlesource.com/chromium/src/buildtools.git/+log/5c1eeb8715..33b52eafd5
* buildtools/linux64: git_revision:57c352b2b03461c24b19c678c61d7aeacc6981f4..git_revision:a4d67be044b42963de801001e7146f9657c7fad4
* buildtools/mac: git_revision:57c352b2b03461c24b19c678c61d7aeacc6981f4..git_revision:a4d67be044b42963de801001e7146f9657c7fad4
* buildtools/third_party/libc++/trunk: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxx.git/+log/888eff8ec2..fc6bbc5eb0
* buildtools/third_party/libc++abi/trunk: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxxabi.git/+log/685c4ad257..8dd405113a
* buildtools/third_party/libunwind/trunk: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libunwind.git/+log/1f633d41a0..aabcd87536
* buildtools/win: git_revision:57c352b2b03461c24b19c678c61d7aeacc6981f4..git_revision:a4d67be044b42963de801001e7146f9657c7fad4
* testing: https://chromium.googlesource.com/chromium/src/testing/+log/50f814ce03..1a1a839b38
* third_party/Python-Markdown: https://chromium.googlesource.com/chromium/src/third_party/Python-Markdown/+log/872ba9e68a..4838827d12
* third_party/abseil-cpp: https://chromium.googlesource.com/chromium/src/third_party/abseil-cpp/+log/3027824279..8fb5a04597
* third_party/android_build_tools: https://chromium.googlesource.com/chromium/src/third_party/android_build_tools/+log/4f07dd5cca..216373bd26
* third_party/android_build_tools/bundletool: sSBNyeRs5Px7nKXDLyQpz24T_OV9_rUkzqgXRNEaH0kC..JUxLsQLBkNG0ylmbHz6FGBtYyK1PNDZ04pMCii90Bd4C
* third_party/android_build_tools/lint: PgXTfxO_ExRhHwuAVaMUh48zDVj5bqVPSjecGWZ8TQIC..oJIo5mCU1gyxTf-EnMPZXg_GG2-3YOE_xUWXtmwO96IC
* third_party/android_build_tools/manifest_merger: lgqr-qkYSNJxPdYaRg1beYU6to-4LBuHBw3WVO7_ancC..xd-wXGBtd-G1FJXc_owo3j_wxWs4YxgOfQ-tKWHwN5AC
* third_party/android_deps: https://chromium.googlesource.com/chromium/src/third_party/android_deps/+log/94f1169192..e8b385d860
* third_party/catapult: https://chromium.googlesource.com/catapult.git/+log/{catapult_..3ffa6b2228
* third_party/depot_tools: https://chromium.googlesource.com/chromium/tools/depot_tools.git/+log/64b6175557..1adbbff2c0
* third_party/fuchsia-sdk/sdk: version:10.20221018.0.1..version:10.20221102.0.1
* third_party/jinja2: https://chromium.googlesource.com/chromium/src/third_party/jinja2/+log/ee69aa00ee..4633bf4311
* third_party/markupsafe: https://chromium.googlesource.com/chromium/src/third_party/markupsafe/+log/1b882ef637..13f4e8c9e2
* third_party/nasm: https://chromium.googlesource.com/chromium/deps/nasm.git/+log/5fd9246276..fc8e0bd892
* third_party/r8/d8: 9PJITrOEIl2U8mvr44d5e9XjOdvzRPuF774VA3jWOsYC..qGtBu6TtxyR5XNy4cmsslb7c946YtkZF5_QCjVP-wc8C
* third_party/turbine: rrpgWQ-uylo8c5IPgUVP464LwcVOmt29MqwsR59O_zkC..HqLybI_r3dCgRJywsqJ3xkp2D6vQAI4-8D7zdqNiyxcC
* third_party/zlib: https://chromium.googlesource.com/chromium/src/third_party/zlib/+log/d689fca54d..cff720848d
* tools/clang: https://chromium.googlesource.com/chromium/src/tools/clang.git/+log/2619cde247..b147cbb71c
* tools/luci-go: git_revision:0b4ca85948120a9e07c81e06386c031a693724c4..git_revision:765f51c332c38e9b8d7981f23640b9df59371cd5
* tools/luci-go: git_revision:0b4ca85948120a9e07c81e06386c031a693724c4..git_revision:765f51c332c38e9b8d7981f23640b9df59371cd5
* tools/mb: https://chromium.googlesource.com/chromium/src/tools/mb/+log/cac69ccc90..88b5767779
* tools/md_browser: https://chromium.googlesource.com/chromium/src/tools/md_browser/+log/7ff27244f2..de79b55b74
* tools/memory: https://chromium.googlesource.com/chromium/src/tools/memory/+log/98140a6948..8581381d92
* tools/perf: https://chromium.googlesource.com/chromium/src/tools/perf/+log/7ab82e1fdc..fe7aa52821
* tools/skia_goldctl/linux: t3TPrZYHYFYj-Uycz4891UuvI29G25cnOuAXx4YKTJEC..96rKSNFMICaC-zy3dzFRxE3xkMm8mIPbR6pxbfHXZysC
* tools/skia_goldctl/mac_amd64: pkodJRDmOHJK-oKhKr3YyRBH-aZDOifqq2f39tyYYkwC..BTXwaBdnwpgPkzCAT5gTk0xV0_vzeR2q_icN_le7NBIC
* tools/skia_goldctl/mac_arm64: MGH9P0-cwU4UFOV-4rkxKLBFEVtXIE8vtynMsKM4O4UC..r0TJJDCO6SDuVGZoUBvAzDe7hACLXwX3fWH6tvNkYAAC
* tools/skia_goldctl/win: -y4QQFDzRbkTKhmiP7CqEhagCHKtWFdfxwAK6anUvfAC..IffTHOl24SBx-1fnxVM5kaNaOA8mS_3urxANjmbsZWUC
Clang version changed llvmorg-16-init-7184-gdeb82d4a:llvmorg-16-init-9369-g87a20868
Details: https://chromium.googlesource.com/chromium/src/tools/clang/+/2619cde247bf037c2afa19b0913cccddac12ccbd..b147cbb71c13c6fec5da3d91b99f3a408c5eb07c/scripts/update.py

Bug: angleproject:4242,angleproject:4417,angleproject:4846,angleproject:5505,angleproject:6430
Bug: angleproject:7788, chromium:1380553
Tbr: syoussefi@google.com,ynovikov@google.com
Change-Id: Ia1f563f1dc5227b2cbb42ac05f5f7f40e47a4168
Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/4000540
Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
Commit-Queue: Yuly Novikov <ynovikov@chromium.org>

Download

third_party/flatbuffers/flatbuffer.gni

# Copyright 2016 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Compile a flatbuffer.
#
#   flatc_out_dir (optional)
#       Specifies the path suffix that output files are generated under. This
#       path will be appended to root_gen_dir.
#
#       Targets that depend on the flatbuffer target will be able to include
#       the resulting FlatBuffers header with an include like:
#         #include "dir/for/my_flatbuffer/buffer_generated.h"
#       If undefined, this defaults to matchign the input directory for each
#       .fbs file (you should almost always use the default mode).
#
#   flatc_include_dirs (optional)
#       Specifies the directories which FlatBuffers compiler uses to find
#       included .fbs files in. Almost always should be empty.
#
#       The list always has an implicit first item corresponding to the root of
#       the source tree. This enables including .fbs files by absolute path.
#
#       The compiler will try the directories in the order given, and if all
#       fail it will try to load relative to the directory of the schema file
#       being parsed.
#
#   mutable (optional)
#       Boolean to compile flatbuffers with the "--gen-mutable" argument, which
#       generates non-const accessors for mutating FlatBuffers in-place.
#
#   deps (optional)
#       Additional dependencies.
#
# Parameters for compiling the generated code:
#
#   defines (optional)
#       Defines to supply to the source set that compiles the generated source
#       code.
#
#   extra_configs (optional)
#       A list of config labels that will be appended to the configs applying
#       to the source set.
#
#   testonly (optional)
#       Boolean to indicate whether the generated source sets should be labeled
#       as testonly.
#
# Example:
#  flatbuffer("mylib") {
#    sources = [
#      "foo.fbs",
#    ]
#  }

import("//build/compiled_action.gni")

template("flatbuffer") {
  assert(defined(invoker.sources), "Need sources for flatbuffers_library")

  action_name = "${target_name}_gen"
  source_set_name = target_name
  compiled_action_foreach(action_name) {
    visibility = [ ":$source_set_name" ]

    tool = "//third_party/flatbuffers:flatc"

    sources = invoker.sources
    deps = []

    if (defined(invoker.flatc_out_dir)) {
      out_dir = "$root_gen_dir/" + invoker.flatc_out_dir
    } else {
      out_dir = "{{source_gen_dir}}"
    }

    outputs = [ "$out_dir/{{source_name_part}}_generated.h" ]

    args = [
      "-c",
      "--keep-prefix",
      "-o",
      "$out_dir",
      "-I",
      rebase_path("//", root_build_dir),
    ]

    if (defined(invoker.flatc_include_dirs)) {
      foreach(include_dir, invoker.flatc_include_dirs) {
        args += [
          "-I",
          rebase_path(include_dir, root_build_dir),
        ]
      }
    }

    if (defined(invoker.mutable) && invoker.mutable) {
      args += [ "--gen-mutable" ]
    }

    if (defined(invoker.args)) {
      args += invoker.args
    }

    args += [ "{{source}}" ]

    # The deps may have steps that have to run before running flatc.
    if (defined(invoker.deps)) {
      deps += invoker.deps
    }
  }

  source_set(target_name) {
    forward_variables_from(invoker,
                           [
                             "visibility",
                             "defines",
                           ])

    sources = get_target_outputs(":$action_name")

    if (defined(invoker.extra_configs)) {
      configs += invoker.extra_configs
    }

    if (defined(invoker.testonly)) {
      testonly = invoker.testonly
    }

    public_configs = [ "//third_party/flatbuffers:flatbuffers_config" ]

    public_deps = [
      # The generated headers reference headers within FlatBuffers, so
      # dependencies must be able to find those headers too.
      ":$action_name",
      "//third_party/flatbuffers",
    ]

    # This will link any libraries in the deps (the use of invoker.deps in the
    # action won't link it).
    if (defined(invoker.deps)) {
      deps += invoker.deps
    }

    # Same for public_deps.
    if (defined(invoker.public_deps)) {
      public_deps += invoker.public_deps
    }
  }
}

Download