kc3-lang/angle/src/libOpenCL/BUILD.gn

• Show log

  Commit

• Hash : baca10b7
  Author :
  Date : 2021-05-29T16:26:57
  

  CL: Remove object cache and fix multi-threading
  
  All CL front end objects used to be cached to be able to determine
  if an object has been created by the front end to check its validity.
  The validity is now checked with the existence of an intrinsic value
  (the dispatch table pointer), which is consistent with the patterns
  found in Mesa and clvk (though clvk uses a magic value).
  This allows the removal of all cached objects.
  
  The cached objects were stored with std::unique_ptr. These are now
  gone and all remaining pointers are now custom intrinsic reference
  count pointers.
  
  Also remove global lock which causes deadlocks, e.g. when CL API
  is called from a separate thread to unlock a blocking call with
  a user event. Most of the front end is constant and already
  thread-safe. The ref count is also thread-safe now (atomic).
  A few remaining locks will follow.
  Without the global lock it was now possible to make the API
  reentrant, and to remove the workaround with the Khronos ICD
  loader to skip ANGLE's OpenCL library.
  
  Bug: angleproject:6001
  Change-Id: I7d3b52db9011a02cb7ea9ebdeb6e22c4c702ef5b
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2927395
  Commit-Queue: John Plate <jplate@google.com>
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  Reviewed-by: Cody Northrop <cnorthrop@google.com>
  

Download

• src/libOpenCL/BUILD.gn

• # Copyright 2021 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  #
  # Build configuration for OpenCL-related targets.
  
  import("../../gni/angle.gni")
  
  assert(angle_enable_cl)
  
  if (is_win || is_linux) {
    glesv2_path =
        rebase_path(get_label_info("$angle_root:libGLESv2", "root_out_dir"))
  }
  
  angle_shared_library("OpenCL_ANGLE") {
    defines = [ "LIBCL_IMPLEMENTATION" ]
    if (is_win) {
      defines += [ "ANGLE_GLESV2_LIBRARY_PATH=\"" +
                   string_replace(glesv2_path, "/", "\\\\") + "\"" ]
    }
  
    sources = [
      "dispatch.cpp",
      "dispatch.h",
      "libOpenCL_autogen.cpp",
    ]
  
    configs += [
      "$angle_root:debug_annotations_config",
      "$angle_root:library_name_config",
    ]
  
    deps = [
      "$angle_root:angle_common",
      "$angle_root:cl_includes",
    ]
  
    if (is_linux) {
      inputs = [ "libOpenCL_autogen.map" ]
      ldflags = [
        "-Wl,--version-script=" +
            rebase_path("libOpenCL_autogen.map", root_build_dir),
        "-Wl,-rpath=" + glesv2_path,
      ]
    }
  }
  
  group("angle_cl") {
    data_deps = [ ":OpenCL_ANGLE" ]
  }
  

Download