kc3-lang/brotli/BUILD.bazel

Branch - branch -mastergithub/HEADgithub/custom-dictionarygithub/mastergithub/recompressiongithub/test_774593500github/test_803421474github/v1.0github/v1.1upstream/HEADupstream/custom-dictionaryupstream/masterupstream/recompressionupstream/test_774593500upstream/test_803421474upstream/v1.0upstream/v1.1- tag -v1.2.0rc2v1.2.0rc1v1.1.0rcv1.1.0v1.0.9v1.0.8v1.0.7v1.0.6v1.0.5v1.0.4v1.0.3v1.0.2v1.0.1v1.0.0v0.6.0v0.4.0v0.3.0v0.2.0v0.1.0go/cbrotli/v1.1.1-rc0go/cbrotli/v1.1.0.bcr.1go/cbrotli/v1.1.0.bcr.0go/cbrotli/v1.1.0go/brotli/v1.1.1-rc0dev/null

• Show log

  Commit

• Hash : 1045ab52
  Author :
  Date : 2024-01-04T03:32:33
  

  Fix/simplify/improve Bazel build
  
  PiperOrigin-RevId: 595656443
  

Download

• BUILD.bazel

• # Description:
  #   Brotli is a generic-purpose lossless compression algorithm.
  
  package(
      default_visibility = ["//visibility:public"],
  )
  
  licenses(["notice"])  # MIT
  
  exports_files(["LICENSE"])
  
  config_setting(
      name = "clang-cl",
      flag_values = {
          "@bazel_tools//tools/cpp:compiler": "clang-cl",
      },
      visibility = ["//visibility:public"],
  )
  
  config_setting(
      name = "msvc",
      flag_values = {
          "@bazel_tools//tools/cpp:compiler": "msvc-cl",
      },
      visibility = ["//visibility:public"],
  )
  
  STRICT_C_OPTIONS = select({
      ":msvc": [],
      ":clang-cl": [
          "/W4",
          "-Wconversion",
          "-Wlong-long",
          "-Wmissing-declarations",
          "-Wmissing-prototypes",
          "-Wno-strict-aliasing",
          "-Wshadow",
          "-Wsign-compare",
          "-Wno-sign-conversion",
      ],
      "//conditions:default": [
          "--pedantic-errors",
          "-Wall",
          "-Wconversion",
          "-Werror",
          "-Wextra",
          "-Wlong-long",
          "-Wmissing-declarations",
          "-Wmissing-prototypes",
          "-Wno-strict-aliasing",
          "-Wshadow",
          "-Wsign-compare",
      ],
  })
  
  filegroup(
      name = "public_headers",
      srcs = glob(["c/include/brotli/*.h"]),
  )
  
  filegroup(
      name = "common_headers",
      srcs = glob(["c/common/*.h"]),
  )
  
  filegroup(
      name = "common_sources",
      srcs = glob(["c/common/*.c"]),
  )
  
  filegroup(
      name = "dec_headers",
      srcs = glob(["c/dec/*.h"]),
  )
  
  filegroup(
      name = "dec_sources",
      srcs = glob(["c/dec/*.c"]),
  )
  
  filegroup(
      name = "enc_headers",
      srcs = glob(["c/enc/*.h"]),
  )
  
  filegroup(
      name = "enc_sources",
      srcs = glob(["c/enc/*.c"]),
  )
  
  cc_library(
      name = "brotli_inc",
      hdrs = [":public_headers"],
      copts = STRICT_C_OPTIONS,
      strip_include_prefix = "c/include",
  )
  
  cc_library(
      name = "brotlicommon",
      srcs = [":common_sources"],
      hdrs = [":common_headers"],
      copts = STRICT_C_OPTIONS,
      deps = [":brotli_inc"],
  )
  
  cc_library(
      name = "brotlidec",
      srcs = [":dec_sources"],
      hdrs = [":dec_headers"],
      copts = STRICT_C_OPTIONS,
      deps = [":brotlicommon"],
  )
  
  cc_library(
      name = "brotlienc",
      srcs = [":enc_sources"],
      hdrs = [":enc_headers"],
      copts = STRICT_C_OPTIONS,
      linkopts = select({
          ":clang-cl": [],
          ":msvc": [],
          "//conditions:default": ["-lm"],
      }),
      deps = [":brotlicommon"],
  )
  
  cc_binary(
      name = "brotli",
      srcs = ["c/tools/brotli.c"],
      copts = STRICT_C_OPTIONS,
      linkstatic = 1,
      deps = [
          ":brotlidec",
          ":brotlienc",
      ],
  )
  
  filegroup(
      name = "dictionary",
      srcs = ["c/common/dictionary.bin"],
  )
  

Download