kc3-lang/libxml2/convert_doc.sed

• Show log

  Commit

• Hash : 61890e39
  Author :
  Date : 2025-04-27T21:50:15
  

  doc: Prepare for conversion to Doxygen
  
  Fix many params in internal functions (not really necessary but Doxygen
  warns about that in XML mode).
  
  Fix formatting in a few corner cases that automatic conversion can't
  handle.
  
  Rearrange some DOC_DISABLE blocks.
  

Download

• convert_doc.sed

• # Delete function names
  /^ \* (xml|xlink|html)[_[:alnum:]]+:/ d
  
  # Escape
  /^ \* /s/#/\\#/g
  
  # Convert parameter names
  /^ \* / s/@([_[:alnum:]]+)([^:_[:alnum:]]|$)/`\1`\2/g
  
  # Convert parameters and return values
  s/^ \* +@([_[:alnum:]]+):[  ]*/ * @param \1  /
  s/^ \* +[Rr]eturns?[[:>:]]:?/ * @returns/
  
  # Convert file headers
  s/^ \* +Summary: *(.*)/ * @brief \1\n * /
  s/^ \* +Description: */ * /
  s/^ \* +Copy:/ * @copyright/
  s/^ \* +Author:/ * @author/
  s/^ \* +DEPRECATED:?/ * @deprecated/
  
  # Convert ignored sections
  s/DOC_DISABLE/@cond IGNORE/
  s/DOC_ENABLE/@endcond/
  

Download