kc3-lang/automake/m4/options.m4

• Show log

  Commit

• Hash : 2fd5b099
  Author :
  Date : 2008-02-19T22:15:03
  

  PR automake/498
  * m4/options.m4 (_AM_SET_OPTIONS): Use m4_foreach_w instead of
  obsolete AC_FOREACH.
  Report by NightStrike and gurganbl@rose-hulman.edu.
  

Download

• m4/options.m4

• # Helper functions for option handling.                     -*- Autoconf -*-
  
  # Copyright (C) 2001, 2002, 2003, 2005, 2008  Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 4
  
  # _AM_MANGLE_OPTION(NAME)
  # -----------------------
  AC_DEFUN([_AM_MANGLE_OPTION],
  [[_AM_OPTION_]m4_bpatsubst($1, [[^a-zA-Z0-9_]], [_])])
  
  # _AM_SET_OPTION(NAME)
  # ------------------------------
  # Set option NAME.  Presently that only means defining a flag for this option.
  AC_DEFUN([_AM_SET_OPTION],
  [m4_define(_AM_MANGLE_OPTION([$1]), 1)])
  
  # _AM_SET_OPTIONS(OPTIONS)
  # ----------------------------------
  # OPTIONS is a space-separated list of Automake options.
  AC_DEFUN([_AM_SET_OPTIONS],
  [m4_foreach_w([_AM_Option], [$1], [_AM_SET_OPTION(_AM_Option)])])
  
  # _AM_IF_OPTION(OPTION, IF-SET, [IF-NOT-SET])
  # -------------------------------------------
  # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
  AC_DEFUN([_AM_IF_OPTION],
  [m4_ifset(_AM_MANGLE_OPTION([$1]), [$2], [$3])])
  

Download