kc3-lang/SDL/android-project/app/build.gradle

• Show log

  Commit

• Hash : 38ae4988
  Author :
  Date : 2018-08-21T20:46:25
  

  Updated required Android SDK to API 26, to match Google's new App Store requirements

Download

• android-project/app/build.gradle

• def buildAsLibrary = project.hasProperty('BUILD_AS_LIBRARY');
  def buildAsApplication = !buildAsLibrary
  if (buildAsApplication) {
      apply plugin: 'com.android.application'
  }
  else {
      apply plugin: 'com.android.library'
  }
  
  android {
      compileSdkVersion 26
      buildToolsVersion "26.0.1"
      defaultConfig {
          if (buildAsApplication) {
              applicationId "org.libsdl.app"
          }
          minSdkVersion 14
          targetSdkVersion 26
          versionCode 1
          versionName "1.0"
          externalNativeBuild {
              ndkBuild {
                  arguments "APP_PLATFORM=android-14"
                  abiFilters 'armeabi-v7a', 'x86'
              }
          }
          testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
      }
      buildTypes {
          release {
              minifyEnabled false
              proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
          }
      }
      if (!project.hasProperty('EXCLUDE_NATIVE_LIBS')) {
          sourceSets.main {
              jniLibs.srcDir 'libs'
          }
          externalNativeBuild {
              ndkBuild {
                  path 'jni/Android.mk'
              }
          }
         
      }
      lintOptions {
          abortOnError false
      }
      
      if (buildAsLibrary) {
          libraryVariants.all { variant ->
              variant.outputs.each { output ->
                  def outputFile = output.outputFile
                  if (outputFile != null && outputFile.name.endsWith(".aar")) {
                      def fileName = "org.libsdl.app.aar";
                      output.outputFile = new File(outputFile.parent, fileName);
                  }
              }
          }
      }
  }
  
  dependencies {
      compile fileTree(include: ['*.jar'], dir: 'libs')
      androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
          exclude group: 'com.android.support', module: 'support-annotations'
      })
      testCompile 'junit:junit:4.12'
  }
  

Download