kc3-lang/automake/m4/depout.m4

• Show log

  Commit

• Hash : d21e7022
  Author :
  Date : 2008-12-21T17:33:17
  

  Fix config.status depfiles failure.
  
  * m4/depout.m4 (_AM_OUTPUT_DEPENDENCY_COMMANDS): Commands are
  again a single shell brace group, so they are correctly skipped
  when dependencies are turned off.  The failure is noisy with
  ksh only.
  * tests/depend6.test: New test.
  * tests/Makefile.am: Adjust.
  * THANKS: Update.
  Report and different suggested patch by Markus Duft.
  
  Signed-off-by: Ralf Wildenhues <Ralf.Wildenhues@gmx.de>
  

Download

• m4/depout.m4

• # Generate code to set up dependency tracking.              -*- Autoconf -*-
  
  # Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2008
  # Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  #serial 5
  
  # _AM_OUTPUT_DEPENDENCY_COMMANDS
  # ------------------------------
  AC_DEFUN([_AM_OUTPUT_DEPENDENCY_COMMANDS],
  [{
    # Autoconf 2.62 quotes --file arguments for eval, but not when files
    # are listed without --file.  Let's play safe and only enable the eval
    # if we detect the quoting.
    case $CONFIG_FILES in
    *\'*) eval set x "$CONFIG_FILES" ;;
    *)   set x $CONFIG_FILES ;;
    esac
    shift
    for mf
    do
      # Strip MF so we end up with the name of the file.
      mf=`echo "$mf" | sed -e 's/:.*$//'`
      # Check whether this is an Automake generated Makefile or not.
      # We used to match only the files named `Makefile.in', but
      # some people rename them; so instead we look at the file content.
      # Grep'ing the first line is not enough: some people post-process
      # each Makefile.in and add a new line on top of each file to say so.
      # Grep'ing the whole file is not good either: AIX grep has a line
      # limit of 2048, but all sed's we know have understand at least 4000.
      if sed -n 's,^#.*generated by automake.*,X,p' "$mf" | grep X >/dev/null 2>&1; then
        dirpart=`AS_DIRNAME("$mf")`
      else
        continue
      fi
      # Extract the definition of DEPDIR, am__include, and am__quote
      # from the Makefile without running `make'.
      DEPDIR=`sed -n 's/^DEPDIR = //p' < "$mf"`
      test -z "$DEPDIR" && continue
      am__include=`sed -n 's/^am__include = //p' < "$mf"`
      test -z "am__include" && continue
      am__quote=`sed -n 's/^am__quote = //p' < "$mf"`
      # When using ansi2knr, U may be empty or an underscore; expand it
      U=`sed -n 's/^U = //p' < "$mf"`
      # Find all dependency output files, they are included files with
      # $(DEPDIR) in their names.  We invoke sed twice because it is the
      # simplest approach to changing $(DEPDIR) to its actual value in the
      # expansion.
      for file in `sed -n "
        s/^$am__include $am__quote\(.*(DEPDIR).*\)$am__quote"'$/\1/p' <"$mf" | \
  	 sed -e 's/\$(DEPDIR)/'"$DEPDIR"'/g' -e 's/\$U/'"$U"'/g'`; do
        # Make sure the directory exists.
        test -f "$dirpart/$file" && continue
        fdir=`AS_DIRNAME(["$file"])`
        AS_MKDIR_P([$dirpart/$fdir])
        # echo "creating $dirpart/$file"
        echo '# dummy' > "$dirpart/$file"
      done
    done
  }
  ])# _AM_OUTPUT_DEPENDENCY_COMMANDS
  
  
  # AM_OUTPUT_DEPENDENCY_COMMANDS
  # -----------------------------
  # This macro should only be invoked once -- use via AC_REQUIRE.
  #
  # This code is only required when automatic dependency tracking
  # is enabled.  FIXME.  This creates each `.P' file that we will
  # need in order to bootstrap the dependency handling code.
  AC_DEFUN([AM_OUTPUT_DEPENDENCY_COMMANDS],
  [AC_CONFIG_COMMANDS([depfiles],
       [test x"$AMDEP_TRUE" != x"" || _AM_OUTPUT_DEPENDENCY_COMMANDS],
       [AMDEP_TRUE="$AMDEP_TRUE" ac_aux_dir="$ac_aux_dir"])
  ])
  

Download