kc3-lang/angle/src/tests/restricted_traces/BUILD.gn

• Show log

  Commit

• Hash : 0e0ea026
  Author :
  Date : 2022-10-13T18:29:33
  

  Split trace tests out into angle_trace_tests.
  
  This makes angle_perftests strictly for microbenchmarks.
  The trace tests are a better separated target because they
  are for both gold correctness tests and performance.
  
  You can now use the GN arg "build_angle_trace_tests" to control
  building the trace tests. "build_angle_trace_perf_tests" is
  still supported for compatibility.
  
  Updates the infra scripts to use this new trace tests target.
  Also updates the build so by default we'll build the trace
  tests if you check them out, without needing a custom arg.
  
  Also updates docs.
  
  Bug: angleproject:7755
  Change-Id: I2b1ae67799234cc1aefe7cda5f3af945c3f867fd
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/3953340
  Commit-Queue: Jamie Madill <jmadill@chromium.org>
  Reviewed-by: Roman Lavrov <romanl@google.com>
  Reviewed-by: Yuly Novikov <ynovikov@chromium.org>
  

Download

• src/tests/restricted_traces/BUILD.gn

• # Copyright 2020 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  #
  # Contains the build rules for confidential trace tests.
  
  import("../../../gni/angle.gni")
  
  angle_trace_library("angle_restricted_traces") {
    json_path = "restricted_traces.json"
    if (angle_restricted_traces != []) {
      trace_list = angle_restricted_traces
    } else {
      _trace_json = read_file(json_path, "json")
      trace_list = _trace_json.traces
    }
  }
  
  group("goldctl") {
    data = []
  
    # Because this links to a CIPD dependency, which is a symlink on Unix
    # platforms, refer to the actual executable rather than the whole directory;
    # copying the whole directory doesn't work, at least with "mb.py zip".
    if (is_win) {
      data += [ "//tools/skia_goldctl/win/goldctl.exe" ]
    } else if (is_mac) {
      data += [
        "//tools/skia_goldctl/mac_amd64/goldctl",
        "//tools/skia_goldctl/mac_arm64/goldctl",
      ]
    } else {
      data += [ "//tools/skia_goldctl/linux/goldctl" ]
    }
  }
  
  group("angle_restricted_trace_gold_tests") {
    testonly = true
    data_deps = [
      ":goldctl",
      "$angle_root/src/tests:angle_system_info_test",
      "$angle_root/src/tests:angle_trace_tests",
    ]
    data = [
      "restricted_trace_gold_tests.py",
      "restricted_traces.json",
      "../py_utils/android_helper.py",
      "../py_utils/angle_path_util.py",
      "../py_utils/angle_test_util.py",
      "../py_utils/skia_gold/",
      "//build/skia_gold_common/",
      "//testing/scripts/common.py",
      "//testing/xvfb.py",
    ]
  }
  

Download