kc3-lang/automake/m4/cond.m4

• Show log

  Commit

• Hash : 3c5d9e8f
  Author :
  Date : 2011-03-15T17:36:40
  

  cosmetics: better use of m4 quoting and m4sugar macros
  
  * m4/dmalloc.m4: Better use of m4 quoting.  Bump serial number.
  * m4/gcj.m4: Likewise.
  * m4/init.m4: Likewise.
  * m4/install-sh.m4: Likewise.
  * m4/lex.m4: Likewise.
  * m4/multi.m4: Likewise.
  * m4/option.m4: Likewise.
  * m4/python.m4: Likewise.
  * m4/sanity.m4: Likewise.
  * m4/cond.m4: Likewise.  Also, prefer the m4sugar macro 'm4_if'
  over the plain m4 macro 'ifelse'.
  * m4/depend.m4: Likewise.
  

Download

• m4/cond.m4

• # AM_CONDITIONAL                                            -*- Autoconf -*-
  
  # Copyright (C) 1997, 2000, 2001, 2003, 2004, 2005, 2006, 2008, 2011
  # Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 10
  
  # AM_CONDITIONAL(NAME, SHELL-CONDITION)
  # -------------------------------------
  # Define a conditional.
  AC_DEFUN([AM_CONDITIONAL],
  [AC_PREREQ([2.52])dnl
   m4_if([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
         [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
  AC_SUBST([$1_TRUE])dnl
  AC_SUBST([$1_FALSE])dnl
  _AM_SUBST_NOTMAKE([$1_TRUE])dnl
  _AM_SUBST_NOTMAKE([$1_FALSE])dnl
  m4_define([_AM_COND_VALUE_$1], [$2])dnl
  if $2; then
    $1_TRUE=
    $1_FALSE='#'
  else
    $1_TRUE='#'
    $1_FALSE=
  fi
  AC_CONFIG_COMMANDS_PRE(
  [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
    AC_MSG_ERROR([[conditional "$1" was never defined.
  Usually this means the macro was only invoked conditionally.]])
  fi])])
  

Download