make.m4

Branch :

Show log
Commit
Author : Ralf Wildenhues
Date : 2009-04-19 17:10:25
Hash : 45060dd0
Message : Detect make `include' style also with parallel non-GNU make. Parallel NetBSD make outputs `--- $target ---' messages, parallel HP-UX make outputs `Making target"$target"'. Just ignore all additional output for the include test. * m4/make.m4 (AM_MAKE_INCLUDE): Ignore additional output produced by `make' to relax `include' style detection. Signed-off-by: Ralf Wildenhues <Ralf.Wildenhues@gmx.de>

m4/make.m4

# Check to see how 'make' treats includes.	            -*- Autoconf -*-

# Copyright (C) 2001, 2002, 2003, 2005, 2009  Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# serial 4

# AM_MAKE_INCLUDE()
# -----------------
# Check to see how make treats includes.
AC_DEFUN([AM_MAKE_INCLUDE],
[am_make=${MAKE-make}
cat > confinc << 'END'
am__doit:
	@echo this is the am__doit target
.PHONY: am__doit
END
# If we don't find an include directive, just comment out the code.
AC_MSG_CHECKING([for style of include used by $am_make])
am__include="#"
am__quote=
_am_result=none
# First try GNU make style include.
echo "include confinc" > confmf
# Ignore all kinds of additional output from `make'.
case `$am_make -s -f confmf 2> /dev/null` in #(
*the\ am__doit\ target*)
  am__include=include
  am__quote=
  _am_result=GNU
  ;;
esac
# Now try BSD make style include.
if test "$am__include" = "#"; then
   echo '.include "confinc"' > confmf
   case `$am_make -s -f confmf 2> /dev/null` in #(
   *the\ am__doit\ target*)
     am__include=.include
     am__quote="\""
     _am_result=BSD
     ;;
   esac
fi
AC_SUBST([am__include])
AC_SUBST([am__quote])
AC_MSG_RESULT([$_am_result])
rm -f confinc confmf
])

kc3-lang/automake/m4/make.m4

Commit

kc3-lang/automake /m4/make.m4