kc3-lang/automake/m4/minuso.m4

• Show log

  Commit

• Hash : 26f02984
  Author :
  Date : 2008-10-05T21:49:32
  

  Work around AIX sh quoting issue in AC_PROG_CC_C_O.
  
  * m4/minuso.m4 (AM_PROG_CC_C_O): Work around shell quoting issue
  with AIX sh; fixes depcomp6.test failure.
  * NEWS, THANKS: Update.
  Report by Rainer Tammer.
  
  Signed-off-by: Ralf Wildenhues <Ralf.Wildenhues@gmx.de>
  

Download

• m4/minuso.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 1999, 2000, 2001, 2003, 2004, 2005, 2008
  # Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 6
  
  # AM_PROG_CC_C_O
  # --------------
  # Like AC_PROG_CC_C_O, but changed for automake.
  AC_DEFUN([AM_PROG_CC_C_O],
  [AC_REQUIRE([AC_PROG_CC_C_O])dnl
  AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
  AC_REQUIRE_AUX_FILE([compile])dnl
  # FIXME: we rely on the cache variable name because
  # there is no other way.
  set dummy $CC
  am_cc=`echo $[2] | sed ['s/[^a-zA-Z0-9_]/_/g;s/^[0-9]/_/']`
  eval am_t=\$ac_cv_prog_cc_${am_cc}_c_o
  if test "$am_t" != yes; then
     # Losing compiler, so override with the script.
     # FIXME: It is wrong to rewrite CC.
     # But if we don't then we get into trouble of one sort or another.
     # A longer-term fix would be to have automake use am__CC in this case,
     # and then we could set am__CC="\$(top_srcdir)/compile \$(CC)"
     CC="$am_aux_dir/compile $CC"
  fi
  dnl Make sure AC_PROG_CC is never called again, or it will override our
  dnl setting of CC.
  m4_define([AC_PROG_CC],
            [m4_fatal([AC_PROG_CC cannot be called after AM_PROG_CC_C_O])])
  ])
  

Download