kc3-lang/automake/m4/silent.m4

• Show log

  Commit

• Hash : d76d91ae
  Author :
  Date : 2010-09-09T17:24:13
  

  Use AS_HELP_STRING in AM_SILENT_RULES.
  
  * m4/silent.m4 (AM_SILENT_RULES): Use `AS_HELP_STRING' to format
  help message regarding configure options `--enable-silent-rules'
  and `--disable-silent-rules'.  Also throw in a couple of cosmetic
  changes in the related `case' statement (indentation, balancing
  of parentheses).
  * THANKS: Update.
  
  From a report by Jeff A. Daily.
  

Download

• m4/silent.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 2009, 2010 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 2
  
  # AM_SILENT_RULES([DEFAULT])
  # --------------------------
  # Enable less verbose build rules; with the default set to DEFAULT
  # (`yes' being less verbose, `no' or empty being verbose).
  AC_DEFUN([AM_SILENT_RULES],
  [AC_ARG_ENABLE([silent-rules], [dnl
  AS_HELP_STRING(
    [--enable-silent-rules],
    [less verbose build output (undo: `make V=1')])
  AS_HELP_STRING(
    [--disable-silent-rules],
    [verbose build output (undo: `make V=0')])dnl
  ])
  case $enable_silent_rules in @%:@ (((
    yes) AM_DEFAULT_VERBOSITY=0;;
     no) AM_DEFAULT_VERBOSITY=1;;
      *) AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1]);;
  esac
  AC_SUBST([AM_DEFAULT_VERBOSITY])dnl
  AM_BACKSLASH='\'
  AC_SUBST([AM_BACKSLASH])dnl
  _AM_SUBST_NOTMAKE([AM_BACKSLASH])dnl
  ])
  

Download