kc3-lang/SDL

diff --git a/Xcode/SDL/pkg-support/resources/CMake/sdl2-config-version.cmake b/Xcode/SDL/pkg-support/resources/CMake/sdl2-config-version.cmake
new file mode 100644
index 0000000..d2939eb
--- /dev/null
+++ b/Xcode/SDL/pkg-support/resources/CMake/sdl2-config-version.cmake
@@ -0,0 +1,54 @@
+# based on the files generated by CMake's write_basic_package_version_file
+
+# SDL2 CMake version configuration file:
+# This file is meant to be placed in Resources/CMake of a SDL2 framework
+
+if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_version.h")
+    message(AUTHOR_WARNING "Could not find SDL_version.h. This script is meant to be placed in the root of SDL2-devel-2.x.y-VC")
+    return()
+endif()
+
+file(READ "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_version.h" _sdl_version_h)
+string(REGEX MATCH "#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_version_h}")
+set(_sdl_major "${CMAKE_MATCH_1}")
+string(REGEX MATCH "#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_version_h}")
+set(_sdl_minor "${CMAKE_MATCH_1}")
+string(REGEX MATCH "#define[ \t]+SDL_PATCHLEVEL[ \t]+([0-9]+)" _sdl_patch_re "${_sdl_version_h}")
+set(_sdl_patch "${CMAKE_MATCH_1}")
+if(_sdl_major_re AND _sdl_minor_re AND _sdl_patch_re)
+    set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_patch}")
+else()
+    message(AUTHOR_WARNING "Could not extract version from SDL_version.h.")
+    return()
+endif()
+
+if(PACKAGE_FIND_VERSION_RANGE)
+    # Package version must be in the requested version range
+    if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
+        OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
+        OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
+        set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    else()
+        set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    endif()
+else()
+    if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
+        set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    else()
+        set(PACKAGE_VERSION_COMPATIBLE TRUE)
+        if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
+            set(PACKAGE_VERSION_EXACT TRUE)
+        endif()
+    endif()
+endif()
+
+# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
+if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
+    set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()
+
+# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
+if(NOT (CMAKE_SIZEOF_VOID_P STREQUAL "8"))
+    set(PACKAGE_VERSION "${PACKAGE_VERSION} (arm64+x64)")
+    set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()
diff --git a/Xcode/SDL/pkg-support/resources/CMake/sdl2-config.cmake b/Xcode/SDL/pkg-support/resources/CMake/sdl2-config.cmake
new file mode 100644
index 0000000..bea873d
--- /dev/null
+++ b/Xcode/SDL/pkg-support/resources/CMake/sdl2-config.cmake
@@ -0,0 +1,47 @@
+# SDL2 CMake configuration file:
+# This file is meant to be placed in Resources/CMake of a SDL2 framework
+
+cmake_minimum_required(VERSION 3.0)
+
+set(_sdl2_known_comps SDL2)
+if(NOT SDL2_FIND_COMPONENTS)
+    set(SDL2_FIND_COMPONENTS ${_sdl2_known_comps})
+endif()
+
+# Fail early when an unknown component is requested
+list(REMOVE_DUPLICATES SDL2_FIND_COMPONENTS)
+list(REMOVE_ITEM SDL2_FIND_COMPONENTS ${_sdl2_known_comps})
+if(SDL2_FIND_COMPONENTS)
+    set(missing_required_comps)
+    foreach(missingcomp ${SDL2_FIND_COMPONENTS})
+        if(SDL2_FIND_REQUIRED_${missingcomp})
+            list(APPEND missing_required_comps ${missingcomp})
+        endif()
+    endforeach()
+    if(missing_required_comps)
+        if(NOT SDL2_FIND_QUIETLY)
+            message(WARNING "SDL2: following component(s) are not available: ${missing_required_comps}")
+        endif()
+        set(SDL2_FOUND FALSE)
+        return()
+    endif()
+endif()
+
+set(SDL2_FOUND TRUE)
+
+set(SDL2_INCLUDE_DIR    "${CMAKE_CURRENT_LIST_DIR}/../../Headers")
+set(SDL2_INCLUDE_DIRS   "${SDL2_INCLUDE_DIR}")
+set(SDL2_LIBRARY        "${CMAKE_CURRENT_LIST_DIR}/../../SDL2")
+
+
+# All targets are created, even when some might not be requested though COMPONENTS.
+# This is done for compatibility with CMake generated SDL2-target.cmake files.
+
+if(NOT TARGET SDL2::SDL2)
+    add_library(SDL2::SDL2 SHARED IMPORTED)
+    set_target_properties(SDL2::SDL2
+        PROPERTIES
+            FRAMEWORK 1
+            IMPORTED_LOCATION "${SDL2_LIBRARY}"
+    )
+endif()