kc3-lang/automake/m4/maintainer.m4

• Show log

  Commit

• Hash : a45c6364
  Author :
  Date : 2011-10-29T12:15:59
  

  maint-mode: fix botched configure messages
  
  This change fixes automake bug#9890.
  
  * m4/maintainer.m4 (AM_MAINTAINER_MODE): Fix the "checking ..."
  configure message related to the enabling/disabling of maintainer
  mode.
  * tests/help-maintainer.test: Renamed ...
  * tests/maintmode-configure-msg.test: ... to this, and extended
  to cover the fixed bug.  Also, since we are at it, make grepping
  of configure help screens stricter, and throw in some few other
  changes to reduce code duplication and enhance readability.
  * tests/Makefile.am (TESTS): Update.
  * THANKS: Update with Zack's new e-mail address.
  
  Report and initial patch by Zack Weinberg, test cases added by
  Stefano Lattarini.
  

Download

• m4/maintainer.m4

• # Add --enable-maintainer-mode option to configure.         -*- Autoconf -*-
  # From Jim Meyering
  
  # Copyright (C) 1996, 1998, 2000, 2001, 2002, 2003, 2004, 2005, 2008,
  # 2011 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 5
  
  # AM_MAINTAINER_MODE([DEFAULT-MODE])
  # ----------------------------------
  # Control maintainer-specific portions of Makefiles.
  # Default is to disable them, unless `enable' is passed literally.
  # For symmetry, `disable' may be passed as well.  Anyway, the user
  # can override the default with the --enable/--disable switch.
  AC_DEFUN([AM_MAINTAINER_MODE],
  [m4_case(m4_default([$1], [disable]),
         [enable], [m4_define([am_maintainer_other], [disable])],
         [disable], [m4_define([am_maintainer_other], [enable])],
         [m4_define([am_maintainer_other], [enable])
          m4_warn([syntax], [unexpected argument to AM@&t@_MAINTAINER_MODE: $1])])
  AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
    dnl maintainer-mode's default is 'disable' unless 'enable' is passed
    AC_ARG_ENABLE([maintainer-mode],
  [  --][am_maintainer_other][-maintainer-mode  am_maintainer_other make rules and dependencies not useful
  			  (and sometimes confusing) to the casual installer],
        [USE_MAINTAINER_MODE=$enableval],
        [USE_MAINTAINER_MODE=]m4_if(am_maintainer_other, [enable], [no], [yes]))
    AC_MSG_RESULT([$USE_MAINTAINER_MODE])
    AM_CONDITIONAL([MAINTAINER_MODE], [test $USE_MAINTAINER_MODE = yes])
    MAINT=$MAINTAINER_MODE_TRUE
    AC_SUBST([MAINT])dnl
  ]
  )
  
  AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  

Download