multi.m4

Branch :

Show log
Commit
Author : Akim Demaille
Date : 2001-01-16 11:04:36
Hash : 1e2c6b41
Message : * m4/multi.m4: Remove the hairy useless quotation of `$'. Simplify `ifelse([$2],,,[$2])' into... `$2'! * m4/minuso.m4: Don't use changequote! * m4/cond.m4: Fix quotation. * m4/sanity.m4: Follow the Autoconf coding style. * m4/missing.m4 (AM_MISSING_INSTALL_SH): Use a for loop. * m4/depend.m4 (AM_DEPENDENCIES): Fix quotation issues. Use AC_CACHE_CHECK.

m4/multi.m4

# serial 2

# AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
# ---------------------------------------------------
# Add --enable-multilib to configure.
AC_DEFUN([AM_ENABLE_MULTILIB],
[# Default to --enable-multilib
AC_ARG_ENABLE(multilib,
[  --enable-multilib         build many library versions (default)],
[case "$enableval" in
  yes) multilib=yes ;;
  no)  multilib=no ;;
  *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 esac],
              [multilib=yes])

# We may get other options which we are undocumented:
# --with-target-subdir, --with-multisrctop, --with-multisubdir

if test "$srcdir" = "."; then
  if test "$with_target_subdir" != "."; then
    multi_basedir="$srcdir/$with_multisrctop../$2"
  else
    multi_basedir="$srcdir/$with_multisrctop$2"
  fi
else
  multi_basedir="$srcdir/$2"
fi
AC_SUBST(multi_basedir)

AC_OUTPUT_COMMANDS([
if test -n "$CONFIG_FILES"; then
  # FIXME: Something is really fishy here, the dot looks like Perl
  # code.  What was meant?  Clearly, this code has never been exercised.
  ac_file=ifelse([$1],,Makefile,[$1]) . ${multi_basedir}/config-ml.in
fi],
                   [
srcdir="$srcdir"
host="$host"
target="$target"
with_multisubdir="$with_multisubdir"
with_multisrctop="$with_multisrctop"
with_target_subdir="$with_target_subdir"
ac_configure_args="${multilib_arg} ${ac_configure_args}"
multi_basedir="$multi_basedir"
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
CC="$CC"])])dnl

kc3-lang/automake/m4/multi.m4

Commit

kc3-lang/automake /m4/multi.m4