kc3-lang/angle/src/libANGLE/renderer/metal/TransformFeedbackMtl.mm

• Show log

  Commit

• Hash : 6136cbcb
  Author :
  Date : 2020-09-23T21:31:05
  

  Metal: Implement transform feedback
  
  - XFB is currently emulated by writing to storage buffers.
  
  - Metal doesn't allow vertex shader to both write to storage buffers and
    to stage output (i.e clip position). So if GL_RASTERIZER_DISCARD is
    NOT enabled, the draw with XFB enabled will have 2 passes:
    + First pass: vertex shader writes to XFB buffers + not write to stage
      output + disable rasterizer.
    + Second pass: vertex shader writes to stage output (i.e.
      [[position]]) + enable rasterizer. If GL_RASTERIZER_DISCARD is
      enabled, the second pass is omitted.
    + This effectively executes the same vertex shader twice. TODO:
      possible improvement is writing vertex outputs to buffer in first
      pass then re-use that buffer as input for second pass which has a
      passthrough vertex shader.
  
  - If GL_RASTERIZER_DISCARD is enabled, and XFB is enabled:
    + Only first pass above will be executed, and the render pass will use
      an empty 1x1 texture attachment since rasterization is not needed.
  
  - If GL_RASTERIZER_DISCARD is enabled, but XFB is NOT enabled:
    + we still enable Metal rasterizer.
    + but vertex shader must emulate the discard by writing gl_Position =
      (-3, -3, -3, 1). This effectively moves the vertex out of clip
      space's visible area.
    + This is because GLSL still allows vertex shader to write to stage
      output when rasterizer is disabled. However, Metal doesn't allow
      that. In Metal, if rasterizer is disabled, then vertex shader must
      not write to stage output.
  
  - See src/libANGLE/renderer/metal/doc/TransformFeedback.md for more
    details.
  
  Bug: angleproject:2634
  Change-Id: I6c700e031052560326b7f660ee7597202d38e6aa
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2408594
  Reviewed-by: Jonah Ryan-Davis <jonahr@google.com>
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  Commit-Queue: Jonah Ryan-Davis <jonahr@google.com>
  

Download

• src/libANGLE/renderer/metal/TransformFeedbackMtl.mm

• //
  // Copyright 2020 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  // TransformFeedbackMtl.mm:
  //    Defines the class interface for TransformFeedbackMtl, implementing TransformFeedbackImpl.
  //
  
  #include "libANGLE/renderer/metal/TransformFeedbackMtl.h"
  
  #include "common/debug.h"
  #include "libANGLE/Context.h"
  #include "libANGLE/Query.h"
  #include "libANGLE/renderer/metal/ContextMtl.h"
  #include "libANGLE/renderer/metal/QueryMtl.h"
  
  namespace rx
  {
  
  TransformFeedbackMtl::TransformFeedbackMtl(const gl::TransformFeedbackState &state)
      : TransformFeedbackImpl(state)
  {}
  
  TransformFeedbackMtl::~TransformFeedbackMtl() {}
  
  angle::Result TransformFeedbackMtl::begin(const gl::Context *context,
                                            gl::PrimitiveMode primitiveMode)
  {
      mtl::GetImpl(context)->onTransformFeedbackActive(context, this);
  
      return angle::Result::Continue;
  }
  
  angle::Result TransformFeedbackMtl::end(const gl::Context *context)
  {
      const gl::State &glState = context->getState();
      gl::Query *transformFeedbackQuery =
          glState.getActiveQuery(gl::QueryType::TransformFeedbackPrimitivesWritten);
      if (transformFeedbackQuery)
      {
          mtl::GetImpl(transformFeedbackQuery)->onTransformFeedbackEnd(context);
      }
  
      mtl::GetImpl(context)->onTransformFeedbackInactive(context, this);
  
      return angle::Result::Continue;
  }
  
  angle::Result TransformFeedbackMtl::pause(const gl::Context *context)
  {
      // When XFB is paused, OpenGL allows XFB buffers to be bound for other purposes. We need to call
      // onTransformFeedbackInactive() to issue a sync.
      mtl::GetImpl(context)->onTransformFeedbackInactive(context, this);
  
      return angle::Result::Continue;
  }
  
  angle::Result TransformFeedbackMtl::resume(const gl::Context *context)
  {
      mtl::GetImpl(context)->onTransformFeedbackActive(context, this);
  
      return angle::Result::Continue;
  }
  
  angle::Result TransformFeedbackMtl::bindIndexedBuffer(
      const gl::Context *context,
      size_t index,
      const gl::OffsetBindingPointer<gl::Buffer> &binding)
  {
      // Do nothing for now
  
      return angle::Result::Continue;
  }
  
  angle::Result TransformFeedbackMtl::getBufferOffsets(ContextMtl *contextMtl,
                                                       GLint drawCallFirstVertex,
                                                       uint32_t skippedVertices,
                                                       int32_t *offsetsOut)
  {
      int64_t verticesDrawn = static_cast<int64_t>(mState.getVerticesDrawn()) + skippedVertices;
      const std::vector<GLsizei> &bufferStrides =
          mState.getBoundProgram()->getTransformFeedbackStrides();
      const gl::ProgramExecutable *executable = contextMtl->getState().getProgramExecutable();
      ASSERT(executable);
      size_t xfbBufferCount = executable->getTransformFeedbackBufferCount();
  
      ASSERT(xfbBufferCount > 0);
  
      for (size_t bufferIndex = 0; bufferIndex < xfbBufferCount; ++bufferIndex)
      {
          const gl::OffsetBindingPointer<gl::Buffer> &bufferBinding =
              mState.getIndexedBuffer(bufferIndex);
  
          ASSERT((bufferBinding.getOffset() % 4) == 0);
  
          // Offset the gl_VertexIndex by drawCallFirstVertex
          int64_t drawCallVertexOffset = static_cast<int64_t>(verticesDrawn) - drawCallFirstVertex;
  
          int64_t writeOffset =
              (bufferBinding.getOffset() + drawCallVertexOffset * bufferStrides[bufferIndex]) /
              static_cast<int64_t>(sizeof(uint32_t));
  
          offsetsOut[bufferIndex] = static_cast<int32_t>(writeOffset);
  
          // Check for overflow.
          ANGLE_CHECK_GL_ALLOC(contextMtl, offsetsOut[bufferIndex] == writeOffset);
      }
  
      return angle::Result::Continue;
  }
  
  }  // namespace rx
  

Download