IABSD.fr/xenocara/lib/libfontenc/configure.ac

Branch : - branch - master - tag -

• Show log

  Commit

• Author : matthieu
  Date : 2026-05-08 11:16:01
  Hash : 96c90628
  Message : Update to libfontenc 1.1.9

• lib/libfontenc/configure.ac

• #  Copyright 2005 Red Hat, Inc.
  #
  #  Permission to use, copy, modify, distribute, and sell this software and its
  #  documentation for any purpose is hereby granted without fee, provided that
  #  the above copyright notice appear in all copies and that both that
  #  copyright notice and this permission notice appear in supporting
  #  documentation, and that the name of Red Hat not be used in
  #  advertising or publicity pertaining to distribution of the software without
  #  specific, written prior permission.  Red Hat makes no
  #  representations about the suitability of this software for any purpose.  It
  #  is provided "as is" without express or implied warranty.
  #
  #  RED HAT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  #  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  #  EVENT SHALL RED HAT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  #  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  #  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  #  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  #  PERFORMANCE OF THIS SOFTWARE.
  #
  
  # Initialize Autoconf
  AC_PREREQ([2.70])
  AC_INIT([libfontenc], [1.1.9],
          [https://gitlab.freedesktop.org/xorg/lib/libfontenc/-/issues], [libfontenc])
  AC_CONFIG_SRCDIR([Makefile.am])
  AC_CONFIG_HEADERS([config.h])
  AC_CONFIG_MACRO_DIRS([m4])
  
  # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  # Must be called before any macros that run the compiler (like LT_INIT)
  # to avoid autoconf errors.
  AC_USE_SYSTEM_EXTENSIONS
  
  # Initialize Automake
  AM_INIT_AUTOMAKE([foreign dist-xz])
  
  # Initialize libtool
  LT_INIT
  
  # Require X.Org macros 1.8 or later
  m4_ifndef([XORG_MACROS_VERSION],
            [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  XORG_MACROS_VERSION(1.8)
  XORG_DEFAULT_OPTIONS
  
  # Require X.Org's font util macros 1.1 or later for XORG_FONTROOTDIR
  m4_ifndef([XORG_FONT_MACROS_VERSION],
  	  [m4_fatal([must install X.Org font-util 1.1 or later before running autoconf/autogen])])
  XORG_FONT_MACROS_VERSION(1.1)
  XORG_FONTSUBDIR([ENCODINGSDIR], [encodingsdir], [encodings])
  
  # zlib - try pkg-config first, then fallback to old method for
  # systems like darwin without a zlib.pc file
  PKG_CHECK_MODULES(ZLIB, [zlib], [Z_REQUIRES=zlib], [Z_REQUIRES=""])
  if test "x$Z_REQUIRES" = "x"; then
  	AC_CHECK_HEADER([zlib.h], [],
  		AC_MSG_FAILURE([zlib.h is required to compile libfontenc]))
  	AC_CHECK_LIB(z, gzclose, [ZLIB_LIBS=-lz],
  		AC_MSG_ERROR([zlib is required to compile libfontenc]))
  fi
  AC_SUBST(Z_REQUIRES)
  
  # Obtain compiler/linker options for dependencies
  PKG_CHECK_MODULES(FONTENC, xproto)
  
  # Checks for typedefs, structures, and compiler characteristics.
  AC_SYS_LARGEFILE
  
  # Checks for library functions.
  AC_REPLACE_FUNCS([reallocarray])
  
  # Allow checking code with lint, sparse, etc.
  XORG_WITH_LINT
  LINT_FLAGS="${LINT_FLAGS} ${FONTENC_CFLAGS}"
  
  AC_CONFIG_FILES([Makefile
  		src/Makefile
  		fontenc.pc])
  AC_OUTPUT