kc3-lang/angle/third_party/glmark2/BUILD.gn

Branch - branch -main

• Show log

  Commit

• Hash : d9c0aa4a
  Author :
  Date : 2025-01-09T18:08:08
  

  Reland "Roll third_party/glmark2/src/ ca8de51fe..2054465f6 (77 commits)"
  
  This is a reland of commit 68b594e859f036b01974f78f8ddca8c419bc8ce3
  
  Includes fixes to glmark2Benchmark.cpp to parse updated output.
  
  Original change's description:
  > Roll third_party/glmark2/src/ ca8de51fe..2054465f6 (77 commits)
  >
  > https://chromium.googlesource.com/external/github.com/glmark2/glmark2/+log/ca8de51fedb7..2054465f6f7c
  >
  > $ git log ca8de51fe..2054465f6 --date=short --no-merges --format='%ad %ae %s'
  > 2024-04-25 alexandros.frantzis Use std::filesystem throughout the codebase
  > 2024-04-25 alexandros.frantzis android: Build native code with C++17
  > 2024-04-25 alexandros.frantzis Doc: Recommend meson for building win32 flavors
  > 2024-04-25 alexandros.frantzis github: Build win32 flavors with msvc in CI
  > 2024-04-25 alexandros.frantzis github: Build win32 flavors with mingw in CI
  > 2024-04-25 alexandros.frantzis include/getopt: Always use non-const char array to avoid MSVC errors
  > 2024-04-25 alexandros.frantzis libmatrix: Add utility function to get idle time
  > 2024-04-25 alexandros.frantzis libmatrix: Add utility function to get process times
  > 2024-04-24 alexandros.frantzis libmatrix: Add utility function to get the number of processors
  > 2024-04-25 alexandros.frantzis libmatrix: Use C++ std::chrono instead of clock_gettime
  > 2024-04-25 alexandros.frantzis libmatrix: Use C++17 std::filesystem instead of dirent
  > 2024-04-25 alexandros.frantzis Build: Add support for win32 flavors in meson
  > 2024-04-24 alexandros.frantzis libmatrix: Provide a copy of the va_list to __android_log_vprint
  > 2024-04-13 kode54 NativeStateX11: Fix WM_DELETE_WINDOW handling
  > 2024-02-15 alexandros.frantzis NativeStateWayland: Explicitly destroy all Wayland resources at shutdown
  > 2024-02-15 alexandros.frantzis Explicitly release GL related resources at shutdown
  > 2023-06-03 prlw1 src/meson.build: add x11 dependency to glx
  > 2024-02-07 timchen021 Fix memory leaks using smart pointers
  > 2024-01-12 daniel.levin Add missing includes in scene-collection.h
  > 2023-11-01 alexandros.frantzis GLVisualConfig: By default don't care about the stencil config component
  > 2023-11-01 alexandros.frantzis Options,GLStateEGL,GLStateGLX: Add option to require a good visual config
  > 2023-07-26 abs GLStateEGL,GLStateGLX: Change failure to get a "good" visual config to warning
  > 2023-11-01 alexandros.frantzis libmatrix: Add Log::warning() function
  > 2023-05-20 prlw1 meson.build: fix build and avoid sigsegv
  > 2023-05-03 ofourdan NativeStateX11: Add winsys option for position
  > 2023-01-19 alexandros.frantzis Build,Doc: Update files for 2023.01 release
  > 2023-01-19 alexandros.frantzis NativeStateMir: Remove Mir/mirclient support
  > 2023-01-03 alexandros.frantzis ResultsFile: Support storing results in an XML file
  > 2023-01-03 alexandros.frantzis ResultsFile: Support storing results in a CSV file
  > 2023-01-03 alexandros.frantzis Options,ResultsFile: Add option to set the results file
  > 2023-01-03 alexandros.frantzis Introduce infrastructure to support saving results to a file
  > 2023-01-03 alexandros.frantzis CanvasGeneric: Store individual info elements in separate strings
  > 2023-01-03 alexandros.frantzis MainLoop: Store indivitual result values in separate strings
  > 2023-01-03 alexandros.frantzis Scene: Remove trailing ':' from scene info string
  > 2023-01-04 alexandros.frantzis SceneTerrain: Silence unused variable warning
  > 2022-12-21 pierre-yves.mordret NativeStateGBM: Lock and release the front buffer on flip
  > 2022-12-21 alexandros.frantzis MainLoop,Scene: Support reporting shader compilation time
  > 2022-12-20 alexandros.frantzis MainLoop,Scene: Add busy percentage in CPU time results
  > 2022-12-20 alexandros.frantzis MainLoop,Scene: Support reporting CPU time results
  > 2022-12-20 alexandros.frantzis Options: Introduce option to specify benchmark results to show
  > 2022-12-20 alexandros.frantzis Scene: Update elapsed times when a benchmark finishes
  > 2022-12-19 alexandros.frantzis Scene: Introduce struct to keep track of elapsed time
  > 2022-12-15 alexandros.frantzis Scene: Introduce infrastructure for more complex scene stats
  > 2022-12-15 alexandros.frantzis Scene: Move common preparation logic to Scene::prepare
  > 2022-12-13 alexandros.frantzis Scene: Introduce non-virtual methods to prepare and finish a scene for benchmark
  > 2022-12-08 alexandros.frantzis GLVisualConfig: Support specifying the config id in --visual-config
  > 2022-12-08 alexandros.frantzis libmatrix: Support prefix dependent input conversions from string
  > 2022-12-08 alexandros.frantzis GLStateEGL,GLStateGLX: Fail if no suitable config is found
  > 2022-12-08 alexandros.frantzis GLStateEGL,GLStateGLX: Don't limit the configs passed to our selection mechanism
  > 2022-12-08 alexandros.frantzis GLVisualConfig: Penalize configs with components smaller than requested
  > 2022-11-16 alexandros.frantzis github: Build x11-gl-egl flavor in CI
  > 2022-11-14 rilian-la-te build: Add x11-gl-egl flavor
  > 2022-11-10 alexandros.frantzis GLStateGLX: Support multisampled configs
  > 2022-11-10 l.stach GLStateEGL: Support multisampled configs
  > 2022-11-10 l.stach GLVisualConfig: Add multisampling support
  > 2022-09-02 120989324 Add missing newline at end of log messages
  > 2022-11-10 alexandros.frantzis NativeStateDRM,NativeStateGBM: Support configuring the DRM device
  > 2022-11-10 alexandros.frantzis Options: Support passing window system specific options
  > 2022-04-23 nunes.erico NativeStateGBM: Add GBM offscreen backend
  > 2022-07-07 wuqianhai SceneJellyfish: Fix memory leak
  > 2022-07-07 wuqianhai SceneRefract: Fix texture leak
  > 2022-07-07 wuqianhai SceneIdeas: Fix texture leak
  > 2022-06-14 Martin.Jansa waflib: fix compatibility with python-3.11
  > 2022-05-12 jeffy.chen NativeStateDRM: Honor visual configuration
  > 2022-05-13 alexandros.frantzis GLStateEGL,GLStateGLX: Use SwapInterval 1 for FIFO swap mode
  > 2022-04-15 alexandros.frantzis NativeStateDrm: Implement swap interval 0
  > 2022-02-14 alexandros.frantzis github: Run apt-get update to get latest packages
  > 2022-02-14 alexandros.frantzis CanvasGeneric,CanvasAndroid: Display surface config info
  > 2022-02-14 alexandros.frantzis Options: Support --version command line argument
  > 2022-02-14 alexandros.frantzis libmatrix: Add missing <utility> include
  > 2022-02-10 hillma libmatrix: avoid -Wimplicit-fallthrough
  > 2021-12-23 alexandros.frantzis Build,Doc: Update files for 2021.12 release
  > 2021-12-23 alexandros.frantzis NativeStateDrm: Fix crash when we can't become DRM master
  > 2021-09-30 jf android: Fix benchmark parameter edition
  > 2021-08-30 alexandros.frantzis Use highp precision modifier only on GLES
  > 2021-08-30 alexandros.frantzis GLStateEGL: Support EGL versions < 1.4
  > 2021-04-11 maahiuzeon Fix model loading on big endian.
  >
  > Created with:
  >   roll-dep third_party/glmark2/src
  >
  > Bug: chromium:40263312
  > No-Presubmit: true
  > Change-Id: Ifee506badac67ff5af57605994daff01278c6d56
  > Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/6162277
  > Reviewed-by: Yuly Novikov <ynovikov@chromium.org>
  > Auto-Submit: Takuto Ikuta <tikuta@chromium.org>
  > Commit-Queue: Yuly Novikov <ynovikov@chromium.org>
  
  Test: angle_perftests --gtest_filter="*GLMark2Benchmark*"
  Bug: chromium:40263312
  Change-Id: I54d8982cb37e488f80b7511ad0111d1ff111f004
  Reviewed-on: https://chromium-review.googlesource.com/c/angle/angle/+/6174747
  Reviewed-by: Roman Lavrov <romanl@google.com>
  Commit-Queue: Cody Northrop <cnorthrop@google.com>
  Reviewed-by: Shahbaz Youssefi <syoussefi@chromium.org>
  

Download

• third_party/glmark2/BUILD.gn

• # Copyright 2019 The ANGLE Project Authors. All rights reserved.
  # Use of this source code is governed by a BSD-style license that can be
  # found in the LICENSE file.
  #
  # Build integration for glmark2.
  
  import("../../gni/angle.gni")
  
  _glmark2_glad_common_sources = [
    "src/src/glad/include/glad/egl.h",
    "src/src/glad/include/glad/wgl.h",
    "src/src/glad/src/egl.c",
  ]
  
  if (is_win) {
    _glmark2_glad_common_sources += [ "src/src/glad/src/wgl.c" ]
  }
  
  config("glmark2_glad_config") {
    include_dirs = [ "src/src/glad/include" ]
  }
  
  source_set("glmark2_glad_gles") {
    sources = _glmark2_glad_common_sources + [
                "src/src/glad/include/glad/gles2.h",
                "src/src/glad/src/gles2.c",
              ]
    public_configs = [ ":glmark2_glad_config" ]
  }
  
  source_set("glmark2_glad_gl") {
    sources = _glmark2_glad_common_sources + [
                "src/src/glad/include/glad/gl.h",
                "src/src/glad/src/gl.c",
              ]
    public_configs = [ ":glmark2_glad_config" ]
  }
  
  glmark_data_path = "${angle_root}/third_party/glmark2/src/data"
  raw_glmark_data_path = rebase_path(glmark_data_path, root_build_dir)
  
  config("glmark2_common_config") {
    defines = [ "GLMARK_DATA_PATH=\"${raw_glmark_data_path}\"" ]
    include_dirs = [ "src/src" ]
    cflags = []
  
    if (is_clang) {
      cflags += [ "-Wno-shadow" ]
    }
  
    if (is_win) {
      include_dirs += [ "src/src/include" ]
  
      # M_PI is nonstandard.
      defines += [ "_USE_MATH_DEFINES" ]
  
      if (!is_clang) {
        cflags += [
          # MSVC warns about the copyright character being illegal.
          "/wd4828",
  
          # A warning generated in scene-effect-2d in vec2::calc_offset
          "/wd4146",
  
          # Needs to be explicitly disabled after http://crrev.com/c/3189512
          "/wd4312",
        ]
      }
    }
  }
  
  config("glmark2_gles_config") {
    defines = [ "GLMARK2_USE_GLESv2" ]
  }
  
  config("glmark2_gl_config") {
    defines = [ "GLMARK2_USE_GL" ]
  }
  
  group("glmark2_gles") {
    public_configs = [
      ":glmark2_common_config",
      ":glmark2_gles_config",
    ]
    public_deps = [ ":glmark2_glad_gles" ]
  }
  
  group("glmark2_gl") {
    public_configs = [
      ":glmark2_common_config",
      ":glmark2_gl_config",
    ]
    public_deps = [ ":glmark2_glad_gl" ]
  }
  
  # Supplies compatible headers on Win32.
  config("glmark2_headers_config") {
    if (is_win) {
      if (is_clang) {
        cflags = [
          "-Wno-unused-function",
          "-Wno-writable-strings",
          "-Wno-extra-tokens",
        ]
      }
    }
  }
  
  source_set("glmark2_headers") {
    sources = [
      "src/src/canvas.h",
      "src/src/gl-headers.h",
      "src/src/gl-state-egl.h",
      "src/src/gl-state.h",
      "src/src/gl-visual-config.h",
      "src/src/mesh.h",
      "src/src/options.h",
      "src/src/scene.h",
      "src/src/shared-library.h",
      "src/src/texture.h",
    ]
  
    if (is_linux || is_chromeos) {
      sources += [ "src/src/gl-state-glx.h" ]
    }
    if (is_win) {
      sources += [
        "src/src/gl-state-wgl.h",
        "src/src/include/getopt.h",
      ]
    }
    public_configs = [ ":glmark2_headers_config" ]
    include_dirs = [ "src/src" ]
  }
  
  config("glmark2_libmatrix_config") {
    include_dirs = [ "src/src/libmatrix" ]
  }
  
  template("glmark2_libmatrix") {
    source_set(target_name) {
      forward_variables_from(invoker, "*")
      sources = [
        "src/src/libmatrix/gl-if.h",
        "src/src/libmatrix/log.cc",
        "src/src/libmatrix/log.h",
        "src/src/libmatrix/mat.cc",
        "src/src/libmatrix/mat.h",
        "src/src/libmatrix/program.cc",
        "src/src/libmatrix/program.h",
        "src/src/libmatrix/shader-source.cc",
        "src/src/libmatrix/shader-source.h",
        "src/src/libmatrix/stack.h",
        "src/src/libmatrix/util.cc",
        "src/src/libmatrix/util.h",
        "src/src/libmatrix/vec.h",
      ]
  
      if (is_clang) {
        cflags_cc = [ "-Wno-implicit-fallthrough" ]
      }
      public_deps = [ ":glmark2_headers" ]
      public_configs = [ ":glmark2_libmatrix_config" ]
      configs += [ "//build/config/compiler:exceptions" ]
      configs -= [ "//build/config/compiler:no_exceptions" ]
    }
  }
  
  glmark2_libmatrix("glmark2_libmatrix_gles") {
    deps = [ ":glmark2_gles" ]
  }
  
  glmark2_libmatrix("glmark2_libmatrix_gl") {
    deps = [ ":glmark2_gl" ]
  }
  
  config("glmark2_scene_ideas_config") {
    include_dirs = [ "src/src/scene-ideas" ]
  }
  
  template("glmark2_scene_ideas") {
    source_set(target_name) {
      forward_variables_from(invoker, "*")
      sources = [
        "src/src/scene-ideas/a.cc",
        "src/src/scene-ideas/characters.h",
        "src/src/scene-ideas/d.cc",
        "src/src/scene-ideas/e.cc",
        "src/src/scene-ideas/i.cc",
        "src/src/scene-ideas/lamp.cc",
        "src/src/scene-ideas/lamp.h",
        "src/src/scene-ideas/logo.cc",
        "src/src/scene-ideas/logo.h",
        "src/src/scene-ideas/m.cc",
        "src/src/scene-ideas/n.cc",
        "src/src/scene-ideas/o.cc",
        "src/src/scene-ideas/s.cc",
        "src/src/scene-ideas/splines.cc",
        "src/src/scene-ideas/splines.h",
        "src/src/scene-ideas/t.cc",
        "src/src/scene-ideas/table.cc",
        "src/src/scene-ideas/table.h",
      ]
      public_configs = [ ":glmark2_scene_ideas_config" ]
    }
  }
  
  glmark2_scene_ideas("glmark2_scene_ideas_gles") {
    deps = [
      ":glmark2_gles",
      ":glmark2_libmatrix_gles",
    ]
  }
  
  glmark2_scene_ideas("glmark2_scene_ideas_gl") {
    deps = [
      ":glmark2_gl",
      ":glmark2_libmatrix_gl",
    ]
  }
  
  config("glmark2_scene_terrain_config") {
    include_dirs = [ "src/src/scene-terrain" ]
  }
  
  template("glmark2_scene_terrain") {
    source_set(target_name) {
      forward_variables_from(invoker, "*")
      sources = [
        "src/src/scene-terrain/base-renderer.cpp",
        "src/src/scene-terrain/blur-renderer.cpp",
        "src/src/scene-terrain/copy-renderer.cpp",
        "src/src/scene-terrain/luminance-renderer.cpp",
        "src/src/scene-terrain/normal-from-height-renderer.cpp",
        "src/src/scene-terrain/overlay-renderer.cpp",
        "src/src/scene-terrain/renderer-chain.cpp",
        "src/src/scene-terrain/renderer.h",
        "src/src/scene-terrain/simplex-noise-renderer.cpp",
        "src/src/scene-terrain/terrain-renderer.cpp",
        "src/src/scene-terrain/texture-renderer.cpp",
      ]
  
      public_configs = [ ":glmark2_scene_terrain_config" ]
    }
  }
  
  glmark2_scene_terrain("glmark2_scene_terrain_gles") {
    deps = [
      ":glmark2_gles",
      ":glmark2_libmatrix_gles",
    ]
  }
  
  glmark2_scene_terrain("glmark2_scene_terrain_gl") {
    deps = [
      ":glmark2_gl",
      ":glmark2_libmatrix_gl",
    ]
  }
  
  template("glmark2_common") {
    source_set(target_name) {
      forward_variables_from(invoker, "*")
      sources = [
        "src/src/benchmark-collection.cpp",
        "src/src/benchmark-collection.h",
        "src/src/benchmark.cpp",
        "src/src/benchmark.h",
        "src/src/default-benchmarks.h",
        "src/src/gl-headers.cpp",
        "src/src/gl-visual-config.cpp",
        "src/src/gl-visual-config.h",
        "src/src/image-reader.cpp",
        "src/src/image-reader.h",
        "src/src/main-loop.cpp",
        "src/src/main-loop.h",
        "src/src/mesh.cpp",
        "src/src/model.cpp",
        "src/src/model.h",
        "src/src/native-state.h",
        "src/src/options.cpp",
        "src/src/results-file.cpp",
        "src/src/scene-buffer.cpp",
        "src/src/scene-build.cpp",
        "src/src/scene-bump.cpp",
        "src/src/scene-clear.cpp",
        "src/src/scene-collection.h",
        "src/src/scene-conditionals.cpp",
        "src/src/scene-default-options.cpp",
        "src/src/scene-desktop.cpp",
        "src/src/scene-effect-2d.cpp",
        "src/src/scene-function.cpp",
        "src/src/scene-grid.cpp",
        "src/src/scene-ideas.cpp",
        "src/src/scene-jellyfish.cpp",
        "src/src/scene-jellyfish.h",
        "src/src/scene-loop.cpp",
        "src/src/scene-pulsar.cpp",
        "src/src/scene-refract.cpp",
        "src/src/scene-refract.h",
        "src/src/scene-shading.cpp",
        "src/src/scene-shadow.cpp",
        "src/src/scene-terrain.cpp",
        "src/src/scene-texture.cpp",
        "src/src/scene.cpp",
        "src/src/shared-library.cpp",
        "src/src/text-renderer.cpp",
        "src/src/text-renderer.h",
        "src/src/texture.cpp",
      ]
  
      public_deps += [
        ":glmark2_headers",
        "${angle_libpng_dir}:libpng",
        "${angle_root}/third_party:jpeg",
      ]
  
      configs += [ "//build/config/compiler:exceptions" ]
      configs -= [ "//build/config/compiler:no_exceptions" ]
    }
  }
  
  glmark2_common("glmark2_common_gles") {
    public_deps = [
      ":glmark2_gles",
      ":glmark2_libmatrix_gles",
      ":glmark2_scene_ideas_gles",
      ":glmark2_scene_terrain_gles",
    ]
  }
  
  glmark2_common("glmark2_common_gl") {
    public_deps = [
      ":glmark2_gl",
      ":glmark2_libmatrix_gl",
      ":glmark2_scene_ideas_gl",
      ":glmark2_scene_terrain_gl",
    ]
  }
  
  glmark2_version = "2017.07"
  
  template("glmark2_exe") {
    executable(target_name) {
      forward_variables_from(invoker, "*")
      sources += [
        "src/src/canvas-generic.cpp",
        "src/src/canvas-generic.h",
        "src/src/main.cpp",
      ]
      data = [ "src/data/" ]
  
      defines += [
        "GLMARK_VERSION=\"${glmark2_version}\"",
        "GLMARK2_EXECUTABLE=\"${target_name}\"",
      ]
  
      if (is_win) {
        defines += [ "GLMARK2_USE_WIN32" ]
        sources += [
          "src/src/native-state-win32.cpp",
          "src/src/native-state-win32.h",
        ]
      }
      if (is_linux || is_chromeos) {
        defines += [ "GLMARK2_USE_X11" ]
        sources += [
          "src/src/native-state-x11.cpp",
          "src/src/native-state-x11.h",
        ]
        libs = [ "X11" ]
      }
    }
  }
  
  glmark2_exe("glmark2_angle") {
    sources = [ "src/src/gl-state-egl.cpp" ]
    deps = [ ":glmark2_common_gles" ]
    data_deps = [
      "${angle_root}:libEGL",
      "${angle_root}:libGLESv2",
    ]
  
    defines = [
      "EGL_EGL_PROTOTYPES=1",
      "GLMARK2_USE_EGL",
    ]
  
    if ((is_linux || is_chromeos) && !is_component_build) {
      # Set rpath to find shared libs in a non-component build.
      public_configs = [ "//build/config/gcc:rpath_for_built_shared_libraries" ]
    }
  }
  
  if (is_linux || is_chromeos) {
    glmark2_exe("glmark2_glx") {
      sources = [
        "src/src/gl-state-glx.cpp",
        "src/src/glad/include/glad/glx.h",
        "src/src/glad/src/glx.c",
      ]
      deps = [ ":glmark2_common_gl" ]
  
      defines = [ "GLMARK2_USE_GLX" ]
    }
  }
  
  # opengl32.lib/opengl32.dll are not available on Windows ARM64.
  if (is_win && target_cpu != "arm64") {
    glmark2_exe("glmark2_wgl") {
      sources = [ "src/src/gl-state-wgl.cpp" ]
      deps = [ ":glmark2_common_gl" ]
  
      libs = [ "opengl32.lib" ]
      defines = [ "GLMARK2_USE_WGL" ]
    }
  }
  

Download