c3-lang/libmd/m4/libmd-linker.m4

Branch - branch -mainorigin/HEADorigin/mainorigin/pu/compatorigin/pu/stringify- tag -1.0.41.0.31.0.21.0.11.0.00.0.0

• Show log

  Commit

• Hash : e4087860
  Author :
  Date : 2023-02-12T23:55:09
  

  build: Fix version script linker support detection
  
  When the linker uses --no-undefined-version either specified by the user
  or as the default behavior (such as with newer clang >= 16 releases),
  a missing symbol definition will cause a linker error if that symbol is
  listed in the version script.
  
  Closes: #1
  

Download

• m4/libmd-linker.m4

• # Copyright © 2014 Guillem Jover <guillem@hadrons.org>
  
  # LIBMD_LINKER_VERSION_SCRIPT
  # --------------------------
  AC_DEFUN([LIBMD_LINKER_VERSION_SCRIPT], [
    AC_CACHE_CHECK([for --version-script linker flag], [libmd_cv_version_script], [
      echo "{ global: symbol; local: *; };" >conftest.map
      save_LDFLAGS=$LDFLAGS
      LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
      AC_LINK_IFELSE([
        AC_LANG_PROGRAM([[
  extern int symbol(void);
  int symbol(void) { return 0; }
  ]], [[
  ]])
      ], [
        libmd_cv_version_script=yes
      ], [
        libmd_cv_version_script=no
      ])
      LDFLAGS="$save_LDFLAGS"
      rm -f conftest.map
    ])
    AM_CONDITIONAL([HAVE_LINKER_VERSION_SCRIPT],
      [test "x$libmd_cv_version_script" = "xyes"])
  ])
  

Download