kc3-lang/angle/third_party/BUILD.gn

Branch : - branch - main - tag -

• Show log

  Commit

• Author : Kyle Piddington
  Date : 2021-04-26 16:56:15
  Hash : d33a2222
  Message : Upstream Apple's direct-to-Metal backend: compile libANGLE. This change is meant to merge the metal backend changes from Apple's direct-to-Metal backend. Taken from Kyle Piddington's CL: https://chromium-review.googlesource.com/c/angle/angle/+/2857366/ The goal of this CL is to merge the metal backend code in a state that compiles, but not to switch the Metal backend over to using the direct-to-metal backend yet. Bug: angleproject:5505 Bug: angleproject:6127 Change-Id: If6783e06e0086b3a1dd25c6f53caca5cfc96cb86 Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2950067 Reviewed-by: Jonah Ryan-Davis <jonahr@google.com> Reviewed-by: Kenneth Russell <kbr@chromium.org> Commit-Queue: Jonah Ryan-Davis <jonahr@google.com>

• third_party/BUILD.gn

• # Copyright 2019 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  #
  # See:
  # https://chromium.googlesource.com/chromium/src/+/master/third_party/BUILD.gn
  
  import("//third_party/libjpeg.gni")
  
  assert(!is_ios, "This is not used on iOS, don't drag it in unintentionally")
  
  config("system_libjpeg_config") {
    libs = [ "jpeg" ]
    defines = [ "USE_SYSTEM_LIBJPEG" ]
  }
  
  config("libjpeg_turbo_config") {
    defines = [ "USE_LIBJPEG_TURBO=1" ]
  }
  
  # This is a meta target that forwards to the system's libjpeg,
  # third_party/libjpeg, or third_party/libjpeg_turbo depending on the build args
  # declared in this file.
  group("jpeg") {
    if (use_system_libjpeg) {
      public_configs = [ ":system_libjpeg_config" ]
    } else if (use_libjpeg_turbo) {
      public_deps = [ "//third_party/libjpeg_turbo:libjpeg" ]
      public_configs = [ ":libjpeg_turbo_config" ]
    } else {
      public_deps = [ "//third_party/libjpeg:libjpeg" ]
    }
  }
  
  # This is a meta target that forwards include paths only to the system's
  # libjpeg, third_party/libjpeg, or third_party/libjpeg_turbo depending on the
  # build args declared in this file. This is needed, rarely, for targets that
  # need to reference libjpeg without explicitly building it.
  group("jpeg_includes") {
    if (use_system_libjpeg) {
      public_configs = [ ":system_libjpeg_config" ]
    } else if (use_libjpeg_turbo) {
      public_configs = [ "//third_party/libjpeg_turbo:libjpeg_config" ]
    } else {
      public_configs = [ "//third_party/libjpeg:libjpeg_config" ]
    }
  }