kc3-lang/gnulib/m4/utimbuf.m4

• Show log

  Commit

• Hash : 42d1eda5
  Author :
  Date : 2009-01-13T08:48:48
  

  many *.m4 files: improve m4 quoting
  
  99% of this change was performed by running the following commands:
  git ls-files | grep '\.m4$' | xargs perl -pi \
    -e 's/(AC_\w+\()([^[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){1})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){2})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){3})([^,[()]+?)([,)])/$1\[$2]$3/g'
  perl -pi -e 's/\[\.\.\.\]/.../' m4/onceonly.m4
  
  The remainder were to add Copyright dates, increment serial numbers,
  undo some changes in comments, exclude m4/intl.m4, and add quotes
  around the "1" in ",1" where the unusual spacing prohibited the
  above regexps from doing the job.  For more details, see
  <http://thread.gmane.org/gmane.comp.lib.gnulib.bugs/16175>.
  

Download

• m4/utimbuf.m4

• # serial 9
  
  # Copyright (C) 1998-2001, 2003-2004, 2007, 2009 Free Software
  # Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  dnl From Jim Meyering
  
  dnl Define HAVE_STRUCT_UTIMBUF if `struct utimbuf' is declared --
  dnl usually in <utime.h>.
  dnl Some systems have utime.h but don't declare the struct anywhere.
  
  AC_DEFUN([gl_CHECK_TYPE_STRUCT_UTIMBUF],
  [
    AC_CHECK_HEADERS_ONCE([sys/time.h utime.h])
    AC_CACHE_CHECK([for struct utimbuf], [gl_cv_sys_struct_utimbuf],
      [AC_COMPILE_IFELSE(
         [AC_LANG_PROGRAM(
  	  [[#if HAVE_SYS_TIME_H
  	     #include <sys/time.h>
  	    #endif
  	    #include <time.h>
  	    #ifdef HAVE_UTIME_H
  	     #include <utime.h>
  	    #endif
  	  ]],
  	  [[static struct utimbuf x; x.actime = x.modtime;]])],
         [gl_cv_sys_struct_utimbuf=yes],
         [gl_cv_sys_struct_utimbuf=no])])
  
    if test $gl_cv_sys_struct_utimbuf = yes; then
      AC_DEFINE([HAVE_STRUCT_UTIMBUF], [1],
        [Define if struct utimbuf is declared -- usually in <utime.h>.
         Some systems have utime.h but don't declare the struct anywhere. ])
    fi
  ])
  

Download