kc3-lang/angle/third_party/clspv/gn/llvm/compiled_action.gni

• Show log

  Commit

• Hash : cd56b248
  Author :
  Date : 2023-12-08T15:36:17
  

  third_party/clspv: Add GN build files
  
  The clspv project uses CMake for build. Adding support for GN build in
  here. The build is currently setup to generate linux/x86 and
  android/arm64 artifacts for now and relevant gn files are placed in
  `third_party/clspv` location.
  
  Bug: angleproject:8369
  Change-Id: Iec7ef1916617a8b8a93324ff7302f89bd571b814
  Signed-off-by: Gowtham Tammana <g.tammana@samsung.com>
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/5106594
  Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
  Commit-Queue: Shahbaz Youssefi <syoussefi@chromium.org>
  

Download

• third_party/clspv/gn/llvm/compiled_action.gni

• # Modified `llvm/utils/gn/build/compiled_action.gni` file to suit clspv build
  # structure.
  import("//build_overrides/clspv.gni")
  
  # Defines compiled_action().
  #
  # compiled_action() is like action(), except that it runs a built binary
  # instead of a script.
  #
  # Parameters:
  #
  #   tool (required)
  #       [label] Label of the tool to run. This should be an executable, and
  #       this label should not include a toolchain (anything in parens). This
  #       tool will be built for the host.
  #
  #   outputs (required)
  #       [list of files] Same meaning as for action().
  #
  #   args (required)
  #       [list of strings] Flags to pass to the built binary. Almost identical
  #       to action()'s `args`, except that `tool` is implicitly added as first
  #       element.
  #
  #   depfile
  #   inputs
  #   public_configs
  #   visibility   (all optional)
  #       Same meaning as for action().
  #
  # Example use:
  #
  #   compiled_action("run_my_tool") {
  #     tool = "//tools/something:mytool"
  #     inputs = [ "my_input_file.txt" ]
  #     outputs = [ "$target_gen_dir/mysource.inc" ]
  #     args = [
  #       rebase_path(inputs[0], root_build_dir),
  #       rebase_path(outputs[0], root_build_dir),
  #     ]
  #   }
  #
  # You would typically declare your tool like this:
  #   if (host_toolchain == current_toolchain) {
  #     executable("mytool") {
  #       ...
  #     }
  #   }
  # The if statement around the executable is optional. It means "I only care
  # about this target in the host toolchain". Usually this is what you want, and
  # saves unnecessarily compiling your tool for the target platform. If you
  # need a target build of your tool as well, omit the if statement.
  
  template("compiled_action") {
    assert(defined(invoker.args), "must set 'args' in $target_name")
    assert(defined(invoker.outputs), "must set 'outputs' in $target_name")
    assert(defined(invoker.tool), "must set 'tool' in $target_name")
    assert(!defined(invoker.sources),
           "use 'inputs' instead of 'sources' in $target_name")
  
    action(target_name) {
      forward_variables_from(invoker,
                             [
                               "depfile",
                               "inputs",
                               "outputs",
                               "public_configs",
                               "visibility",
                             ])
      host_tool = rebase_path(invoker.tool) + "($host_toolchain)"
  
      # TODO Need to get the path from the toolchain itself
      host_executable = get_label_info(host_tool, "root_out_dir") + "/" +
                        get_label_info(host_tool, "name")  # "/bin/" +
      deps = [ host_tool ]
      script = "//$clspv_llvm_dir/llvm/utils/gn/build/run_built_binary.py"
      args = [ rebase_path(host_executable, root_build_dir) ] + invoker.args
    }
  }
  

Download