kc3-lang/angle/src/common/apple_platform_utils.mm

• Show log

  Commit

• Hash : 448e2275
  Author :
  Date : 2022-07-21T16:40:59
  

  (Reland) [Metal] Disable ANGLE's Metal backend on older GPUs.
  
  Disable creation of EGL_PLATFORM_ANGLE_TYPE_METAL_ANGLE displays on:
    iOS: MTLGPUFamilyApple2 and older (A8 and older GPUs)
    macOS and Mac Catalyst: MTLGPUFamilyMac1 and older
  
  This is a partial integration of this recent WebKit fix:
  https://bugs.webkit.org/show_bug.cgi?id=242764
  
  Refactored to eliminate duplicate copies of this code between libANGLE
  and the test suites.
  
  Changes since initial landing:
  
  - Explicitly link the angle_common static library against
    Metal.framework for the definition of MTLCreateSystemDefaultDevice,
    which was missing on the iOS Simulator.
  
  Fixed: angleproject:7514
  Change-Id: I25028a298f1235db5b717ac6a1999552121d60c6
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/3806252
  Commit-Queue: Geoff Lang <geofflang@chromium.org>
  Auto-Submit: Kenneth Russell <kbr@chromium.org>
  Reviewed-by: Geoff Lang <geofflang@chromium.org>
  

Download

• src/common/apple_platform_utils.mm

• //
  // Copyright 2022 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  
  #include "common/apple_platform_utils.h"
  
  #include <Metal/Metal.h>
  
  namespace angle
  {
  
  bool IsMetalRendererAvailable()
  {
      static bool queriedSystemDevice = false;
      static bool gpuFamilySufficient = false;
  
      // We only support macos 10.13+ and 11 for now. Since they are requirements for Metal 2.0.
  #if TARGET_OS_SIMULATOR
      if (ANGLE_APPLE_AVAILABLE_XCI(10.13, 13.0, 13))
  #else
      if (ANGLE_APPLE_AVAILABLE_XCI(10.13, 13.0, 11))
  #endif
      {
          if (!queriedSystemDevice)
          {
              ANGLE_APPLE_OBJC_SCOPE
              {
                  queriedSystemDevice = true;
                  auto device         = [MTLCreateSystemDefaultDevice() ANGLE_APPLE_AUTORELEASE];
                  if (!device)
                  {
                      return false;
                  }
  
                  // -[MTLDevice supportsFamily] introduced in macOS 10.15, Catalyst 13.1, iOS 13.
  #if defined(ANGLE_PLATFORM_MACOS) || defined(ANGLE_PLATFORM_MACCATALYST)
                  // Old Macs, such as MacBookPro11,4, cannot use ANGLE's Metal backend.
                  // This check can be removed once they are no longer supported.
                  if (ANGLE_APPLE_AVAILABLE_XCI(10.15, 13.1, 13))
                  {
                      if ([device supportsFamily:MTLGPUFamilyMac2])
                          gpuFamilySufficient = true;
                  }
                  else
                  {
                      // Hardcode constant to sidestep compiler errors. Call will
                      // return false on older macOS versions.
                      const NSUInteger macFamily2v1 = 10005;
                      if ([device supportsFeatureSet:static_cast<MTLFeatureSet>(macFamily2v1)])
                          gpuFamilySufficient = true;
                  }
  #elif defined(ANGLE_PLATFORM_IOS) && !TARGET_OS_SIMULATOR
                  // A8 devices (iPad Mini 4, iPad Air 2) cannot use ANGLE's Metal backend.
                  // This check can be removed once they are no longer supported.
                  if (ANGLE_APPLE_AVAILABLE_XCI(10.15, 13.1, 13))
                  {
                      if ([device supportsFamily:MTLGPUFamilyApple3])
                          gpuFamilySufficient = true;
                  }
                  else
                  {
                      // Hardcode constant to sidestep compiler errors. Call will
                      // return false on older macOS versions.
                      const NSUInteger iosFamily3v1 = 4;
                      if ([device supportsFeatureSet:static_cast<MTLFeatureSet>(iosFamily3v1)])
                          gpuFamilySufficient = true;
                  }
  #endif
              }
          }
  
          return gpuFamilySufficient;
      }
      return false;
  }
  
  }  // namespace angle
  

Download