kc3-lang/angle/gni

Branch : - branch - main - tag -

• Show log

  Commit

• Author : Tobin Ehlis
  Date : 2018-03-06 17:02:47
  Hash : da6dd738
  Message : Roll (2/2) to latest LVL as of 3/6/18 Bug: angleproject:2393 Moving to HEAD of LVL master on afternoon of 3/6/18. Made some updates to BUILD.gn to add args to spirv tools external_revision_generator.py script. Re-enable ANGLE Vulkan build. Change-Id: I1705d7a2acae578bab9bbd8bb93176107e0e21dc Reviewed-on: https://chromium-review.googlesource.com/952547 Reviewed-by: Jamie Madill <jmadill@chromium.org> Commit-Queue: Jamie Madill <jmadill@chromium.org>

• angle.gni

• # Copyright 2015 The Chromium Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  
  import("//build_overrides/build.gni")
  import("//build/config/ui.gni")  # import the use_x11 variable
  if (is_android) {
    import("//build/config/android/config.gni")
  }
  
  if (build_with_chromium) {
    angle_root = "//third_party/angle"
  
    import("//ui/ozone/ozone.gni")
  } else {
    angle_root = "//"
  
    declare_args() {
      ozone_platform_gbm = false
    }
  }
  
  # Subdirectory to place data files (e.g. layer JSON files).
  data_dir = "angledata"
  
  declare_args() {
    if (!is_android) {
      ndk_supports_vulkan = false
    } else {
      ndk_supports_vulkan =
          (current_cpu == "arm" && android32_ndk_api_level >= 24) ||
          (current_cpu == "arm64" && android64_ndk_api_level >= 24)
    }
  }
  
  declare_args() {
    angle_enable_d3d9 = is_win
    angle_enable_d3d11 = is_win
    angle_enable_gl = ozone_platform_gbm || !is_linux || (use_x11 && !is_chromeos)
  
    angle_enable_vulkan = is_win || (is_linux && use_x11 && !is_chromeos) ||
                          (is_android && ndk_supports_vulkan)
    angle_enable_null = true
    angle_enable_essl = true
    angle_enable_glsl = true
  }
  
  declare_args() {
    angle_enable_gl_null = angle_enable_gl
    angle_enable_hlsl = angle_enable_d3d9 || angle_enable_d3d11
  }
  
  if (is_win) {
    import("//build/config/win/visual_studio_version.gni")
  }