kc3-lang/angle/third_party/OpenCL-CTS/gn/angle_ocl_cts.gni

Branch - branch -main

• Show log

  Commit

• Hash : 059734f9
  Author :
  Date : 2025-05-02T13:20:28
  

  CL: Roll OpenCL headers, docs, CTS, loader
  
  Updated OpenCL headers
  and updated third_party sources accordingly.
  
  - Updated OpenCL Headers from change 265df85
  - Updated third_party/OpenCL-Docs
  - Updated third_party/OpenCL-CTS and modified ninja build corresponding
  to update
  - Updated third_party/OpenCL-ICD-Loader and modified ninja build
  corresponding to update
  - When after updating OpenCL-Docs, entry-points for
  clIcdGetFunctionAddressForPlatformKHR and
  clIcdSetPlatformDispatchDataKHR (cl_khr_icd 2.0.0) are generated by
  run_code_generation.py. Filled code returning INVALID_OPERATION error
  in the entry-points.
  - When after updating cl_ext.h, cl_khr_external_memory_dx is removed.
  Deleted codes referencing cl_khr_external_memory_dx (e.q.,
  CL_EXTERNAL_MEMORY_HANDLE_D3D11_TEXTURE_KHR)
  
  Bug: angleproject:441956395
  Tests-Passing: test_basic, test_api
  Change-Id: I08e0b78abb5c0ff5f1ea693ea355893b1a6f765e
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/6915959
  Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
  Commit-Queue: Austin Annestrand <a.annestrand@samsung.com>
  

Download

• third_party/OpenCL-CTS/gn/angle_ocl_cts.gni

• # Copyright 2024 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  
  import("//gni/angle.gni")
  
  template("ocl_cts_source_set") {
    angle_source_set(target_name) {
      cflags = [
        "-Wno-deprecated-declarations",
        "-Wno-#warnings",
        "-Wno-format",
        "-Wno-vla-cxx-extension",
        "-Wno-deprecated-volatile",
        "-Wno-c++11-narrowing",
      ]
      defines = [ "CL_TARGET_OPENCL_VERSION=300" ]
      defines += [ "CL_USE_DEPRECATED_OPENCL_2_2_APIS=1" ]
      defines += [ "CL_USE_DEPRECATED_OPENCL_2_1_APIS=1" ]
      defines += [ "CL_USE_DEPRECATED_OPENCL_2_0_APIS=1" ]
      defines += [ "CL_USE_DEPRECATED_OPENCL_1_2_APIS=1" ]
      defines += [ "CL_USE_DEPRECATED_OPENCL_1_1_APIS=1" ]
      defines += [ "CL_USE_DEPRECATED_OPENCL_1_0_APIS=1" ]
      defines += [ "CL_NO_EXTENSION_PROTOTYPES" ]
      defines += [ "CL_ENABLE_BETA_EXTENSIONS" ]
  
      # Rename main() to avoid conflict with the gtest-based main()
      defines += [ "main=ANGLE_oclcts_main" ]
      deps = [
        "$angle_root:cl_includes",
        "$angle_root/third_party/OpenCL-CTS/gn:test_common",
        "$angle_root/third_party/OpenCL-ICD-Loader:opencl_icd_loader",
      ]
      suppressed_configs += [
        "//build/config/compiler:chromium_code",
        "//build/config/compiler:no_exceptions",
        "//build/config/compiler:no_rtti",
        "$angle_root:extra_warnings",
        "$angle_root:constructor_and_destructor_warnings",
      ]
      include_dirs = [
        "$angle_root/third_party/OpenCL-CTS/src/test_common",
        "$angle_root/third_party/OpenCL-CTS/src/test_common/autotest",
        "$angle_root/third_party/OpenCL-CTS/src/test_common/harness",
        "$angle_root/third_party/OpenCL-CTS/src/test_common/miniz",
        "$angle_root/third_party/OpenCL-ICD-Loader/src/loader",
      ]
  
      forward_variables_from(invoker,
                             "*",
                             [
                               "configs",
                               "deps",
                               "include_dirs",
                               "cflags",
                             ])
      if (defined(invoker.configs)) {
        configs += invoker.configs
      }
      if (defined(invoker.deps)) {
        deps += invoker.deps
      }
      if (defined(invoker.include_dirs)) {
        include_dirs += invoker.include_dirs
      }
      if (defined(invoker.cflags)) {
        cflags += invoker.cflags
      }
    }
  }
  

Download