kc3-lang/angle/src/libANGLE/renderer/metal/mtl_context_device.mm

• Show log

  Commit

• Hash : aea88562
  Author :
  Date : 2023-05-19T16:52:43
  

  Reland "Metal: Optimized BufferSubData per device"
  
  This reverts commit ee64836f702332adaca58d9f452063a04b2da955 ,
  relanding the patch stack described there.
  
  Between patchsets 1 and 5:
  
  - The shadow buffer allocation has been replaced with a multimap of
    precisely-sized buffers, rather than rounding up buffer sizes.
  
  - Garbage collection of shadow buffers is triggered in three situations:
  
    - A certain number of context switches have occurred; this number
      was hand-tuned to avoid GC every frame.
  
    - A certain number of command buffer submissions has occurred; this
      number was hand-tuned to GC no more often than every few seconds
      on representative workloads.
  
    - The total size of the allocated shadow buffers is more than 1 MB,
      and either more than twice the size at the last garbage
      collection, or 64 MB more than at the last garbage collection. In
      this case, aggressive GC is performed in order to reclaim shadow
      buffers more quickly.
  
  Performance before and after these changes appears identical on
  microbenchmarks. On one Figma test case, comparing GPU memory
  allocated inside the BufferManager, peak consumption is decreased by
  over 75%, and steady-state consumption decreases by over 88%.
  
  Patchset 6 adds a needed workaround for a bug in the
  AMDMTLBronzeDriver affecting uploads of client-side data, and
  therefore some dEQP tests. It also streamlines the aggressive GC.
  
  Bug: angleproject:7544
  Change-Id: I81b061f0b33c27fa403527fa12d626f4e9c88ebe
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/4497413
  Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
  Reviewed-by: Geoff Lang <geofflang@chromium.org>
  Commit-Queue: Geoff Lang <geofflang@chromium.org>
  Commit-Queue: Shahbaz Youssefi <syoussefi@chromium.org>
  

Download

• src/libANGLE/renderer/metal/mtl_context_device.mm

• //
  // Copyright 2021 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  // mtl_context_device.mm:
  //      Implementation of Metal framework's MTLDevice wrapper per context.
  //
  
  #include "libANGLE/renderer/metal/mtl_context_device.h"
  #if ANGLE_USE_METAL_OWNERSHIP_IDENTITY
  #    include "libANGLE/renderer/metal/mtl_resource_spi.h"
  #endif
  
  namespace rx
  {
  namespace mtl
  {
  
  ContextDevice::ContextDevice(GLint ownershipIdentity)
  {
  #if ANGLE_USE_METAL_OWNERSHIP_IDENTITY
      mOwnershipIdentity = static_cast<task_id_token_t>(ownershipIdentity);
      if (mOwnershipIdentity != TASK_ID_TOKEN_NULL)
      {
          kern_return_t kr =
              mach_port_mod_refs(mach_task_self(), mOwnershipIdentity, MACH_PORT_RIGHT_SEND, 1);
          if (ANGLE_UNLIKELY(kr != KERN_SUCCESS))
          {
              ERR() << "mach_port_mod_refs failed with: %s (%x)" << mach_error_string(kr) << kr;
              ASSERT(false);
          }
      }
  #endif
  }
  
  ContextDevice::~ContextDevice()
  {
  #if ANGLE_USE_METAL_OWNERSHIP_IDENTITY
      if (mOwnershipIdentity != TASK_ID_TOKEN_NULL)
      {
          kern_return_t kr =
              mach_port_mod_refs(mach_task_self(), mOwnershipIdentity, MACH_PORT_RIGHT_SEND, -1);
          if (ANGLE_UNLIKELY(kr != KERN_SUCCESS))
          {
              ERR() << "mach_port_mod_refs failed with: %s (%x)" << mach_error_string(kr) << kr;
              ASSERT(false);
          }
      }
  #endif
  }
  
  AutoObjCPtr<id<MTLSamplerState>> ContextDevice::newSamplerStateWithDescriptor(
      MTLSamplerDescriptor *descriptor) const
  {
      return adoptObjCObj([get() newSamplerStateWithDescriptor:descriptor]);
  }
  
  AutoObjCPtr<id<MTLTexture>> ContextDevice::newTextureWithDescriptor(
      MTLTextureDescriptor *descriptor) const
  {
  
      auto resource = adoptObjCObj([get() newTextureWithDescriptor:descriptor]);
      setOwnerWithIdentity(resource);
      return resource;
  }
  
  AutoObjCPtr<id<MTLTexture>> ContextDevice::newTextureWithDescriptor(
      MTLTextureDescriptor *descriptor,
      IOSurfaceRef iosurface,
      NSUInteger plane) const
  {
      return adoptObjCObj([get() newTextureWithDescriptor:descriptor
                                                iosurface:iosurface
                                                    plane:plane]);
  }
  
  AutoObjCPtr<id<MTLBuffer>> ContextDevice::newBufferWithLength(NSUInteger length,
                                                                MTLResourceOptions options) const
  {
      auto resource = adoptObjCObj([get() newBufferWithLength:length options:options]);
      setOwnerWithIdentity(resource);
      return resource;
  }
  
  AutoObjCPtr<id<MTLBuffer>> ContextDevice::newBufferWithBytes(const void *pointer,
                                                               NSUInteger length,
                                                               MTLResourceOptions options) const
  {
      auto resource = adoptObjCObj([get() newBufferWithBytes:pointer length:length options:options]);
      setOwnerWithIdentity(resource);
      return resource;
  }
  
  AutoObjCPtr<id<MTLComputePipelineState>> ContextDevice::newComputePipelineStateWithFunction(
      id<MTLFunction> computeFunction,
      __autoreleasing NSError **error) const
  {
      return adoptObjCObj([get() newComputePipelineStateWithFunction:computeFunction error:error]);
  }
  
  AutoObjCPtr<id<MTLRenderPipelineState>> ContextDevice::newRenderPipelineStateWithDescriptor(
      MTLRenderPipelineDescriptor *descriptor,
      __autoreleasing NSError **error) const
  {
      return adoptObjCObj([get() newRenderPipelineStateWithDescriptor:descriptor error:error]);
  }
  
  AutoObjCPtr<id<MTLLibrary>> ContextDevice::newLibraryWithSource(
      NSString *source,
      MTLCompileOptions *options,
      __autoreleasing NSError **error) const
  {
      return adoptObjCObj([get() newLibraryWithSource:source options:options error:error]);
  }
  
  AutoObjCPtr<id<MTLLibrary>> ContextDevice::newLibraryWithData(dispatch_data_t data,
                                                                __autoreleasing NSError **error) const
  {
      return adoptObjCObj([get() newLibraryWithData:data error:error]);
  }
  
  AutoObjCPtr<id<MTLDepthStencilState>> ContextDevice::newDepthStencilStateWithDescriptor(
      MTLDepthStencilDescriptor *descriptor) const
  {
      return adoptObjCObj([get() newDepthStencilStateWithDescriptor:descriptor]);
  }
  
  AutoObjCPtr<id<MTLSharedEvent>> ContextDevice::newSharedEvent() const
  {
      return adoptObjCObj([get() newSharedEvent]);
  }
  
  void ContextDevice::setOwnerWithIdentity(id<MTLResource> resource) const
  {
  #if ANGLE_USE_METAL_OWNERSHIP_IDENTITY
      mtl::setOwnerWithIdentity(resource, mOwnershipIdentity);
  #endif
  }
  
  bool ContextDevice::hasUnifiedMemory() const
  {
      if (@available(iOS 13.0, macOS 10.15, macCatalyst 13.1, tvOS 13.0, *))
      {
          return [get() hasUnifiedMemory];
      }
  
      return false;
  }
  
  }  // namespace mtl
  }  // namespace rx
  

Download