BUILD.gn

Show log
Commit

Hash : 82826be0
Author :
Date : 2023-01-06T11:20:14

Reland "Make ANGLE program version only dependent on data that matters"

This is a reland of commit 61728827d2e5ecce685578bc54bb2c744b65fc9a

Changes made on top of previous commit
1. In src/program_serialize_data_version.py,
fix the script error on Windows: anglebug.com/7918.
2. In BUILD.gn, replace the 'write_file' with
'response_file_content'. See
https://gn.googlesource.com/gn/+/main/docs/reference.md#var_response_file_contents
3. In scripts/generate_android.bp.py, add code to
handle the special GN build flag {{response_file_name}}.
The code writes the list defined in srcs
(identified by $(in) in Android blueprint) into a
temp file named 'gn_response_file', and replaces the
{{response_file_name}} with 'gn_response_file'.

Original change's description

> Changes made on top of original commit
> 1. Enable execution permission on python script
> program_serialize_data_version.py
> 2. Remove unused list in libGLESv2.gni
> 3. In angle/BUILD.gn, change file path from
> "relative to angle_root", to "relative to root_build_dir",
> so that inside the script program_serialize_data_version.py,
> we don't have to find the absolute path of the code files for
> hashing.

> Original change's description

> > This change introduces a new variable ANGLE_PROGRAM_VERSION
> > to track the version of ANGLE source files that affect shader
> > program serialization/deserialization. This change include more
> > source files than necessary, to serve the purpose of a conservative
> > jumping off point. We will narrow down the list of files for
> > ANGLE_PROGRAM_VERSION hash generation in the future.

> > Add a new script program_serialize_data_version.py that will
> > be triggered during the build when the related source files changed.
> > The script will generate a hash and the hash size from the related
> > source files. In program serialization/deserialization and cache
> > key generation, we will use this hash value instead of the entire
> > ANGLE git hash. When the hash value changed, we know that the
> > related source files changed, and we should invalidate the program
> > cache and re-generate the blob cache / program binary.

> > Bug: angleproject:4981
> > Change-Id: I2fb609416738d459d3289190c232c2d797ba58e3
> > Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/4072215
> > Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
> > Reviewed-by: Cody Northrop <cnorthrop@google.com>
> > Reviewed-by: Jamie Madill <jmadill@chromium.org>
> > Commit-Queue: Yuxin Hu <yuxinhu@google.com>

> Bug: angleproject:4981
> Change-Id: Iaa9eb0ab33439197bc30d03064fc245ea7ef1ea8
> Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/4113445
> Reviewed-by: Amirali Abdolrashidi <abdolrashidi@google.com>
> Reviewed-by: Cody Northrop <cnorthrop@google.com>
> Commit-Queue: Yuxin Hu <yuxinhu@google.com>

Bug: angleproject:4981
Change-Id: Ib5bba199be6d08a1e19807026df0e7b747dbc8a9
Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/4144078
Reviewed-by: Roman Lavrov <romanl@google.com>
Commit-Queue: Yuxin Hu <yuxinhu@google.com>
Reviewed-by: Cody Northrop <cnorthrop@google.com>

Download

src/libANGLE/renderer/vulkan/BUILD.gn

# Copyright 2019 The ANGLE Project Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
#
# This file houses the build configuration for the ANGLE Vulkan back-end.

import("//build/config/dcheck_always_on.gni")
import("//build_overrides/swiftshader.gni")
import("vulkan_backend.gni")

#import("../../../../gni/angle.gni")

assert(angle_enable_vulkan)

declare_args() {
  # Enable custom (cpu-side) secondary command buffers
  angle_enable_custom_vulkan_cmd_buffers = true

  # Enable Vulkan GPU trace event capability
  angle_enable_vulkan_gpu_trace_events = false
}

declare_args() {
  # Enable custom secondary command buffers for outside render pass commands only
  angle_enable_custom_vulkan_outside_render_pass_cmd_buffers =
      angle_enable_custom_vulkan_cmd_buffers

  # Enable custom secondary command buffers for render pass commands only
  angle_enable_custom_vulkan_render_pass_cmd_buffers =
      angle_enable_custom_vulkan_cmd_buffers

  # Enable shared ring buffer command buffer allocator
  angle_enable_vulkan_shared_ring_buffer_cmd_alloc = false
}

angle_source_set("angle_vk_mem_alloc_wrapper") {
  deps = [
    "$angle_root/src/common/vulkan:angle_vulkan_headers",
    "$angle_vulkan_memory_allocator_dir",
  ]
  include_dirs = [ "$angle_vulkan_memory_allocator_dir/include" ]
  configs += [ "$angle_root:angle_no_cfi_unrelated_cast" ]
  sources = [
    "vk_mem_alloc_wrapper.cpp",
    "vk_mem_alloc_wrapper.h",
  ]
  if (is_clang) {
    cflags_cc = [
      "-Wno-extra-semi-stmt",
      "-Wno-missing-field-initializers",
      "-Wno-suggest-destructor-override",
      "-Wno-suggest-override",
      "-Wno-inconsistent-missing-destructor-override",
    ]
  }
}

config("angle_vulkan_backend_config") {
  defines = [ "ANGLE_ENABLE_VULKAN" ]
  if (angle_enable_swiftshader) {
    defines += [ "ANGLE_ENABLE_SWIFTSHADER" ]
  }
  if (angle_enable_vulkan_gpu_trace_events) {
    defines += [ "ANGLE_ENABLE_VULKAN_GPU_TRACE_EVENTS=1" ]
  }
  if (angle_enable_vulkan_validation_layers) {
    defines += [ "ANGLE_ENABLE_VULKAN_VALIDATION_LAYERS" ]
  }

  defines += [ "ANGLE_ENABLE_VULKAN_SHARED_RING_BUFFER_CMD_ALLOC=" +
               "${angle_enable_vulkan_shared_ring_buffer_cmd_alloc}" ]

  # Ensures that the memory allocation logging can only be enabled with debug layers.
  assert(angle_debug_layers_enabled || !angle_enable_memory_alloc_logging)
  if (angle_enable_memory_alloc_logging) {
    defines += [ "ANGLE_ENABLE_MEMORY_ALLOC_LOGGING=1" ]
  }
}

template("angle_vulkan_backend_template") {
  config("${target_name}_internal_config") {
    defines = []
    if (invoker.enable_custom_outside_render_pass_cmd_buffers ||
        angle_enable_vulkan_shared_ring_buffer_cmd_alloc) {
      defines += [ "ANGLE_USE_CUSTOM_VULKAN_OUTSIDE_RENDER_PASS_CMD_BUFFERS=1" ]
    }
    if (invoker.enable_custom_render_pass_cmd_buffers ||
        angle_enable_vulkan_shared_ring_buffer_cmd_alloc) {
      defines += [ "ANGLE_USE_CUSTOM_VULKAN_RENDER_PASS_CMD_BUFFERS=1" ]
    }
  }

  angle_source_set(target_name) {
    sources = vulkan_backend_sources
    libs = []
    deps = [
      ":angle_vk_mem_alloc_wrapper",
      "$angle_root:angle_abseil",
      "$angle_root:angle_compression",
      "$angle_root:angle_gpu_info_util",
      "$angle_root:angle_image_util",
      "$angle_root/src/common/spirv:angle_spirv_base",
      "$angle_root/src/common/spirv:angle_spirv_builder",
      "$angle_root/src/common/spirv:angle_spirv_headers",
      "$angle_root/src/common/spirv:angle_spirv_parser",
      "$angle_spirv_headers_dir:spv_headers",
    ]

    if (angle_enable_cl || is_android) {
      deps += [ "$angle_root:angle_version_info" ]
    }

    public_deps = [
      "$angle_root:libANGLE_headers",
      "$angle_root/src/common/vulkan",
      "$angle_root/src/common/vulkan:angle_libvulkan_loader",
      "$angle_root/src/common/vulkan:angle_vulkan_entry_points",
      "$angle_root/src/common/vulkan:angle_vulkan_headers",
    ]
    public_configs = [
      ":angle_vulkan_backend_config",
      ":${target_name}_internal_config",
    ]

    if (angle_use_wayland) {
      public_configs += [ "$angle_root:angle_wayland_config" ]
    }

    data_deps = []

    defines = []

    if (angle_enable_vulkan_validation_layers) {
      defines += [ "ANGLE_ENABLE_VULKAN_VALIDATION_LAYERS_BY_DEFAULT" ]
      data_deps += [ "$angle_root/src/common/vulkan:vulkan_validation_layers" ]
    }

    if (is_linux || is_chromeos) {
      deps += [ "$angle_root/src/common/linux:angle_dma_buf" ]
      if (angle_use_gbm) {
        deps += [ "//third_party/minigbm" ]
      }
    }

    if (is_fuchsia) {
      public_deps += [ "$angle_root/src/common/fuchsia_egl:backend" ]
    }

    # Include generated shaders.
    import("vk_internal_shaders_autogen.gni")
    sources += angle_vulkan_internal_shaders
  }
}

angle_vulkan_backend_template("angle_vulkan_backend") {
  enable_custom_outside_render_pass_cmd_buffers =
      angle_enable_custom_vulkan_outside_render_pass_cmd_buffers
  enable_custom_render_pass_cmd_buffers =
      angle_enable_custom_vulkan_render_pass_cmd_buffers
}

angle_vulkan_backend_template("angle_vulkan_secondaries_backend") {
  enable_custom_outside_render_pass_cmd_buffers = false
  enable_custom_render_pass_cmd_buffers = false
}

Download