kc3-lang/automake/m4/minuso.m4

• Show log

  Commit

• Hash : c148dc73
  Author :
  Date : 2013-05-11T11:45:16
  

  Use AC_DEFUN_ONCE to define AM_PROG_CC_C_O
  
  If AM_PROG_CC_C_O is expanded multiple times, and the compiler does not
  support -c and -o together, each expansion of the macro will prepend
  the compile script to CC.  This can result in the compile script
  invoking the compile script, which at best pointless and silly.
  Fortunately, there does not appear to be any serious problems as the
  first compile invocation strips out -o options, causing subsequent
  invocations of the script to merely exec their arguments.
  
  Other than fixing the above, this should not normally cause any changes
  to the resulting configure script, except in the (hopefully rare) case
  where AM_PROG_CC_C_O is directly expanded (i.e., *not* using AC_REQUIRE)
  in the body of a macro defined with AC_DEFUN.  In that case, the use of
  AC_DEFUN_ONCE may cause the expansion of AM_PROG_CC_C_O to appear
  earlier in the configure script.
  
  * m4/minuso.m4: Change the definition of AM_PROG_CC_C_O to use
  AC_DEFUN_ONCE, avoiding problems caused by multiple expansions.
  
  Copyright-paperwork-exempt: yes
  Signed-off-by: Stefano Lattarini <stefano.lattarini@gmail.com>
  

Download

• m4/minuso.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 1999-2013 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # AM_PROG_CC_C_O
  # --------------
  # Like AC_PROG_CC_C_O, but changed for automake.
  AC_DEFUN_ONCE([AM_PROG_CC_C_O],
  [AC_REQUIRE([AC_PROG_CC_C_O])dnl
  AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
  AC_REQUIRE_AUX_FILE([compile])dnl
  # FIXME: we rely on the cache variable name because
  # there is no other way.
  set dummy $CC
  am_cc=`echo $[2] | sed ['s/[^a-zA-Z0-9_]/_/g;s/^[0-9]/_/']`
  eval am_t=\$ac_cv_prog_cc_${am_cc}_c_o
  if test "$am_t" != yes; then
     # Losing compiler, so override with the script.
     # FIXME: It is wrong to rewrite CC.
     # But if we don't then we get into trouble of one sort or another.
     # A longer-term fix would be to have automake use am__CC in this case,
     # and then we could set am__CC="\$(top_srcdir)/compile \$(CC)"
     CC="$am_aux_dir/compile $CC"
  fi
  dnl Make sure AC_PROG_CC is never called again, or it will override our
  dnl setting of CC.
  m4_define([AC_PROG_CC],
            [m4_fatal([AC_PROG_CC cannot be called after AM_PROG_CC_C_O])])
  ])
  

Download