kc3-lang/angle/android/angle_apk.gni

• Show log

  Commit

• Hash : 3ad3a9ac
  Author :
  Date : 2021-04-01T17:40:26
  

  Fix and re-enable component build of angle_apks
  
  These were disabled in http://crrev.com/c/1387344, after breaking
  android-dbg (now android-archive-dbg) in crbug.com/916751.
  
  Re-enable them, so that CQ bots can be switched to component build,
  which is more stable due to http://anglebug.com/4396.
  
  The fix is to correct the library names,
  which have .cr.so suffix in component builds.
  
  Bug: angleproject:4483, angleproject:2981, chromium:916751
  Change-Id: Ie9cb6e11513ecd2b5e4daa3f636296a4500ddfb9
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/2800193
  Commit-Queue: Yuly Novikov <ynovikov@chromium.org>
  Reviewed-by: Jamie Madill <jmadill@chromium.org>
  

Download

• android/angle_apk.gni

• # Copyright 2018 The Chromium Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  
  import("//build/config/android/rules.gni")
  import("../gni/angle.gni")
  
  vulkan_validation_layers = [ "VkLayer_khronos_validation" ]
  
  angle_libraries = [
    "libEGL",
    "libGLESv1_CM",
    "libGLESv2",
    "libfeature_support",
  ]
  
  if (enable_java_templates) {
    template("angle_apk") {
      manifest_target_name = "${target_name}__manifest"
      manifest_path =
          "${target_gen_dir}/${target_name}/android/AndroidManifest.xml"
  
      jinja_template(manifest_target_name) {
        input = "//third_party/angle/android/AndroidManifest.xml.jinja2"
        output = manifest_path
        variables = [
          "manifest_package=${invoker.package_name}",
          "extract_native_libs=${angle_extract_native_libs}",
        ]
      }
  
      android_assets("${invoker.package_name}_assets") {
        disable_compression = true
        sources = [ "src/feature_support_util/a4a_rules.json" ]
      }
  
      android_apk(target_name) {
        forward_variables_from(invoker, "*")
        android_manifest = manifest_path
        android_manifest_dep = ":$manifest_target_name"
        version_code = invoker.version_code
        version_name = invoker.version_name
        min_sdk_version = 26
        target_sdk_version = 28
        deps = [ ":${invoker.package_name}_assets" ]
        if (symbol_level != 0) {
          deps += [ ":compressed_symbols" ]
          if (android_64bit_target_cpu) {
            deps += [ ":compressed_symbols($android_secondary_abi_toolchain)" ]
          }
        }
  
        uncompress_shared_libraries = true
  
        if (android_64bit_target_cpu) {
          if (symbol_level == 0) {
            secondary_abi_shared_libraries = []
            foreach(_library, angle_libraries) {
              secondary_abi_shared_libraries +=
                  [ "$angle_root:${_library}($android_secondary_abi_toolchain)" ]
            }
            if (angle_enable_vulkan_validation_layers) {
              foreach(_layer, vulkan_validation_layers) {
                secondary_abi_shared_libraries +=
                    [ "$angle_vulkan_validation_layers_dir:${_layer}" +
                      "($android_secondary_abi_toolchain)" ]
              }
            }
          } else {
            _secondary_out_dir = get_label_info(
                    ":compressed_symbols($android_secondary_abi_toolchain)",
                    "root_out_dir")
            secondary_abi_loadable_modules = []
            foreach(_library, angle_libraries) {
              if (is_component_build) {
                secondary_abi_loadable_modules += [ "$_secondary_out_dir/lib.compressed/${_library}${angle_libs_suffix}.cr.so" ]
              } else {
                secondary_abi_loadable_modules += [ "$_secondary_out_dir/lib.compressed/${_library}${angle_libs_suffix}.so" ]
              }
            }
            if (angle_enable_vulkan_validation_layers) {
              foreach(_layer, vulkan_validation_layers) {
                if (is_component_build) {
                  secondary_abi_loadable_modules += [
                    "${_secondary_out_dir}/lib.compressed/lib${_layer}.cr.so",
                  ]
                } else {
                  secondary_abi_loadable_modules +=
                      [ "${_secondary_out_dir}/lib.compressed/lib${_layer}.so" ]
                }
              }
            }
          }
        }
  
        if (symbol_level == 0) {
          shared_libraries = []
          foreach(_library, angle_libraries) {
            shared_libraries += [ "$angle_root:$_library" ]
          }
          if (angle_enable_vulkan_validation_layers) {
            foreach(_layer, vulkan_validation_layers) {
              shared_libraries +=
                  [ "$angle_vulkan_validation_layers_dir:${_layer}" ]
            }
          }
        } else {
          loadable_modules = []
          foreach(_library, angle_libraries) {
            if (is_component_build) {
              loadable_modules += [ "$root_out_dir/lib.compressed/${_library}${angle_libs_suffix}.cr.so" ]
            } else {
              loadable_modules += [
                "$root_out_dir/lib.compressed/${_library}${angle_libs_suffix}.so",
              ]
            }
          }
          if (angle_enable_vulkan_validation_layers) {
            foreach(_layer, vulkan_validation_layers) {
              if (is_component_build) {
                loadable_modules +=
                    [ "$root_out_dir/lib.compressed/lib${_layer}.cr.so" ]
              } else {
                loadable_modules +=
                    [ "$root_out_dir/lib.compressed/lib${_layer}.so" ]
              }
            }
          }
        }
      }
    }
  }
  

Download