header.m4

Branch :

Show log
Commit
Author : Jim Meyering
Date : 2000-08-06 12:36:53
Hash : 15f3cbc2
Message : (AM_CONFIG_HEADER): Fix typo in last change: add missing closing bracket and closing parenthesis. Don't quote the first argument to AC_OUTPUT_COMMANDS. Backslash-escape the backquotes and `$' in `am_indx'-incrementing stmt.

m4/header.m4

# Like AC_CONFIG_HEADER, but automatically create stamp file.

# serial 3

# When config.status generates a header, we must update the stamp-h file.
# This file resides in the same directory as the config header
# that is generated.  We must strip everything past the first ":",
# and everything past the last "/".

AC_PREREQ([2.12])

AC_DEFUN([AM_CONFIG_HEADER],
[AC_CONFIG_HEADER([$1])
  AC_OUTPUT_COMMANDS(
   ifelse(patsubst([$1], [[^ ]], []),
	  [],
	  [test -z "$CONFIG_HEADERS" || echo timestamp >dnl
	   patsubst([$1], [^\([^:]*/\)?.*], [\1])stamp-h]),
  [am_indx=1
  for am_file in $1; do
    case " $CONFIG_HEADERS " in
    *" $am_file "*)
      echo timestamp > `echo $am_file | sed 's%:.*%%;s%[^/]*$%%'`stamp-h$am_indx
      ;;
    esac
    am_indx=\`expr \$am_indx + 1\`
  done])
])

kc3-lang/automake/m4/header.m4

Commit

kc3-lang/automake /m4/header.m4