kc3-lang/angle/src/libANGLE/renderer/d3d/d3d9/shaders/generate_shaders.bat

• Show log

  Commit

• Hash : 2b5420c0
  Author :
  Date : 2014-11-19T14:20:15
  

  Merge libGLESv2 and libEGL classes into libANGLE.
  
  BUG=angle:733
  
  Change-Id: Ic491c971411fe82c56cd97c5c8325ac14ec218df
  Reviewed-on: https://chromium-review.googlesource.com/230830
  Reviewed-by: Geoff Lang <geofflang@chromium.org>
  Tested-by: Geoff Lang <geofflang@chromium.org>
  

Download

• src/libANGLE/renderer/d3d/d3d9/shaders/generate_shaders.bat

• @ECHO OFF
  REM
  REM Copyright (c) 2013 The ANGLE Project Authors. All rights reserved.
  REM Use of this source code is governed by a BSD-style license that can be
  REM found in the LICENSE file.
  REM
  
  PATH %PATH%;%ProgramFiles(x86)%\Windows Kits\8.1\bin\x86;%DXSDK_DIR%\Utilities\bin\x86
  
  setlocal
  set errorCount=0
  set successCount=0
  set debug=0
  
  if "%1" == "debug" (
      set debug=1
  )
  if "%1" == "release" (
      set debug=0
  )
  
  ::              | Input file          | Entry point           | Type | Output file                        | Debug |
  call:BuildShader Blit.vs               standardvs              vs_2_0 compiled\standardvs.h                %debug%
  call:BuildShader Blit.vs               flipyvs                 vs_2_0 compiled\flipyvs.h                   %debug%
  call:BuildShader Blit.ps               passthroughps           ps_2_0 compiled\passthroughps.h             %debug%
  call:BuildShader Blit.ps               luminanceps             ps_2_0 compiled\luminanceps.h               %debug%
  call:BuildShader Blit.ps               componentmaskps         ps_2_0 compiled\componentmaskps.h           %debug%
  
  echo.
  
  if %successCount% GTR 0 (
     echo %successCount% shaders compiled successfully.
  )
  if %errorCount% GTR 0 (
     echo There were %errorCount% shader compilation errors.
  )
  
  endlocal
  exit /b
  
  :BuildShader
  set input=%~1
  set entry=%~2
  set type=%~3
  set output=%~4
  set debug=%~5
  
  if %debug% == 0 (
      set "buildCMD=fxc /nologo /E %entry% /T %type% /Fh %output% %input%"
  ) else (
      set "buildCMD=fxc /nologo /Zi /Od /E %entry% /T %type% /Fh %output% %input%"
  )
  
  set error=0
  %buildCMD% || set error=1
  
  if %error% == 0 (
      set /a successCount=%successCount%+1
  ) else (
      set /a errorCount=%errorCount%+1
  )
  
  exit /b
  

Download