IABSD.fr/xenocara/app/xgamma/meson.build

Branch : - branch - master - tag -

• Show log

  Commit

• Author : matthieu
  Date : 2025-11-03 09:51:43
  Hash : 7e9523eb
  Message : update to xgamma 1.0.8

• app/xgamma/meson.build

• # SPDX-License-Identifier: MIT
  #
  # Copyright (c) 2025, Oracle and/or its affiliates.
  #
  # Permission is hereby granted, free of charge, to any person obtaining a
  # copy of this software and associated documentation files (the "Software"),
  # to deal in the Software without restriction, including without limitation
  # the rights to use, copy, modify, merge, publish, distribute, sublicense,
  # and/or sell copies of the Software, and to permit persons to whom the
  # Software is furnished to do so, subject to the following conditions:
  #
  # The above copyright notice and this permission notice (including the next
  # paragraph) shall be included in all copies or substantial portions of the
  # Software.
  #
  # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  # THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  # DEALINGS IN THE SOFTWARE.
  #
  
  project(
    'xgamma',
    'c',
    version: '1.0.8',
    license: 'X11',
    license_files: 'COPYING',
    meson_version: '>= 1.1.0',
  )
  
  package_string = ' '.join(meson.project_name(), meson.project_version())
  conf = configuration_data()
  conf.set_quoted('PACKAGE_STRING', package_string)
  
  cc = meson.get_compiler('c')
  
  # Replacement for XORG_DEFAULT_OPTIONS
  if cc.has_argument('-fno-strict-aliasing')
    add_project_arguments('-fno-strict-aliasing', language: 'c')
  endif
  
  conf.set('HAVE_STRTOF', cc.has_function('strtof') ? '1' : false)
  
  # Checks for pkg-config packages
  dep_libx11     = dependency('x11', required: true)
  dep_libxxf86vm = dependency('xxf86vm', required: true)
  dep_xproto     = dependency('xproto', required: true, version: '>= 7.0.17')
  deps = [dep_libx11, dep_libxxf86vm, dep_xproto]
  
  config_h = configure_file(output: 'config.h', configuration: conf)
  add_project_arguments('-DHAVE_CONFIG_H', language: ['c'])
  
  executable(
    'xgamma',
    [config_h, 'xgamma.c'],
    dependencies: deps,
    install: true
  )
  
  # Man page
  prog_sed = find_program('sed')
  
  custom_target(
    'xgamma.man',
    input: 'man/xgamma.man',
    output: 'xgamma.1',
    command: [
      prog_sed,
      '-e', 's/__vendorversion__/"@0@" "X Version 11"/'.format(package_string),
      '-e', 's/__appmansuffix__/1/g',
      '-e', 's/__libmansuffix__/3/g',
      '-e', 's/__filemansuffix__/5/g',
      '-e', 's/__miscmansuffix__/7/g',
      '@INPUT@',
    ],
    capture: true,
    install: true,
    install_dir: get_option('mandir') / 'man1',
  )