kc3-lang/angle/src/libANGLE/renderer/d3d/d3d9/shaders/generate_shaders.bat

• Show log

  Commit

• Hash : 9d737966
  Author :
  Date : 2019-08-14T12:25:12
  

  Standardize copyright notices to project style
  
  For all "ANGLE Project" copyrights, standardize to the format specified
  by the style guide. Changes:
  - "Copyright (c)" and "Copyright(c)" changed to just "Copyright".
  - Removed the second half of date ranges ("Y1Y1-Y2Y2"->"Y1Y1").
  - Fixed a small number of files that had no copyright date using the
    initial commit year from the version control history.
  - Fixed one instance of copyright being "The ANGLE Project" rather than
    "The ANGLE Project Authors"
  
  These changes are applied both to the copyright of source file, and
  where applicable to copyright statements that are generated by
  templates.
  
  BUG=angleproject:3811
  
  Change-Id: I973dd65e4ef9deeba232d5be74c768256a0eb2e5
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/1754397
  Commit-Queue: Jamie Madill <jmadill@chromium.org>
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  

Download

• src/libANGLE/renderer/d3d/d3d9/shaders/generate_shaders.bat

• @ECHO OFF
  REM
  REM Copyright 2013 The ANGLE Project Authors. All rights reserved.
  REM Use of this source code is governed by a BSD-style license that can be
  REM found in the LICENSE file.
  REM
  
  PATH %PATH%;%ProgramFiles(x86)%\Windows Kits\8.1\bin\x86;%DXSDK_DIR%\Utilities\bin\x86
  
  setlocal
  set errorCount=0
  set successCount=0
  set debug=0
  
  if "%1" == "debug" (
      set debug=1
  )
  if "%1" == "release" (
      set debug=0
  )
  
  ::              | Input file          | Entry point           | Type | Output file                        | Debug |
  call:BuildShader Blit.vs               standardvs              vs_2_0 compiled\standardvs.h                %debug%
  call:BuildShader Blit.ps               passthroughps           ps_2_0 compiled\passthroughps.h             %debug%
  call:BuildShader Blit.ps               luminanceps             ps_2_0 compiled\luminanceps.h               %debug%
  call:BuildShader Blit.ps               luminancepremultps      ps_2_0 compiled\luminancepremultps.h        %debug%
  call:BuildShader Blit.ps               luminanceunmultps       ps_2_0 compiled\luminanceunmultps.h         %debug%
  call:BuildShader Blit.ps               componentmaskps         ps_2_0 compiled\componentmaskps.h           %debug%
  call:BuildShader Blit.ps               componentmaskpremultps  ps_2_0 compiled\componentmaskpremultps.h    %debug%
  call:BuildShader Blit.ps               componentmaskunmultps   ps_2_0 compiled\componentmaskunmultps.h     %debug%
  
  echo.
  
  if %successCount% GTR 0 (
     echo %successCount% shaders compiled successfully.
  )
  if %errorCount% GTR 0 (
     echo There were %errorCount% shader compilation errors.
  )
  
  endlocal
  exit /b
  
  :BuildShader
  set input=%~1
  set entry=%~2
  set type=%~3
  set output=%~4
  set debug=%~5
  
  if %debug% == 0 (
      set "buildCMD=fxc /nologo /E %entry% /T %type% /Fh %output% %input%"
  ) else (
      set "buildCMD=fxc /nologo /Zi /Od /E %entry% /T %type% /Fh %output% %input%"
  )
  
  set error=0
  %buildCMD% || set error=1
  
  if %error% == 0 (
      set /a successCount=%successCount%+1
  ) else (
      set /a errorCount=%errorCount%+1
  )
  
  exit /b
  

Download