BUILD.gn

Show log
Commit

Hash : a070b65a
Author :
Date : 2024-10-23T09:52:11

Roll Chromium from e7eae5389783 to ada7221c4738 (2147 revisions)

Sync libdrm from Chromium after
https://chromium-review.googlesource.com/c/chromium/src/+/5941361

https://chromium.googlesource.com/chromium/src.git/+log/e7eae5389783..ada7221c4738

If this roll has caused a breakage, revert this CL and stop the roller
using the controls here:
https://autoroll.skia.org/r/chromium-angle-autoroll
Please CC angle-team@google.com,cnorthrop@google.com on the revert to
ensure that a human
is aware of the problem.

To file a bug in Chromium:
https://bugs.chromium.org/p/chromium/issues/entry
To file a bug in ANGLE:
https://bugs.chromium.org/p/angleproject/issues/entry

To report a problem with the AutoRoller itself, please file a bug:
https://issues.skia.org/issues/new?component=1389291&template=1850622

Documentation for the AutoRoller is here:
https://skia.googlesource.com/buildbot/+doc/main/autoroll/README.md

Changed dependencies
* build: https://chromium.googlesource.com/chromium/src/build.git/+log/64f08eb696..774b608643
* buildtools: https://chromium.googlesource.com/chromium/src/buildtools.git/+log/3e502749c2..09ea565f4a
* testing: https://chromium.googlesource.com/chromium/src/testing/+log/48150ad7ff..546ad56e8a
* third_party/android_build_tools: https://chromium.googlesource.com/chromium/src/third_party/android_build_tools/+log/1bbb99f4c8..9c2addd45d
* third_party/android_build_tools/error_prone/cipd: hcirhm3eL0eu2NTEMxlGV_mdnvPATJ2-iQZa4SaUUfIC..n77J6kWie5cSD7pmkTyni9GjOYh2lyebCU6Eyr6GxXkC
* third_party/android_build_tools/lint/cipd: nKZoTG4Pkcpxo4-FX-0UVN1jIfWLTTTZs2lCfkq2Zg0C..4LvjVBJ-tE7OOEwn-wr9aM6zYpZjl2bZ6jvbfAdCo3wC
* third_party/android_build_tools/manifest_merger/cipd: BtJFh2thmUKU-OBYMaw_dRmyizFdL8AzLQ6C2pV99wUC..92AO-IC4QP7pBCfygcFNL6xN7xiJLTSWdiS0q-pq4ukC
* third_party/android_deps: https://chromium.googlesource.com/chromium/src/third_party/android_deps/+log/306f6a40ac..fdebd3d15a
* third_party/catapult: https://chromium.googlesource.com/catapult.git/+log/dc40fdd237..940a36cedf
* third_party/depot_tools: https://chromium.googlesource.com/chromium/tools/depot_tools.git/+log/c4d75a1519..cc924d1ab6
* third_party/fuchsia-sdk/sdk: version:24.20241014.3.1..version:25.20241022.0.1
* third_party/libc++/src: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxx.git/+log/d9456b7a63..c8eec3629a
* third_party/libunwind/src: https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libunwind.git/+log/41b4634414..59d05179e3
* third_party/protobuf: https://chromium.googlesource.com/chromium/src/third_party/protobuf/+log/a661187e08..29d8a79ce5
* third_party/r8/cipd: K7fIEIzzANXaspaV4maRvvy6jqYIHGEgoC4gfJvSD_0C..zNYp2KVrHI9KDsLQCdJIFzXTvkqx3Dav9o5vR1UlMxQC
* third_party/r8/d8/cipd: 3KCj5eRYCvGGYs5i90pRaeihkzsqgUGc4OkICT8AOlIC..zNYp2KVrHI9KDsLQCdJIFzXTvkqx3Dav9o5vR1UlMxQC
* third_party/siso/cipd: git_revision:f10ec3c74e86f2de9b9e5ad4e2d8d3b0192ea4d2..git_revision:4237c4b45d2accad9955693251a99f0b862a0a03
* third_party/turbine/cipd: vSia3h9tzpwpP_goLj4HMdl7_FEB5iVCv9nU5ZXOfIMC..dODwcAXI7V4M-fHO0rZvcMEcW3qgfNnkoPeuwxzO4DsC
* third_party/zlib: https://chromium.googlesource.com/chromium/src/third_party/zlib/+log/fa9f14143c..c7678ba8af
* tools/android: https://chromium.googlesource.com/chromium/src/tools/android/+log/f390ba146f..4b9a28a9b7
* tools/clang: https://chromium.googlesource.com/chromium/src/tools/clang.git/+log/fcba6e59ba..53554bf3da
* tools/luci-go: git_revision:7dd39503276dfa4a920102ca77a2f409f2f67655..git_revision:d212e392e327834378013806f0263ab263600db2
* tools/luci-go: git_revision:7dd39503276dfa4a920102ca77a2f409f2f67655..git_revision:d212e392e327834378013806f0263ab263600db2
* tools/perf: https://chromium.googlesource.com/chromium/src/tools/perf/+log/b2fd313bb8..752c7a08fc
* tools/skia_goldctl/linux: PpuoaxFG9rnuDcsvax6FcKG2ZWKhNvsO7tqW6G70GXAC..CXeEV6BLm5q9KGe-brhM2NLdmEgjyMyTutd_o3ioqMwC
* tools/skia_goldctl/mac_amd64: RQRQgiXDQ-q73iA9ZFw7R00gRWhOTXu3l1ns3hede0AC..XrxKbvaH3xwOzOdudnSzNTwqJhocETDPtsYNQNWHeIwC
* tools/skia_goldctl/mac_arm64: MU2sytEh51XCW0Nk_qOg2tC9GumCMAjxh-xg8tB0IYkC..oZ0XmjQl2uVb7JQS4TNGfkr4O_ZGRDCZK7VuTwAdZsoC
* tools/skia_goldctl/win: tEJ0WAy5v1qaOQ_jBcMUj540tXs7W8JZOXUNJKKQNPYC..fuydFP_nMX2mXcsO2vqFYHv2H1jdpvF95t8AGCcH7wIC
No update to Clang.

Bug: None
Change-Id: Ie03b429529f91371cc7f6da3973391c640eaf6c5
Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/5955606
Commit-Queue: Yuly Novikov <ynovikov@chromium.org>
Reviewed-by: Cody Northrop <cnorthrop@google.com>

Download

third_party/libdrm/BUILD.gn

# Copyright 2016 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
assert(is_linux || is_chromeos)

generated_static_table_fourcc_file =
    "$target_gen_dir/src/generated_static_table_fourcc.h"
fourcc_file = "src/include/drm/drm_fourcc.h"

action("make_generated_static_table_fourcc") {
  script = "src/gen_table_fourcc.py"
  args = [
    rebase_path(fourcc_file, root_build_dir),
    rebase_path(generated_static_table_fourcc_file),
  ]
  outputs = [ generated_static_table_fourcc_file ]
  inputs = [ fourcc_file ]
}

config("libdrm_config") {
  # TODO(thomasanderson): Remove this hack once
  # https://patchwork.kernel.org/patch/10545295/ lands.
  defines = [ "typeof(x)=__typeof__(x)" ]

  include_dirs = [
    "src",
    "src/include",
    "src/include/drm",
  ]

  # libdrm uses macros defined by <sys/types.h> which are being moved to
  # <sys/sysmacros.h>.  GLIBC headers give a pragma warning in this case.
  # Suppress this warning for now.  This may be removed once
  # https://patchwork.kernel.org/patch/9628231/ lands.
  cflags = [ "-Wno-#pragma-messages" ]

  # glibc version >= 2.25 explicitly include <sys/sysmacros.h>
  cflags += [ "-DMAJOR_IN_SYSMACROS=1" ]

  # TODO(b/357680612): unused function 'swap32'.
  cflags += [ "-Wno-unused-function" ]

  if (is_clang) {
    cflags += [
      "-Wno-enum-conversion",

      # TODO(crbug.com/932060) fix unused result from asprintf in modetest.c.
      "-Wno-unused-result",

      # modetest.c has an improper conversion in a printf statement.
      "-Wno-format",
    ]
  }
}

static_library("libdrm") {
  sources = [
    "src/include/drm/drm.h",
    "src/include/drm/drm_fourcc.h",
    "src/include/drm/drm_mode.h",
    "src/libdrm_macros.h",
    "src/util_math.h",
    "src/xf86drm.c",
    "src/xf86drm.h",
    "src/xf86drmHash.c",
    "src/xf86drmHash.h",
    "src/xf86drmMode.c",
    "src/xf86drmMode.h",
    "src/xf86drmRandom.c",
    "src/xf86drmRandom.h",
  ]

  deps = [ ":make_generated_static_table_fourcc" ]

  include_dirs = [
    get_path_info(generated_static_table_fourcc_file, "dir"),
    "src",
    "src/include",
  ]
  configs -= [ "//build/config/compiler:chromium_code" ]
  configs += [ "//build/config/compiler:no_chromium_code" ]
  cflags = [
    # xf86drm.c uses readdir_r, which has been deprecated as of
    # glibc-2.24.  This causes a build error when using the Debian
    # Stretch sysroot.
    "-Wno-deprecated-declarations",
  ]

  public_configs = [ ":libdrm_config" ]
}

executable("modetest") {
  sources = [
    "src/tests/modetest/buffers.c",
    "src/tests/modetest/buffers.h",
    "src/tests/modetest/cursor.c",
    "src/tests/modetest/cursor.h",
    "src/tests/modetest/modetest.c",
    "src/tests/util/common.h",
    "src/tests/util/format.c",
    "src/tests/util/format.h",
    "src/tests/util/kms.c",
    "src/tests/util/kms.h",
    "src/tests/util/pattern.c",
    "src/tests/util/pattern.h",
  ]

  include_dirs = [
    "src/tests",
    "src/tests/modetest",
  ]

  configs -= [ "//build/config/compiler:chromium_code" ]
  configs += [ "//build/config/compiler:no_chromium_code" ]
  configs += [ ":libdrm_config" ]

  deps = [ ":libdrm" ]
}

Download