kc3-lang/angle/src/libANGLE/renderer/vulkan/mac/WindowSurfaceVkMac.mm

• Show log

  Commit

• Hash : 63b54d9d
  Author :
  Date : 2022-03-09T17:04:13
  

  Do not copy parent layer frame position
  
  The position value in a frame refers to its relative position to
  its parent. We do not want to copy that to its new child layer.
  
  Test: when using ANGLE (with metal or swiftshader backend) with
  emulator frame, it should render the emulator at the right
  position.
  Bug: angleproject:7097
  Change-Id: I94f78e1253d7ee016bf7ab512d908f75250ce9c7
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/3523622
  Reviewed-by: Kenneth Russell <kbr@chromium.org>
  Reviewed-by: Jonah Ryan-Davis <jonahr@google.com>
  Auto-Submit: Yahan Zhou <yahan@google.com>
  Reviewed-by: Yahan Zhou <yahan@google.com>
  Commit-Queue: Kenneth Russell <kbr@chromium.org>
  

Download

• src/libANGLE/renderer/vulkan/mac/WindowSurfaceVkMac.mm

• //
  // Copyright 2019 The ANGLE Project Authors. All rights reserved.
  // Use of this source code is governed by a BSD-style license that can be
  // found in the LICENSE file.
  //
  // WindowSurfaceVkMac.mm:
  //    Implements methods from WindowSurfaceVkMac.
  //
  
  #include "libANGLE/renderer/vulkan/mac/WindowSurfaceVkMac.h"
  
  #include <Metal/Metal.h>
  #include <QuartzCore/CAMetalLayer.h>
  
  #include "libANGLE/renderer/vulkan/RendererVk.h"
  #include "libANGLE/renderer/vulkan/vk_utils.h"
  
  namespace rx
  {
  
  WindowSurfaceVkMac::WindowSurfaceVkMac(const egl::SurfaceState &surfaceState,
                                         EGLNativeWindowType window)
      : WindowSurfaceVk(surfaceState, window), mMetalLayer(nullptr)
  {}
  
  WindowSurfaceVkMac::~WindowSurfaceVkMac()
  {
      [mMetalDevice release];
      [mMetalLayer release];
  }
  
  angle::Result WindowSurfaceVkMac::createSurfaceVk(vk::Context *context, gl::Extents *extentsOut)
      API_AVAILABLE(macosx(10.11))
  {
      mMetalDevice = MTLCreateSystemDefaultDevice();
  
      CALayer *layer = reinterpret_cast<CALayer *>(mNativeWindowType);
  
      mMetalLayer        = [[CAMetalLayer alloc] init];
      mMetalLayer.frame  = CGRectMake(0, 0, layer.frame.size.width, layer.frame.size.height);
      mMetalLayer.device = mMetalDevice;
      mMetalLayer.drawableSize =
          CGSizeMake(mMetalLayer.bounds.size.width * mMetalLayer.contentsScale,
                     mMetalLayer.bounds.size.height * mMetalLayer.contentsScale);
      mMetalLayer.framebufferOnly  = NO;
      mMetalLayer.autoresizingMask = kCALayerWidthSizable | kCALayerHeightSizable;
      mMetalLayer.contentsScale    = layer.contentsScale;
  
      [layer addSublayer:mMetalLayer];
  
      VkMetalSurfaceCreateInfoEXT createInfo = {};
      createInfo.sType                       = VK_STRUCTURE_TYPE_METAL_SURFACE_CREATE_INFO_EXT;
      createInfo.flags                       = 0;
      createInfo.pNext                       = nullptr;
      createInfo.pLayer                      = mMetalLayer;
      ANGLE_VK_TRY(context, vkCreateMetalSurfaceEXT(context->getRenderer()->getInstance(),
                                                    &createInfo, nullptr, &mSurface));
  
      return getCurrentWindowSize(context, extentsOut);
  }
  
  angle::Result WindowSurfaceVkMac::getCurrentWindowSize(vk::Context *context,
                                                         gl::Extents *extentsOut)
      API_AVAILABLE(macosx(10.11))
  {
      ANGLE_VK_CHECK(context, (mMetalLayer != nullptr), VK_ERROR_INITIALIZATION_FAILED);
  
      mMetalLayer.drawableSize =
          CGSizeMake(mMetalLayer.bounds.size.width * mMetalLayer.contentsScale,
                     mMetalLayer.bounds.size.height * mMetalLayer.contentsScale);
      *extentsOut = gl::Extents(static_cast<int>(mMetalLayer.drawableSize.width),
                                static_cast<int>(mMetalLayer.drawableSize.height), 1);
  
      return angle::Result::Continue;
  }
  
  }  // namespace rx
  

Download