kc3-lang/automake/m4/strip.m4

• Show log

  Commit

• Hash : 1cddf410
  Author :
  Date : 2011-04-17T11:21:49
  

  m4: add missing serial numbers to a few files
  
  Related to automake bug#8483.
  
  * m4/amversion.in: Add serial number.
  * m4/auxdir.m4: Likewise.
  * m4/gcj.m4: Likewise.
  * m4/install-sh.m4: Likewise.
  * m4/mkdirp.m4: Likewise.
  * m4/python.m4: Likewise.
  * m4/runlog.m4: Likewise.
  * m4/strip.m4: Likewise.
  * m4/upc.m4: Likewise.
  

Download

• m4/strip.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 2001, 2003, 2005, 2011 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 1
  
  # AM_PROG_INSTALL_STRIP
  # ---------------------
  # One issue with vendor `install' (even GNU) is that you can't
  # specify the program used to strip binaries.  This is especially
  # annoying in cross-compiling environments, where the build's strip
  # is unlikely to handle the host's binaries.
  # Fortunately install-sh will honor a STRIPPROG variable, so we
  # always use install-sh in `make install-strip', and initialize
  # STRIPPROG with the value of the STRIP variable (set by the user).
  AC_DEFUN([AM_PROG_INSTALL_STRIP],
  [AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
  # Installed binaries are usually stripped using `strip' when the user
  # run `make install-strip'.  However `strip' might not be the right
  # tool to use in cross-compilation environments, therefore Automake
  # will honor the `STRIP' environment variable to overrule this program.
  dnl Don't test for $cross_compiling = yes, because it might be `maybe'.
  if test "$cross_compiling" != no; then
    AC_CHECK_TOOL([STRIP], [strip], :)
  fi
  INSTALL_STRIP_PROGRAM="\$(install_sh) -c -s"
  AC_SUBST([INSTALL_STRIP_PROGRAM])])
  

Download