kc3-lang/automake/m4/multi.m4

• Show log

  Commit

• Hash : 3c5d9e8f
  Author :
  Date : 2011-03-15T17:36:40
  

  cosmetics: better use of m4 quoting and m4sugar macros
  
  * m4/dmalloc.m4: Better use of m4 quoting.  Bump serial number.
  * m4/gcj.m4: Likewise.
  * m4/init.m4: Likewise.
  * m4/install-sh.m4: Likewise.
  * m4/lex.m4: Likewise.
  * m4/multi.m4: Likewise.
  * m4/option.m4: Likewise.
  * m4/python.m4: Likewise.
  * m4/sanity.m4: Likewise.
  * m4/cond.m4: Likewise.  Also, prefer the m4sugar macro 'm4_if'
  over the plain m4 macro 'ifelse'.
  * m4/depend.m4: Likewise.
  

Download

• m4/multi.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 1998, 1999, 2000, 2001, 2003, 2004, 2005, 2006, 2011
  # Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 8
  
  # AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
  # ---------------------------------------------------
  # Add --enable-multilib to configure.
  AC_DEFUN([AM_ENABLE_MULTILIB],
  [# Default to --enable-multilib
  AC_ARG_ENABLE([multilib],
  [AS_HELP_STRING(
     [--enable-multilib],
     [build many library versions (default)])],
  [case "$enableval" in
    yes) multilib=yes ;;
    no)  multilib=no ;;
    *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
   esac],
  	      [multilib=yes])
  
  # We may get other options which we leave undocumented:
  # --with-target-subdir, --with-multisrctop, --with-multisubdir
  # See config-ml.in if you want the gory details.
  
  if test "$srcdir" = "."; then
    if test "$with_target_subdir" != "."; then
      multi_basedir="$srcdir/$with_multisrctop../$2"
    else
      multi_basedir="$srcdir/$with_multisrctop$2"
    fi
  else
    multi_basedir="$srcdir/$2"
  fi
  AC_SUBST([multi_basedir])
  
  # Even if the default multilib is not a cross compilation,
  # it may be that some of the other multilibs are.
  if test $cross_compiling = no && test $multilib = yes \
     && test "x${with_multisubdir}" != x ; then
     cross_compiling=maybe
  fi
  
  AC_OUTPUT_COMMANDS([
  # Only add multilib support code if we just rebuilt the top-level
  # Makefile.
  case " $CONFIG_FILES " in
   *" ]m4_default([$1],Makefile)[ "*)
     ac_file=]m4_default([$1],Makefile)[ . ${multi_basedir}/config-ml.in
     ;;
  esac],
  		   [
  srcdir="$srcdir"
  host="$host"
  target="$target"
  with_multisubdir="$with_multisubdir"
  with_multisrctop="$with_multisrctop"
  with_target_subdir="$with_target_subdir"
  ac_configure_args="${multilib_arg} ${ac_configure_args}"
  multi_basedir="$multi_basedir"
  CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
  CC="$CC"])])dnl
  

Download