IABSD.fr/src/sys/dev/sdmmc/devlist2h.awk

Branch : - branch - master - tag -

• Show log

  Commit

• Author : jsg
  Date : 2023-01-04 14:42:46
  Hash : e4453397
  Message : Christos Zoulas removed his name from advertising clauses and copyrights of some files in NetBSD. Make the same changes here. https://mail-index.netbsd.org/source-changes/2017/06/03/msg084953.html https://mail-index.netbsd.org/source-changes/2017/06/03/msg084955.html https://mail-index.netbsd.org/source-changes/2019/12/02/msg111431.html https://mail-index.netbsd.org/source-changes/2019/12/02/msg111432.html

• sys/dev/sdmmc/devlist2h.awk

• #! /usr/bin/awk -f
  #	$OpenBSD: devlist2h.awk,v 1.4 2023/01/04 14:42:46 jsg Exp $
  #	$NetBSD: devlist2h.awk,v 1.2 1998/07/22 11:47:13 christos Exp $
  #
  # Copyright (c) 1995, 1996 Christopher G. Demetriou
  # All rights reserved.
  #
  # Redistribution and use in source and binary forms, with or without
  # modification, are permitted provided that the following conditions
  # are met:
  # 1. Redistributions of source code must retain the above copyright
  #    notice, this list of conditions and the following disclaimer.
  # 2. Redistributions in binary form must reproduce the above copyright
  #    notice, this list of conditions and the following disclaimer in the
  #    documentation and/or other materials provided with the distribution.
  # 3. All advertising materials mentioning features or use of this software
  #    must display the following acknowledgement:
  #      This product includes software developed by Christopher G. Demetriou.
  # 4. The name of the author(s) may not be used to endorse or promote products
  #    derived from this software without specific prior written permission
  #
  # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  #
  function collectline(f, line) {
  	oparen = 0
  	line = ""
  	while (f <= NF) {
  		if ($f == "#") {
  			line = line "("
  			oparen = 1
  			f++
  			continue
  		}
  		if (oparen) {
  			line = line $f
  			if (f < NF)
  				line = line " "
  			f++
  			continue
  		}
  		line = line $f
  		if (f < NF)
  			line = line " "
  		f++
  	}
  	if (oparen)
  		line = line ")"
  	return line
  }
  BEGIN {
  	nproducts = nvendors = 0
  	hfile="sdmmcdevs.h"
  }
  NR == 1 {
  	VERSION = $0
  	gsub("\\$", "", VERSION)
  
  	printf("/*\t\$OpenBSD\$\t*/\n\n") > hfile
  	printf("/*\n") > hfile
  	printf(" * THIS FILE AUTOMATICALLY GENERATED.  DO NOT EDIT.\n") \
  	    > hfile
  	printf(" *\n") > hfile
  	printf(" * generated from:\n") > hfile
  	printf(" *\t%s\n", VERSION) > hfile
  	printf(" */\n") > hfile
  
  	next
  }
  $1 == "vendor" {
  	nvendors++
  
  	vendors[nvendors, 1] = $2;		# name
  	vendors[nvendors, 2] = $3;		# id
  	printf("#define\tSDMMC_VENDOR_%s\t%s\t", vendors[nvendors, 1],
  	    vendors[nvendors, 2]) > hfile
  	vendors[nvendors, 3] = collectline(4, line)
  	printf("/* %s */\n", vendors[nvendors, 3]) > hfile
  	next
  }
  $1 == "product" {
  	nproducts++
  
  	products[nproducts, 1] = $2;		# vendor name
  	products[nproducts, 2] = $3;		# product id
  	products[nproducts, 3] = $4;		# id
  	printf("#define\tSDMMC_PRODUCT_%s_%s\t%s\n", products[nproducts, 1],
  	    products[nproducts, 2], products[nproducts, 3]) > hfile
  	next
  }
  {
  	if ($0 == "")
  		blanklines++
  	print $0 > hfile
  }