kc3-lang/angle/src/libANGLE/renderer/metal/QueryMtl.mm

• Show log

  Commit

• Hash : da3db87e
  Author :
  Date : 2021-07-06T14:00:58
  

  Upstream latest changes to Metal backend from Apple to 7/1/2021
  
  This CL merges in the ANGLE changes between these two WebKit commits:
  https://git.webkit.org/?p=WebKit.git;a=commit;h=8648b353ab1d7730438c2e08319e1a4d64982c31
  https://git.webkit.org/?p=WebKit.git;a=commit;h=166e4924a52971d6a32ad48247a439b16c00e062
  
  Include provoking vertex buffer out of bounds fix
  from https://bugs.webkit.org/show_bug.cgi?id=230107
  
  Fix bad merge of resetting of dirty bits, breaking
  DepthStencilFormatsTest.DepthTextureRender test and perhaps others.
  
  Disable GL_APPLE_clip_distance when the direct-to-Metal compiler is
  active. It can not yet handle the gl_ClipDistance array.
  
  Disable use of rectangular textures for IOSurfaces. Metal can bind
  IOSurfaces to 2D textures, and this was passing all tests in the
  SPIR-V Metal backend. Introducing rectangular textures breaks the
  SPIR-V Metal backend, and the tests currently fail on the
  direct-to-Metal backend.
  
  Fix several bugs with ProvokingVertex, which was causing
  both the SpirV and Direct backends to incorrectly draw
  indices.
  (https://bugs.webkit.org/show_bug.cgi?id=230107)
  
  Skip the following tests on the Metal backend which is still failing
    RobustResourceInitTestES3.BlitDepthStencilAfterClearBuffer
    GLSLTest_ES3.GLVertexIDIntegerTextureDrawArrays/ES3_Metal
  
  With these changes, angle_end2end_tests again runs to completion.
  
  Bug: angleproject:6395
  Change-Id: I3cc58f531426a95fc8f177a4ad87f56c1855a546
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/3167010
  Reviewed-by: Jonah Ryan-Davis <jonahr@google.com>
  Reviewed-by: Kenneth Russell <kbr@chromium.org>
  Commit-Queue: Kyle Piddington <kpiddington@apple.com>
  

Download

• src/libANGLE/renderer/metal/QueryMtl.mm

• //
  // Copyright (c) 2020 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  // QueryMtl.mm:
  //    Defines the class interface for QueryMtl, implementing QueryImpl.
  //
  
  #include "libANGLE/renderer/metal/QueryMtl.h"
  
  #include "libANGLE/renderer/metal/ContextMtl.h"
  
  namespace rx
  {
  QueryMtl::QueryMtl(gl::QueryType type) : QueryImpl(type), mTransformFeedbackPrimitivesDrawn(0) {}
  
  QueryMtl::~QueryMtl() {}
  
  void QueryMtl::onDestroy(const gl::Context *context)
  {
      ContextMtl *contextMtl = mtl::GetImpl(context);
      if (!getAllocatedVisibilityOffsets().empty())
      {
          contextMtl->onOcclusionQueryDestroy(context, this);
      }
      mVisibilityResultBuffer = nullptr;
  }
  
  angle::Result QueryMtl::begin(const gl::Context *context)
  {
      ContextMtl *contextMtl = mtl::GetImpl(context);
      switch (getType())
      {
          case gl::QueryType::AnySamples:
          case gl::QueryType::AnySamplesConservative:
              if (!mVisibilityResultBuffer)
              {
                  // Allocate buffer
                  ANGLE_TRY(mtl::Buffer::MakeBuffer(contextMtl, mtl::kOcclusionQueryResultSize,
                                                    nullptr, &mVisibilityResultBuffer));
  
                  ANGLE_MTL_OBJC_SCOPE
                  {
                      mVisibilityResultBuffer->get().label =
                          [NSString stringWithFormat:@"QueryMtl=%p", this];
                  }
              }
  
              ANGLE_TRY(contextMtl->onOcclusionQueryBegin(context, this));
              break;
          case gl::QueryType::TransformFeedbackPrimitivesWritten:
              mTransformFeedbackPrimitivesDrawn = 0;
              break;
          default:
              UNIMPLEMENTED();
              break;
      }
  
      return angle::Result::Continue;
  }
  angle::Result QueryMtl::end(const gl::Context *context)
  {
      ContextMtl *contextMtl = mtl::GetImpl(context);
      switch (getType())
      {
          case gl::QueryType::AnySamples:
          case gl::QueryType::AnySamplesConservative:
              contextMtl->onOcclusionQueryEnd(context, this);
              break;
          case gl::QueryType::TransformFeedbackPrimitivesWritten:
              onTransformFeedbackEnd(context);
              break;
          default:
              UNIMPLEMENTED();
              break;
      }
      return angle::Result::Continue;
  }
  angle::Result QueryMtl::queryCounter(const gl::Context *context)
  {
      UNIMPLEMENTED();
      return angle::Result::Continue;
  }
  
  template <typename T>
  angle::Result QueryMtl::waitAndGetResult(const gl::Context *context, T *params)
  {
      ASSERT(params);
      ContextMtl *contextMtl = mtl::GetImpl(context);
      switch (getType())
      {
          case gl::QueryType::AnySamples:
          case gl::QueryType::AnySamplesConservative:
          {
              ASSERT(mVisibilityResultBuffer);
              if (mVisibilityResultBuffer->hasPendingWorks(contextMtl))
              {
                  contextMtl->flushCommandBuffer(mtl::NoWait);
              }
              // map() will wait for the pending GPU works to finish
              const uint8_t *visibilityResultBytes = mVisibilityResultBuffer->mapReadOnly(contextMtl);
              uint64_t queryResult;
              memcpy(&queryResult, visibilityResultBytes, sizeof(queryResult));
              mVisibilityResultBuffer->unmap(contextMtl);
  
              *params = queryResult ? GL_TRUE : GL_FALSE;
          }
          break;
          case gl::QueryType::TransformFeedbackPrimitivesWritten:
              *params = static_cast<T>(mTransformFeedbackPrimitivesDrawn);
              break;
          default:
              UNIMPLEMENTED();
              break;
      }
      return angle::Result::Continue;
  }
  
  angle::Result QueryMtl::isResultAvailable(const gl::Context *context, bool *available)
  {
      ASSERT(available);
      ContextMtl *contextMtl = mtl::GetImpl(context);
      // glGetQueryObjectuiv implicitly flush any pending works related to the query
      switch (getType())
      {
          case gl::QueryType::AnySamples:
          case gl::QueryType::AnySamplesConservative:
              ASSERT(mVisibilityResultBuffer);
              if (mVisibilityResultBuffer->hasPendingWorks(contextMtl))
              {
                  contextMtl->flushCommandBuffer(mtl::NoWait);
              }
  
              *available = !mVisibilityResultBuffer->isBeingUsedByGPU(contextMtl);
              break;
          case gl::QueryType::TransformFeedbackPrimitivesWritten:
              *available = true;
              break;
          default:
              UNIMPLEMENTED();
              break;
      }
      return angle::Result::Continue;
  }
  
  angle::Result QueryMtl::getResult(const gl::Context *context, GLint *params)
  {
      return waitAndGetResult(context, params);
  }
  angle::Result QueryMtl::getResult(const gl::Context *context, GLuint *params)
  {
      return waitAndGetResult(context, params);
  }
  angle::Result QueryMtl::getResult(const gl::Context *context, GLint64 *params)
  {
      return waitAndGetResult(context, params);
  }
  angle::Result QueryMtl::getResult(const gl::Context *context, GLuint64 *params)
  {
      return waitAndGetResult(context, params);
  }
  
  void QueryMtl::resetVisibilityResult(ContextMtl *contextMtl)
  {
      // Occlusion query buffer must be allocated in QueryMtl::begin
      ASSERT(mVisibilityResultBuffer);
  
      // Fill the query's buffer with zeros
      auto blitEncoder = contextMtl->getBlitCommandEncoder();
      blitEncoder->fillBuffer(mVisibilityResultBuffer, NSMakeRange(0, mtl::kOcclusionQueryResultSize),
                              0);
      mVisibilityResultBuffer->syncContent(contextMtl, blitEncoder);
  }
  
  void QueryMtl::onTransformFeedbackEnd(const gl::Context *context)
  {
      gl::TransformFeedback *transformFeedback = context->getState().getCurrentTransformFeedback();
      if (transformFeedback)
      {
          mTransformFeedbackPrimitivesDrawn += transformFeedback->getPrimitivesDrawn();
      }
  }
  
  }
  

Download