AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL.m4

Branch :

Show log
Commit
Author : Tom Tromey
Date : 1996-08-24 16:20:57
Hash : 18518e21
Message : m4 fixes

m4/AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL.m4

dnl From Jim Meyering.

# serial 1

AC_DEFUN(AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL,
[AC_REQUIRE([AM_SYS_POSIX_TERMIOS])
 AC_CACHE_CHECK([whether use of TIOCGWINSZ requires sys/ioctl.h],
	        am_cv_sys_tiocgwinsz_needs_sys_ioctl_h,
  [am_cv_sys_tiocgwinsz_needs_sys_ioctl_h=no

  gwinsz_in_termios_h=no
  if test $am_cv_sys_posix_termios = yes; then
    AC_EGREP_CPP([yes],
    [#include <sys/types.h>
#     include <termios.h>
#     ifdef TIOCGWINSZ
        yes
#     endif
    ], gwinsz_in_termios_h=yes)
  fi

  if test $gwinsz_in_termios_h = no; then
    AC_EGREP_CPP([yes],
    [#include <sys/types.h>
#     include <sys/ioctl.h>
#     ifdef TIOCGWINSZ
        yes
#     endif
    ], am_cv_sys_tiocgwinsz_needs_sys_ioctl_h=yes)
  fi
  ])
  if test $am_cv_sys_tiocgwinsz_needs_sys_ioctl_h = yes; then
    AC_DEFINE(GWINSZ_IN_SYS_IOCTL)
  fi
])

kc3-lang/automake/m4/AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL.m4

Commit

kc3-lang/automake /m4/AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL.m4