kc3-lang/gnulib/m4/roundl.m4

• Show log

  Commit

• Hash : 42d1eda5
  Author :
  Date : 2009-01-13T08:48:48
  

  many *.m4 files: improve m4 quoting
  
  99% of this change was performed by running the following commands:
  git ls-files | grep '\.m4$' | xargs perl -pi \
    -e 's/(AC_\w+\()([^[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){1})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){2})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){3})([^,[()]+?)([,)])/$1\[$2]$3/g'
  perl -pi -e 's/\[\.\.\.\]/.../' m4/onceonly.m4
  
  The remainder were to add Copyright dates, increment serial numbers,
  undo some changes in comments, exclude m4/intl.m4, and add quotes
  around the "1" in ",1" where the unusual spacing prohibited the
  above regexps from doing the job.  For more details, see
  <http://thread.gmane.org/gmane.comp.lib.gnulib.bugs/16175>.
  

Download

• m4/roundl.m4

• # roundl.m4 serial 5
  dnl Copyright (C) 2007, 2009 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_ROUNDL],
  [
    AC_REQUIRE([gl_MATH_H_DEFAULTS])
    dnl Persuade glibc <math.h> to declare roundl().
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
    AC_CHECK_DECLS([roundl], , , [#include <math.h>])
    if test "$ac_cv_have_decl_roundl" = yes; then
      gl_CHECK_MATH_LIB([ROUNDL_LIBM], [x = roundl (x);])
    fi
    if test "$ac_cv_have_decl_roundl" != yes || test "$ROUNDL_LIBM" = missing; then
      REPLACE_ROUNDL=1
      AC_LIBOBJ([roundl])
      AC_CHECK_DECLS([ceill, floorl], , , [#include <math.h>])
      if test "$ac_cv_have_decl_floorl" = yes \
         && test "$ac_cv_have_decl_ceill" = yes; then
        gl_FUNC_FLOORL_LIBS
        gl_FUNC_CEILL_LIBS
        if test "$FLOORL_LIBM" != '?' && test "$CEILL_LIBM" != '?'; then
          AC_DEFINE([HAVE_FLOORL_AND_CEILL], [1],
            [Define if the both the floorl() and ceill() functions exist.])
          ROUNDL_LIBM="$FLOORL_LIBM $CEILL_LIBM"
        else
          ROUNDL_LIBM=
        fi
      else
        ROUNDL_LIBM=
      fi
    fi
    AC_SUBST([ROUNDL_LIBM])
  ])
  

Download