kc3-lang/angle/src/tests/restricted_traces/BUILD.gn

• Show log

  Commit

• Hash : 4df8ca04
  Author :
  Date : 2022-05-11T09:03:33
  

  Remove angle_util from restricted traces.
  
  This target is not needed because the traces use a custom GL/EGL
  loader. This way we can be sure we don't call the wrong entry
  points.
  
  Bug: angleproject:4964
  Change-Id: I5bfa29f087d47ab598ae0ae5ac2ddf9aa04806b2
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/3641924
  Reviewed-by: Cody Northrop <cnorthrop@google.com>
  Commit-Queue: Jamie Madill <jmadill@chromium.org>
  

Download

• src/tests/restricted_traces/BUILD.gn

• # Copyright 2020 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  #
  # Contains the build rules for confidential trace tests.
  
  import("../../../gni/angle.gni")
  
  angle_shared_library("angle_restricted_trace_loader") {
    sources = [
      "restricted_traces_export.h",
      "trace_egl_loader_autogen.cpp",
      "trace_egl_loader_autogen.h",
      "trace_gles_loader_autogen.cpp",
      "trace_gles_loader_autogen.h",
    ]
    defines = [ "ANGLE_TRACE_LOADER_IMPLEMENTATION" ]
    deps = [ "$angle_root:includes" ]
  }
  
  angle_trace_fixture("angle_restricted_trace_fixture") {
    gl_header = "angle_trace_gl.h"
    public_deps = [ ":angle_restricted_trace_loader" ]
    public_configs = [ "$angle_root:no_gl_prototypes" ]
  }
  
  angle_trace_library("angle_restricted_trace") {
    json_path = "restricted_traces.json"
    trace_fixture = ":angle_restricted_trace_fixture"
  }
  
  angle_shared_library("angle_restricted_traces") {
    testonly = true
  
    sources = [ "restricted_traces_export.h" ]
  
    data = [ "restricted_traces.json" ]
  
    data_deps = [ ":angle_restricted_trace" ]
    defines = [ "ANGLE_TRACE_IMPLEMENTATION" ]
  
    deps = [ "$angle_root:angle_common" ]
    public_deps = [ ":angle_restricted_trace_loader" ]
  }
  
  group("goldctl") {
    data = []
  
    # Because this links to a CIPD dependency, which is a symlink on Unix
    # platforms, refer to the actual executable rather than the whole directory;
    # copying the whole directory doesn't work, at least with "mb.py zip".
    if (is_win) {
      data += [ "//tools/skia_goldctl/win/goldctl.exe" ]
    } else if (is_mac) {
      data += [
        "//tools/skia_goldctl/mac_amd64/goldctl",
        "//tools/skia_goldctl/mac_arm64/goldctl",
      ]
    } else {
      data += [ "//tools/skia_goldctl/linux/goldctl" ]
    }
  }
  
  group("angle_restricted_trace_gold_tests") {
    testonly = true
    data_deps = [
      ":goldctl",
      "$angle_root/src/tests:angle_perftests",
      "$angle_root/src/tests:angle_system_info_test",
    ]
    data = [
      "restricted_trace_gold_tests.py",
      "restricted_traces.json",
      "../py_utils/android_helper.py",
      "../py_utils/angle_path_util.py",
      "../py_utils/angle_test_util.py",
      "../py_utils/skia_gold/",
      "//build/skia_gold_common/",
      "//testing/scripts/common.py",
      "//testing/xvfb.py",
    ]
  }
  

Download