kc3-lang/angle/src/common/vulkan/BUILD.gn

• Show log

  Commit

• Hash : e8d71eb3
  Author :
  Date : 2020-05-12T14:40:44
  

  Vulkan: Fix ANGLE_ENABLE_VULKAN_VALIDATION_LAYERS_BY_DEFAULT
  
  Unfortunately this was broken by 605af42e1 ("Vulkan: Move ICD overrides
  to a common place").
  
  This adds an unconditional dependency on the layers to tests. Tests
  don't respect angle_enable_vulkan_validation_layers, so we need to ship
  the layers irrespective of that setting.
  
  Bug: angleproject:4634
  Change-Id: Ided291ea645a72e6c3bdb960e55d15013aa20a3a
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2197279
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  Reviewed-by: Courtney Goeltzenleuchter <courtneygo@google.com>
  Commit-Queue: Jamie Madill <jmadill@chromium.org>
  

Download

• src/common/vulkan/BUILD.gn

• # Copyright 2020 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  
  import("//build_overrides/swiftshader.gni")
  import("../../../gni/angle.gni")
  
  assert(angle_enable_vulkan)
  
  angle_source_set("vulkan") {
    sources = [
      "vulkan_icd.cpp",
      "vulkan_icd.h",
    ]
  
    public_deps = [
      "$angle_root:angle_common",
      "$angle_root/src/libANGLE/renderer/vulkan:angle_vulkan_entry_points",
    ]
  
    defines = [
      "ANGLE_VK_LAYERS_DIR=\"$angle_data_dir\"",
      "ANGLE_VK_MOCK_ICD_JSON=\"$angle_data_dir/VkICD_mock_icd.json\"",
    ]
  
    deps = []
    data_deps = []
  
    if (!is_android && !is_fuchsia && !is_ggp) {
      if (angle_shared_libvulkan) {
        data_deps += [ "$angle_root/third_party/vulkan-loader/src:libvulkan" ]
      } else {
        deps += [ "$angle_root/third_party/vulkan-loader/src:libvulkan" ]
      }
      data_deps += [ "$angle_root/third_party/vulkan-tools/src:VkICD_mock_icd" ]
    }
  
    if (angle_enable_swiftshader) {
      import("$swiftshader_dir/src/Vulkan/vulkan.gni")
      _sws_icd = "./$swiftshader_icd_file_name"
      if (is_win) {
        _sws_icd = ".\\\\$swiftshader_icd_file_name"
      }
  
      defines += [ "ANGLE_VK_SWIFTSHADER_ICD_JSON=\"${_sws_icd}\"" ]
  
      data_deps += [
        "$swiftshader_dir/src/Vulkan:icd_file",
        "$swiftshader_dir/src/Vulkan:swiftshader_libvulkan",
      ]
    }
  }
  
  group("vulkan_validation_layers") {
    data_deps = []
    if (is_fuchsia) {
      data_deps += [ "//third_party/fuchsia-sdk:vulkan_validation" ]
    } else {
      data_deps += [ "$angle_root/third_party/vulkan-validation-layers/src:vulkan_validation_layers" ]
      if (!is_android) {
        data_deps += [ "$angle_root/third_party/vulkan-validation-layers/src:vulkan_gen_json_files" ]
      }
    }
  }
  

Download