amversion.in

Branch :

Show log
Commit
Author : Alexandre Duret-Lutz
Date : 2006-04-21 19:02:29
Hash : 0562c007
Message : * m4/amversion.in (_AM_AUTOCONF_VERSION): New macro. (AM_SET_CURRENT_AUTOMAKE_VERSION): Call it. * aclocal.in (trace_used_macros): Trace _AM_AUTOCONF_VERSION. (write_aclocal): Output a check for Autoconf's version in aclocal.m4. Doing so ensures that users cannot build configure and Makefiles with two different autoconf versions. Report from Noah Misch. * tests/missing4.test: New file. * tests/Makefile.am (TESTS): Add it.

m4/amversion.in

##                                                          -*- Autoconf -*-
## @configure_input@
# Copyright (C) 2002, 2003, 2005, 2006  Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# AM_AUTOMAKE_VERSION(VERSION)
# ----------------------------
# Automake X.Y traces this macro to ensure aclocal.m4 has been
# generated from the m4 files accompanying Automake X.Y.
# (This private macro should not be called outside this file.)
AC_DEFUN([AM_AUTOMAKE_VERSION],
[am__api_version='@APIVERSION@'
dnl Some users find AM_AUTOMAKE_VERSION and mistake it for a way to
dnl require some minimum version.  Point them to the right macro.
m4_if([$1], [@VERSION@], [],
      [AC_FATAL([Do not call $0, use AM_INIT_AUTOMAKE([$1]).])])dnl
])

# _AM_AUTOCONF_VERSION(VERSION)
# -----------------------------
# aclocal traces this macro to find the Autoconf version.
# This is a private macro too.  Using m4_define simplifies
# the logic in aclocal, which can simply ignore this definition.
m4_define([_AM_AUTOCONF_VERSION], [])

# AM_SET_CURRENT_AUTOMAKE_VERSION
# -------------------------------
# Call AM_AUTOMAKE_VERSION and AM_AUTOMAKE_VERSION so they can be traced.
# This function is AC_REQUIREd by AC_INIT_AUTOMAKE.
AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
[AM_AUTOMAKE_VERSION([@VERSION@])dnl
_AM_AUTOCONF_VERSION(m4_PACKAGE_VERSION)])

kc3-lang/automake/m4/amversion.in

Commit

kc3-lang/automake /m4/amversion.in